[Top][All Lists]
[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
[PATCH] {master} cosmetics: better use of m4 quoting and m4sugar macros
From: |
Stefano Lattarini |
Subject: |
[PATCH] {master} cosmetics: better use of m4 quoting and m4sugar macros (was: Re: [PATCH] {maint} python: extend and improve tests, fix minor glitches) |
Date: |
Thu, 17 Mar 2011 12:21:15 +0100 |
User-agent: |
KMail/1.13.3 (Linux/2.6.30-2-686; KDE/4.4.4; i686; ; ) |
Hello automakers, and sorry for the delay.
Reference:
<http://lists.gnu.org/archive/html/automake-patches/2011-02/msg00005.html>
[Stefano Lattarini]
> > > > > --- a/tests/python5.test
> > > > > +++ b/tests/python5.test
> > > >
> > > > > @@ -24,16 +24,32 @@ set -e
> > > > >
> > > > > cat >>configure.in <<EOF
> > > > > # Hopefully the Python team will never release such a version.
> > > > > -AM_PATH_PYTHON(9999.9)
> > > > > +AM_PATH_PYTHON([9999.9])
> > > >
[Ralf Wildenhues]
> > > > Nice that you do it here, but up in python.m4 you should then, too.
> > > >
[Stefano Lattarini]
> > > Definitely. But in a follow-up patch IMHO (and since we are at it, we
> > > should fix underquoting in all the other *.m4 automake files). I will
> > > submit this patch in the coming week.
> >
[Ralf Wildenhues]
> > OK.
> >
[Stefano Lattarini]
> Patch still on the todo list ...
>
Now patch ready! (about time you'll say :-)
The testsuite still passes with it applied.
OK for master? I'll push in 72 hours if there's no objection.
Regards,
Stefano
From b5b89f1eeb9a0b235a0ed285d03a851a623a2ed4 Mon Sep 17 00:00:00 2001
From: Stefano Lattarini <address@hidden>
Date: Tue, 15 Mar 2011 17:36:40 +0100
Subject: [PATCH] cosmetics: better use of m4 quoting and m4sugar macros
* m4/dmalloc.m4: Better use of m4 quoting. Bump serial number.
* m4/gcj.m4: Likewise.
* m4/init.m4: Likewise.
* m4/install-sh.m4: Likewise.
* m4/lex.m4: Likewise.
* m4/multi.m4: Likewise.
* m4/option.m4: Likewise.
* m4/python.m4: Likewise.
* m4/sanity.m4: Likewise.
* m4/cond.m4: Likewise. Also, prefer the m4sugar macro 'm4_if'
over the plain m4 macro 'ifelse'.
* m4/depend.m4: Likewise.
* tests/deprecated-acinit.test: New test.
* tests/Makefile.am (TESTS): Update.
---
ChangeLog | 18 ++++++++++++++
m4/cond.m4 | 10 ++++----
m4/depend.m4 | 14 +++++-----
m4/dmalloc.m4 | 14 +++++-----
m4/gcj.m4 | 9 ++++---
m4/init.m4 | 34 ++++++++++++++-------------
m4/install-sh.m4 | 5 ++-
m4/lex.m4 | 8 +++---
m4/multi.m4 | 6 ++--
m4/options.m4 | 6 ++--
m4/python.m4 | 10 ++++----
m4/sanity.m4 | 4 +-
tests/Makefile.am | 1 +
tests/Makefile.in | 1 +
tests/deprecated-acinit.test | 52 ++++++++++++++++++++++++++++++++++++++++++
15 files changed, 134 insertions(+), 58 deletions(-)
create mode 100755 tests/deprecated-acinit.test
diff --git a/ChangeLog b/ChangeLog
index 5b666d7..9677fb1 100644
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,3 +1,21 @@
+2011-03-17 Stefano Lattarini <address@hidden>
+
+ cosmetics: better use of m4 quoting and m4sugar macros
+ * m4/dmalloc.m4: Better use of m4 quoting. Bump serial number.
+ * m4/gcj.m4: Likewise.
+ * m4/init.m4: Likewise.
+ * m4/install-sh.m4: Likewise.
+ * m4/lex.m4: Likewise.
+ * m4/multi.m4: Likewise.
+ * m4/option.m4: Likewise.
+ * m4/python.m4: Likewise.
+ * m4/sanity.m4: Likewise.
+ * m4/cond.m4: Likewise. Also, prefer the m4sugar macro 'm4_if'
+ over the plain m4 macro 'ifelse'.
+ * m4/depend.m4: Likewise.
+ * tests/deprecated-acinit.test: New test.
+ * tests/Makefile.am (TESTS): Update.
+
2011-03-04 Stefano Lattarini <address@hidden>
tests: fix bug (comments-in-var-defn.test + autoconf 2.62)
diff --git a/m4/cond.m4 b/m4/cond.m4
index fd248b2..7fa5dfd 100644
--- a/m4/cond.m4
+++ b/m4/cond.m4
@@ -1,21 +1,21 @@
# AM_CONDITIONAL -*- Autoconf -*-
-# Copyright (C) 1997, 2000, 2001, 2003, 2004, 2005, 2006, 2008
+# Copyright (C) 1997, 2000, 2001, 2003, 2004, 2005, 2006, 2008, 2011
# Free Software Foundation, Inc.
#
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.
-# serial 9
+# serial 10
# AM_CONDITIONAL(NAME, SHELL-CONDITION)
# -------------------------------------
# Define a conditional.
AC_DEFUN([AM_CONDITIONAL],
-[AC_PREREQ(2.52)dnl
- ifelse([$1], [TRUE], [AC_FATAL([$0: invalid condition: $1])],
- [$1], [FALSE], [AC_FATAL([$0: invalid condition: $1])])dnl
+[AC_PREREQ([2.52])dnl
+ m4_if([$1], [TRUE], [AC_FATAL([$0: invalid condition: $1])],
+ [$1], [FALSE], [AC_FATAL([$0: invalid condition: $1])])dnl
AC_SUBST([$1_TRUE])dnl
AC_SUBST([$1_FALSE])dnl
_AM_SUBST_NOTMAKE([$1_TRUE])dnl
diff --git a/m4/depend.m4 b/m4/depend.m4
index a5726c6..cf1b3d8 100644
--- a/m4/depend.m4
+++ b/m4/depend.m4
@@ -6,7 +6,7 @@
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.
-# serial 13
+# serial 14
# There are a few dirty hacks below to avoid letting `AC_PROG_CC' be
# written in clear, in which case automake, when reading aclocal.m4,
@@ -31,12 +31,12 @@ AC_REQUIRE([AM_OUTPUT_DEPENDENCY_COMMANDS])dnl
AC_REQUIRE([AM_MAKE_INCLUDE])dnl
AC_REQUIRE([AM_DEP_TRACK])dnl
-ifelse([$1], CC, [depcc="$CC" am_compiler_list=],
- [$1], CXX, [depcc="$CXX" am_compiler_list=],
- [$1], OBJC, [depcc="$OBJC" am_compiler_list='gcc3 gcc'],
- [$1], UPC, [depcc="$UPC" am_compiler_list=],
- [$1], GCJ, [depcc="$GCJ" am_compiler_list='gcc3 gcc'],
- [depcc="$$1" am_compiler_list=])
+m4_if([$1], [CC], [depcc="$CC" am_compiler_list=],
+ [$1], [CXX], [depcc="$CXX" am_compiler_list=],
+ [$1], [OBJC], [depcc="$OBJC" am_compiler_list='gcc3 gcc'],
+ [$1], [UPC], [depcc="$UPC" am_compiler_list=],
+ [$1], [GCJ], [depcc="$GCJ" am_compiler_list='gcc3 gcc'],
+ [depcc="$$1" am_compiler_list=])
AC_CACHE_CHECK([dependency style of $depcc],
[am_cv_$1_dependencies_compiler_type],
diff --git a/m4/dmalloc.m4 b/m4/dmalloc.m4
index 5d48a24..82743fd 100644
--- a/m4/dmalloc.m4
+++ b/m4/dmalloc.m4
@@ -3,14 +3,14 @@
## From Franc,ois Pinard ##
## ----------------------------------- ##
-# Copyright (C) 1996, 1998, 1999, 2000, 2001, 2002, 2003, 2005, 2010
-# Free Software Foundation, Inc.
+# Copyright (C) 1996, 1998, 1999, 2000, 2001, 2002, 2003, 2005, 2010,
+# 2011 Free Software Foundation, Inc.
#
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.
-# serial 5
+# serial 6
AC_DEFUN([AM_WITH_DMALLOC],
[AC_MSG_CHECKING([if malloc debugging is wanted])
@@ -18,14 +18,14 @@ AC_ARG_WITH([dmalloc],
[AS_HELP_STRING([--with-dmalloc],
[use dmalloc, as in http://www.dmalloc.com])],
[if test "$withval" = yes; then
- AC_MSG_RESULT(yes)
- AC_DEFINE(WITH_DMALLOC,1,
+ AC_MSG_RESULT([yes])
+ AC_DEFINE([WITH_DMALLOC], [1],
[Define if using the dmalloc debugging malloc package])
LIBS="$LIBS -ldmalloc"
LDFLAGS="$LDFLAGS -g"
else
- AC_MSG_RESULT(no)
-fi], [AC_MSG_RESULT(no)])
+ AC_MSG_RESULT([no])
+fi], [AC_MSG_RESULT([no])])
])
AU_DEFUN([fp_WITH_DMALLOC], [AM_WITH_DMALLOC])
diff --git a/m4/gcj.m4 b/m4/gcj.m4
index 9e930e0..c53a1bf 100644
--- a/m4/gcj.m4
+++ b/m4/gcj.m4
@@ -1,18 +1,19 @@
# Check for Java compiler. -*- Autoconf -*-
# For now we only handle the GNU compiler.
-# Copyright (C) 1999, 2000, 2003, 2005, 2009 Free Software Foundation, Inc.
+# Copyright (C) 1999, 2000, 2003, 2005, 2009, 2011 Free Software
+# Foundation, Inc.
#
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.
-AC_DEFUN([AM_PROG_GCJ],[
-AC_CHECK_TOOLS(GCJ, gcj, gcj)
+AC_DEFUN([AM_PROG_GCJ],
+[AC_CHECK_TOOLS([GCJ], [gcj], [gcj])
test -z "$GCJ" && AC_MSG_ERROR([no acceptable gcj found in \$PATH])
if test "x${GCJFLAGS-unset}" = xunset; then
GCJFLAGS="-g -O2"
fi
-AC_SUBST(GCJFLAGS)
+AC_SUBST([GCJFLAGS])
_AM_IF_OPTION([no-dependencies],, [_AM_DEPENDENCIES(GCJ)])
])
diff --git a/m4/init.m4 b/m4/init.m4
index 365c9ac..ccc1965 100644
--- a/m4/init.m4
+++ b/m4/init.m4
@@ -1,13 +1,13 @@
# Do all the work for Automake. -*- Autoconf -*-
# Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
-# 2005, 2006, 2008, 2009 Free Software Foundation, Inc.
+# 2005, 2006, 2008, 2009, 2011 Free Software Foundation, Inc.
#
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.
-# serial 16
+# serial 17
# This macro actually does too much. Some checks are only needed if
# your package does certain things. But this isn't really a big deal.
@@ -58,23 +58,25 @@ m4_ifval([$2],
AC_SUBST([VERSION], [$2])],
[_AM_SET_OPTIONS([$1])dnl
dnl Diagnose old-style AC_INIT with new-style AM_AUTOMAKE_INIT.
-m4_if(m4_ifdef([AC_PACKAGE_NAME], 1)m4_ifdef([AC_PACKAGE_VERSION], 1), 11,,
+m4_if(
+ m4_ifdef([AC_PACKAGE_NAME], [ok]):m4_ifdef([AC_PACKAGE_VERSION], [ok]),
+ [ok:ok],,
[m4_fatal([AC_INIT should be called with package and version arguments])])dnl
AC_SUBST([PACKAGE], ['AC_PACKAGE_TARNAME'])dnl
AC_SUBST([VERSION], ['AC_PACKAGE_VERSION'])])dnl
_AM_IF_OPTION([no-define],,
-[AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
- AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version number of package])])dnl
+[AC_DEFINE_UNQUOTED([PACKAGE], ["$PACKAGE"], [Name of package])
+ AC_DEFINE_UNQUOTED([VERSION], ["$VERSION"], [Version number of package])])dnl
# Some tools Automake needs.
AC_REQUIRE([AM_SANITY_CHECK])dnl
AC_REQUIRE([AC_ARG_PROGRAM])dnl
-AM_MISSING_PROG(ACLOCAL, aclocal-${am__api_version})
-AM_MISSING_PROG(AUTOCONF, autoconf)
-AM_MISSING_PROG(AUTOMAKE, automake-${am__api_version})
-AM_MISSING_PROG(AUTOHEADER, autoheader)
-AM_MISSING_PROG(MAKEINFO, makeinfo)
+AM_MISSING_PROG([ACLOCAL], [aclocal-${am__api_version}])
+AM_MISSING_PROG([AUTOCONF], [autoconf])
+AM_MISSING_PROG([AUTOMAKE], [automake-${am__api_version}])
+AM_MISSING_PROG([AUTOHEADER], [autoheader])
+AM_MISSING_PROG([MAKEINFO], [makeinfo])
AC_REQUIRE([AM_PROG_INSTALL_SH])dnl
AC_REQUIRE([AM_PROG_INSTALL_STRIP])dnl
AC_REQUIRE([AM_PROG_MKDIR_P])dnl
@@ -88,17 +90,17 @@ _AM_IF_OPTION([tar-ustar], [_AM_PROG_TAR([ustar])],
[_AM_PROG_TAR([v7])])])
_AM_IF_OPTION([no-dependencies],,
[AC_PROVIDE_IFELSE([AC_PROG_CC],
- [_AM_DEPENDENCIES(CC)],
+ [_AM_DEPENDENCIES([CC])],
[define([AC_PROG_CC],
- defn([AC_PROG_CC])[_AM_DEPENDENCIES(CC)])])dnl
+ defn([AC_PROG_CC])[_AM_DEPENDENCIES([CC])])])dnl
AC_PROVIDE_IFELSE([AC_PROG_CXX],
- [_AM_DEPENDENCIES(CXX)],
+ [_AM_DEPENDENCIES([CXX])],
[define([AC_PROG_CXX],
- defn([AC_PROG_CXX])[_AM_DEPENDENCIES(CXX)])])dnl
+ defn([AC_PROG_CXX])[_AM_DEPENDENCIES([CXX])])])dnl
AC_PROVIDE_IFELSE([AC_PROG_OBJC],
- [_AM_DEPENDENCIES(OBJC)],
+ [_AM_DEPENDENCIES([OBJC])],
[define([AC_PROG_OBJC],
- defn([AC_PROG_OBJC])[_AM_DEPENDENCIES(OBJC)])])dnl
+ defn([AC_PROG_OBJC])[_AM_DEPENDENCIES([OBJC])])])dnl
])
_AM_IF_OPTION([silent-rules], [AC_REQUIRE([AM_SILENT_RULES])])dnl
dnl The `parallel-tests' driver may need to know about EXEEXT, so add the
diff --git a/m4/install-sh.m4 b/m4/install-sh.m4
index b153715..a9b81e0 100644
--- a/m4/install-sh.m4
+++ b/m4/install-sh.m4
@@ -1,5 +1,6 @@
## -*- Autoconf -*-
-# Copyright (C) 2001, 2003, 2005, 2008 Free Software Foundation, Inc.
+# Copyright (C) 2001, 2003, 2005, 2008, 2011 Free Software Foundation,
+# Inc.
#
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
@@ -18,4 +19,4 @@ if test x"${install_sh}" != xset; then
install_sh="\${SHELL} $am_aux_dir/install-sh"
esac
fi
-AC_SUBST(install_sh)])
+AC_SUBST([install_sh])])
diff --git a/m4/lex.m4 b/m4/lex.m4
index 022f6a8..5012926 100644
--- a/m4/lex.m4
+++ b/m4/lex.m4
@@ -1,20 +1,20 @@
## Replacement for AC_PROG_LEX. -*- Autoconf -*-
## by Alexandre Oliva <address@hidden>
-# Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2005
-# Free Software Foundation, Inc.
+# Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2005, 2011 Free
+# Software Foundation, Inc.
#
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.
-# serial 5
+# serial 6
# AM_PROG_LEX
# -----------
# Autoconf leaves LEX=: if lex or flex can't be found. Change that to a
# "missing" invocation, for better error output.
AC_DEFUN([AM_PROG_LEX],
-[AC_PREREQ(2.50)dnl
+[AC_PREREQ([2.50])dnl
AC_REQUIRE([AM_MISSING_HAS_RUN])dnl
AC_REQUIRE([AC_PROG_LEX])dnl
if test "$LEX" = :; then
diff --git a/m4/multi.m4 b/m4/multi.m4
index dce3675..bc01dcf 100644
--- a/m4/multi.m4
+++ b/m4/multi.m4
@@ -1,12 +1,12 @@
## -*- Autoconf -*-
-# Copyright (C) 1998, 1999, 2000, 2001, 2003, 2004, 2005, 2006
+# Copyright (C) 1998, 1999, 2000, 2001, 2003, 2004, 2005, 2006, 2011
# Free Software Foundation, Inc.
#
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.
-# serial 7
+# serial 8
# AM_ENABLE_MULTILIB([MAKEFILE], [REL-TO-TOP-SRCDIR])
# ---------------------------------------------------
@@ -37,7 +37,7 @@ if test "$srcdir" = "."; then
else
multi_basedir="$srcdir/$2"
fi
-AC_SUBST(multi_basedir)
+AC_SUBST([multi_basedir])
# Even if the default multilib is not a cross compilation,
# it may be that some of the other multilibs are.
diff --git a/m4/options.m4 b/m4/options.m4
index 6824d84..efdc49d 100644
--- a/m4/options.m4
+++ b/m4/options.m4
@@ -1,13 +1,13 @@
# Helper functions for option handling. -*- Autoconf -*-
-# Copyright (C) 2001, 2002, 2003, 2005, 2008, 2010 Free Software
+# Copyright (C) 2001, 2002, 2003, 2005, 2008, 2010, 2011 Free Software
# Foundation, Inc.
#
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.
-# serial 5
+# serial 6
# _AM_MANGLE_OPTION(NAME)
# -----------------------
@@ -18,7 +18,7 @@ AC_DEFUN([_AM_MANGLE_OPTION],
# --------------------
# Set option NAME. Presently that only means defining a flag for this option.
AC_DEFUN([_AM_SET_OPTION],
-[m4_define(_AM_MANGLE_OPTION([$1]), 1)])
+[m4_define(_AM_MANGLE_OPTION([$1]), [1])])
# _AM_SET_OPTIONS(OPTIONS)
# ------------------------
diff --git a/m4/python.m4 b/m4/python.m4
index 2410436..4133823 100644
--- a/m4/python.m4
+++ b/m4/python.m4
@@ -3,8 +3,8 @@
## From Andrew Dalke
## Updated by James Henstridge
## ------------------------
-# Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2008, 2009
-# Free Software Foundation, Inc.
+# Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2008, 2009,
+# 2011 Free Software Foundation, Inc.
#
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
@@ -55,9 +55,9 @@ AC_DEFUN([AM_PATH_PYTHON],
# If the user set $PYTHON, use it and don't search something else.
AC_MSG_CHECKING([whether $PYTHON version is >= $1])
AM_PYTHON_CHECK_VERSION([$PYTHON], [$1],
- [AC_MSG_RESULT(yes)],
- [AC_MSG_RESULT(no)
- AC_MSG_ERROR(Python interpreter is too old)])
+ [AC_MSG_RESULT([yes])],
+ [AC_MSG_RESULT([no])
+ AC_MSG_ERROR([Python interpreter is too old])])
am_display_PYTHON=$PYTHON
else
# Otherwise, try each interpreter until we find one that satisfies
diff --git a/m4/sanity.m4 b/m4/sanity.m4
index a9cac5c..b718ac4 100644
--- a/m4/sanity.m4
+++ b/m4/sanity.m4
@@ -7,7 +7,7 @@
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.
-# serial 8
+# serial 9
# AM_SANITY_CHECK
# ---------------
@@ -66,7 +66,7 @@ else
AC_MSG_ERROR([newly created file is older than distributed files!
Check your system clock])
fi
-AC_MSG_RESULT(yes)
+AC_MSG_RESULT([yes])
# If we didn't sleep, we still need to ensure time stamps of config.status and
# generated files are strictly newer.
am_sleep_pid=
diff --git a/tests/Makefile.am b/tests/Makefile.am
index c0efdc3..121d0a6 100644
--- a/tests/Makefile.am
+++ b/tests/Makefile.am
@@ -377,6 +377,7 @@ depend3.test \
depend4.test \
depend5.test \
depend6.test \
+deprecated-acinit.test \
destdir.test \
dirforbid.test \
dirlist.test \
diff --git a/tests/Makefile.in b/tests/Makefile.in
index 311b524..1fe16e0 100644
--- a/tests/Makefile.in
+++ b/tests/Makefile.in
@@ -639,6 +639,7 @@ depend3.test \
depend4.test \
depend5.test \
depend6.test \
+deprecated-acinit.test \
destdir.test \
dirforbid.test \
dirlist.test \
diff --git a/tests/deprecated-acinit.test b/tests/deprecated-acinit.test
new file mode 100755
index 0000000..b0aeea1
--- /dev/null
+++ b/tests/deprecated-acinit.test
@@ -0,0 +1,52 @@
+#! /bin/sh
+# Copyright (C) 2010, 2011 Free Software Foundation, Inc.
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2, or (at your option)
+# any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program. If not, see <http://www.gnu.org/licenses/>.
+
+# Check that automake and autoconf complain about old-style AC_INIT
+# used with new-style AM_AUTOMAKE_INIT.
+
+. ./defs || Exit 1
+
+: > Makefile.am
+
+# We'll need a proper aclocal.m4, but aclocal is expected to fail
+# later, so get and store it now.
+$ACLOCAL
+mv aclocal.m4 aclocal-m4.sav
+
+errmsg='AC_INIT should be called with package and version argument'
+
+for ac_init in AC_INIT 'AC_INIT([Makefile.am])'; do
+ for am_init_automake in AM_INIT_AUTOMAKE 'AM_INIT_AUTOMAKE([1.11])'; do
+ rm -rf autom4te*.cache aclocal.m4
+ unindent > configure.in <<END
+ $ac_init
+ $am_init_automake
+ AC_CONFIG_FILES([Makefile])
+END
+ cat configure.in # might be useful for debugging
+ $ACLOCAL 2>stderr && { cat stderr >&2; Exit 1; }
+ cat stderr >&2
+ grep "^configure\\.in:.* $errmsg" stderr
+ cp aclocal-m4.sav aclocal.m4
+ $AUTOCONF 2>stderr && { cat stderr >&2; Exit 1; }
+ cat stderr >&2
+ grep "^configure\\.in:.* $errmsg" stderr
+ AUTOMAKE_fails
+ grep "^configure\\.in:.* $errmsg" stderr
+ done
+done
+
+:
--
1.7.2.3
- [PATCH] {master} cosmetics: better use of m4 quoting and m4sugar macros (was: Re: [PATCH] {maint} python: extend and improve tests, fix minor glitches),
Stefano Lattarini <=