[Top][All Lists]
[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
Re: 23.0.60; customize or whatever to disable gpm-mouse-mode
From: |
Stefan Monnier |
Subject: |
Re: 23.0.60; customize or whatever to disable gpm-mouse-mode |
Date: |
Tue, 10 Jun 2008 17:14:09 -0400 |
User-agent: |
Gnus/5.13 (Gnus v5.13) Emacs/23.0.60 (gnu/linux) |
> I had some trouble disabling gpm-mouse-mode, which is on by default in
> the recent cvs.
> I tried M-x customize-variable gpm-mouse-mode and saving, which turned
> it off, but on the next startup it was enabled again. Then I tried
> "(gpm-mouse-mode 0)" in my .emacs, but that didn't have any effect at
> all.
(defalias 'gpm-mouse-mode 'ignore)
will do the trick. But no, this is not the way it should be, I agree.
Can you try the patch below to see if it works more like what you'd expect?
Stefan
Index: lisp/t-mouse.el
===================================================================
RCS file: /sources/emacs/emacs/lisp/t-mouse.el,v
retrieving revision 1.21
diff -u -r1.21 t-mouse.el
--- lisp/t-mouse.el 6 May 2008 07:57:53 -0000 1.21
+++ lisp/t-mouse.el 10 Jun 2008 21:12:51 -0000
@@ -41,6 +41,27 @@
;; Prevent warning when compiling in an Emacs without gpm support.
(declare-function gpm-mouse-start "term.c" ())
+(defun gpm-mouse-enable ()
+ "Try to enable gpm mouse support on the current terminal."
+ (let ((activated nil))
+ (unwind-protect
+ (progn
+ (unless (fboundp 'gpm-mouse-start)
+ (error "Emacs must be built with Gpm to use this mode"))
+ (when gpm-mouse-mode
+ (gpm-mouse-start)
+ (set-terminal-parameter nil 'gpm-mouse-active t)
+ (setq activated t)))
+ ;; If something failed to turn it on, try to turn it off as well,
+ ;; just in case.
+ (unless activated (gpm-mouse-disable)))))
+
+(defun gpm-mouse-disable ()
+ "Try to disable gpm mouse support on the current terminal."
+ (when (fboundp 'gpm-mouse-stop)
+ (gpm-mouse-stop))
+ (set-terminal-parameter nil 'gpm-mouse-active nil))
+
;;;###autoload
(define-obsolete-function-alias 't-mouse-mode 'gpm-mouse-mode "23.1")
;;;###autoload
@@ -52,21 +73,14 @@
This allows the use of the mouse when operating on a GNU/Linux console,
in the same way as you can use the mouse under X11.
It relies on the `gpm' daemon being activated."
- :global t :group 'mouse
- (let ((activated nil))
- (unwind-protect
- (progn
- (unless (fboundp 'gpm-mouse-start)
- (error "Emacs must be built with Gpm to use this mode"))
- (when gpm-mouse-mode
- (gpm-mouse-start)
- (setq activated t)))
- ;; If the user asked to turn it off do that.
- ;; If something failed to turn it on, try to turn it off as well,
- ;; just in case.
- (when (and (fboundp 'gpm-mouse-stop) (not activated))
- (setq gpm-mouse-mode nil)
- (gpm-mouse-stop)))))
+ :global t :group 'mouse :init-value t
+ (dolist (terminal (terminal-list))
+ (when (and (eq t (terminal-live-p terminal))
+ (not (eq gpm-mouse-mode
+ (terminal-parameter terminal 'gpm-mouse-active))))
+ ;; Simulate selecting a terminal by selecting one of its frames ;-(
+ (with-selected-frame (car (frames-on-display-list terminal))
+ (if gpm-mouse-mode (gpm-mouse-enable) (gpm-mouse-disable))))))
(provide 't-mouse)
Index: lisp/term/linux.el
===================================================================
RCS file: /sources/emacs/emacs/lisp/term/linux.el,v
retrieving revision 1.13
diff -u -r1.13 linux.el
--- lisp/term/linux.el 7 Jun 2008 02:42:21 -0000 1.13
+++ lisp/term/linux.el 10 Jun 2008 21:12:51 -0000
@@ -9,7 +9,7 @@
;; It can't really display underlines.
(tty-no-underline)
- (ignore-errors (gpm-mouse-mode 1))
+ (ignore-errors (if gpm-mouse-mode (gpm-mouse-enable)))
;; Make Latin-1 input characters work, too.
;; Meta will continue to work, because the kernel