bug#16381: 24.3.50; align issue

[Leo Liu]

On 2014-06-24 01:54 -0400, Glenn Morris wrote:
> Leo, any chance you could fix that one too?
>
> There are a handful of other files that use tab-stop-list;
> it would be good to check them too.

I did a grep in lisp/ and these are the files using tab-stop-list:

- woman.el
- progmodes/asm-mode.el
- ruler-mode.el
- textmodes/picture.el

The following patch seems to fix all except woman.el. woman.el seems to
use its own interpretation of tab-stop-list i.e. it may not be affected
at all by the change to tab-stop-list. Comments? Leo

=== modified file 'lisp/indent.el'
--- lisp/indent.el      2014-06-23 23:09:20 +0000
+++ lisp/indent.el      2014-06-24 12:22:40 +0000
@@ -677,6 +677,13 @@
                             (if (<= column last) -1 (/ (- column last 1) step))
                           (1+ (/ (- column last) step)))))))))
 
+(defun indent-accumulate-tab-stops (limit)
+  "Get a list of tab stops before LIMIT (inclusive)."
+  (let ((tab 0) (tab-stops))
+    (while (<= (setq tab (indent-next-tab-stop tab)) limit)
+      (push tab tab-stops))
+    (nreverse tab-stops)))
+
 (defun tab-to-tab-stop ()
   "Insert spaces or tabs to next defined tab-stop column.
 The variable `tab-stop-list' is a list of columns at which there are tab stops.

=== modified file 'lisp/progmodes/asm-mode.el'
--- lisp/progmodes/asm-mode.el  2014-02-10 01:34:22 +0000
+++ lisp/progmodes/asm-mode.el  2014-06-24 12:53:03 +0000
@@ -172,7 +172,7 @@
    ;; Simple `;' comments go to the comment-column.
    (and (looking-at "\\s<\\(\\S<\\|\\'\\)") comment-column)
    ;; The rest goes at the first tab stop.
-   (or (car tab-stop-list) tab-width)))
+   (or (indent-next-tab-stop 0))))
 
 (defun asm-colon ()
   "Insert a colon; if it follows a label, delete the label's indentation."

=== modified file 'lisp/ruler-mode.el'
--- lisp/ruler-mode.el  2014-06-16 06:37:37 +0000
+++ lisp/ruler-mode.el  2014-06-24 12:58:16 +0000
@@ -476,8 +476,11 @@
                (not (member ts tab-stop-list))
                (progn
                  (message "Tab stop set to %d" ts)
-                 (setq tab-stop-list (sort (cons ts tab-stop-list)
-                                           #'<)))))))))
+                 ;; If `tab-stop-list' is empty, populate it with tab
+                 ;; stops before TS.
+                 (when (null tab-stop-list)
+                   (setq tab-stop-list (indent-accumulate-tab-stops (1- ts))))
+                 (setq tab-stop-list (sort (cons ts tab-stop-list) #'<)))))))))
 
 (defun ruler-mode-mouse-del-tab-stop (start-event)
   "Delete tab stop at the graduation where the mouse pointer is on.
@@ -753,7 +756,7 @@
          i (1+ i) 'help-echo ruler-mode-fill-column-help-echo
          ruler))
        ;; Show the `tab-stop-list' markers.
-       ((and ruler-mode-show-tab-stops (member j tab-stop-list))
+       ((and ruler-mode-show-tab-stops (= j (indent-next-tab-stop (1- j))))
         (aset ruler i ruler-mode-tab-stop-char)
         (put-text-property
          i (1+ i) 'face 'ruler-mode-tab-stop

=== modified file 'lisp/textmodes/picture.el'
--- lisp/textmodes/picture.el   2014-02-10 01:34:22 +0000
+++ lisp/textmodes/picture.el   2014-06-24 12:45:46 +0000
@@ -418,7 +418,8 @@
   (save-excursion
     (let (tabs)
       (if arg
-         (setq tabs (default-value 'tab-stop-list))
+         (setq tabs (or (default-value 'tab-stop-list)
+                        (indent-accumulate-tab-stops (window-width))))
        (let ((regexp (concat "[ \t]+[" (regexp-quote picture-tab-chars) "]")))
          (beginning-of-line)
          (let ((bol (point)))