bug#18847: 24.4; Inconsistent behaviour of M-h with negative arguments

[H. Dieter Wilhelm]

Hello,

please try M-- M-h M-h M-h.

below some paragraphs.  The behaviour is not in line with the other
marking commands like M-@, ...

Here's a suggestion and a matching patch:

(defun mark-paragraph (&optional arg allow-extend)
  "Put mark at beginning of this paragraph,  point at end.
The paragraph marked is the one that contains point or follows
point. 

With argument ARG, puts mark at the end of a following paragraph,
so that the number of paragraphs marked equals ARG.

If ARG is negative, point is put at the beginning of this
paragraph, mark is put at the end of this or a previous
paragraph.

Interactively, if this command is repeated or (in Transient Mark
Mode) if the mark is active, it marks the next ARG paragraphs
after the ones already marked.  This means when activating the
mark before using this command, the current paragraph is only
marked from point."
  (interactive "P\np")
  (let ((numeric-arg (prefix-numeric-value arg)))
    (cond ((eobp)                       ; smart-aleck?
           (backward-paragraph (abs numeric-arg))
           (push-mark nil t t)
           (forward-paragraph (abs numeric-arg)))
          ((and allow-extend ;we already called this function or have
                             ;a (possibly empty) region
                (or (eq last-command this-command)
                    (region-active-p)))
           (if arg
               (setq arg numeric-arg)
             (if (< (mark) (point))
                 (setq arg -1)
               (setq arg 1)))
           (set-mark
            (save-excursion
              (goto-char (mark))
              (forward-paragraph arg)
              (point))))
          ((zerop numeric-arg)          
           (message "Will not mark zero paragraphs."))
          (t
           (forward-paragraph numeric-arg)
           (push-mark nil t t)
           (backward-paragraph numeric-arg)))))


Thank you for your troubles!

diff -c /usr/local/src/emacs-24.4/lisp/textmodes/paragraphs.el 
/usr/local/src/emacs/lisp/textmodes/paragraphs.el
*** /usr/local/src/emacs-24.4/lisp/textmodes/paragraphs.el      2014-03-21 
06:34:40.000000000 +0100
--- /usr/local/src/emacs/lisp/textmodes/paragraphs.el   2014-10-27 
00:22:41.874845901 +0100
***************
*** 370,403 ****
    (forward-paragraph (- arg)))
  
  (defun mark-paragraph (&optional arg allow-extend)
!   "Put point at beginning of this paragraph, mark at end.
! The paragraph marked is the one that contains point or follows point.
  
! With argument ARG, puts mark at end of a following paragraph, so that
! the number of paragraphs marked equals ARG.
  
! If ARG is negative, point is put at end of this paragraph, mark is put
! at beginning of this or a previous paragraph.
  
! Interactively (or if ALLOW-EXTEND is non-nil), if this command is
! repeated or (in Transient Mark mode) if the mark is active,
! it marks the next ARG paragraphs after the ones already marked."
!   (interactive "p\np")
!   (unless arg (setq arg 1))
!   (when (zerop arg)
!     (error "Cannot mark zero paragraphs"))
!   (cond ((and allow-extend
!             (or (and (eq last-command this-command) (mark t))
!                 (and transient-mark-mode mark-active)))
!        (set-mark
!         (save-excursion
!           (goto-char (mark))
!           (forward-paragraph arg)
!           (point))))
!       (t
!        (forward-paragraph arg)
!        (push-mark nil t t)
!        (backward-paragraph arg))))
  
  (defun kill-paragraph (arg)
    "Kill forward to end of paragraph.
--- 370,417 ----
    (forward-paragraph (- arg)))
  
  (defun mark-paragraph (&optional arg allow-extend)
!   "Put mark at beginning of this paragraph,  point at end.
! The paragraph marked is the one that contains point or follows
! point.
  
! With argument ARG, puts mark at the end of a following paragraph,
! so that the number of paragraphs marked equals ARG.
  
! If ARG is negative, point is put at the beginning of this
! paragraph, mark is put at the end of this or a previous
! paragraph.
  
! Interactively, if this command is repeated or (in Transient Mark
! Mode) if the mark is active, it marks the next ARG paragraphs
! after the ones already marked.  This means when activating the
! mark before using this command, the current paragraph is only
! marked from point."
!   (interactive "P\np")
!   (let ((numeric-arg (prefix-numeric-value arg)))
!     (cond ((eobp)                     ; smart-aleck?
!          (backward-paragraph (abs numeric-arg))
!          (push-mark nil t t)
!          (forward-paragraph (abs numeric-arg)))
!         ((and allow-extend ;we already called this function or have
!                            ;a (possibly empty) region
!               (or (eq last-command this-command)
!                   (region-active-p)))
!          (if arg
!              (setq arg numeric-arg)
!            (if (< (mark) (point))
!                (setq arg -1)
!              (setq arg 1)))
!          (set-mark
!           (save-excursion
!             (goto-char (mark))
!             (forward-paragraph arg)
!             (point))))
!         ((zerop numeric-arg)
!          (message "Will not mark zero paragraphs."))
!         (t
!          (forward-paragraph numeric-arg)
!          (push-mark nil t t)
!          (backward-paragraph numeric-arg)))))
  
  (defun kill-paragraph (arg)
    "Kill forward to end of paragraph.

Diff finished.  Mon Oct 27 00:22:49 2014


-- 
Best wishes
H. Dieter Wilhelm
Darmstadt, Germany