Re: Don't complain about changed file when it hasn't changed

[Stefan Monnier]

>> The patch below is supposed to change Emacs such that if the file's
>> timestamp has changed, but the contents is still the same, it doesn't
>> prompt the user about a supersession-threat.
>> Any objection?
> This sounds like a neat feature! Are you sure you want (point-min) and
> (point-max) rather than 1 and (buffer-size), though?

I hate this assumption that point-min is 1 (so much so that my own
local Emacs has point-min set to 12345678).  I dreamed of changing this
long-standing wart so that point-min starts at 0 but it would require
changes in the redisplay code which I was not able to figure out.

[ For the curious, the error of using 1 became blindly obvious when
  I did some work on src/intervals.c where we have things like
  interval_start_pos (that's right: 15 lines to decide if it starts
  with 0 or with 1).  ]

> Also, maybe this should be predicated on a test for small-enough files?
> For large-ish files, it could make things slow.

Presumably, this code is not run often and is normally followed by
a prompt to the user, so its acceptable time scale is fairly large.

If we want to speed it up, I think a more promising approach would be
for "visited-modtime" to keep not just the modtime but also the file
size, so we would only perform the (potentially slow)
insert-file-contents with the new file has the same size as the old.

Michael added:
> Same concern here, for remote files.  For large remote files I would
> prefer a cksum call, if possible.  But maybe we shall profile this, first.

Of course we can't cksum the buffer without first encoding it.  Also,
this would require a cksum on files.  Is there a reliably-available
cksum operation we could run on files?


        Stefan


PS: I just noticed a problem with the patch.  I need to set
coding-system-for-read around the insert-file-contents call, otherwise
we might fail to notice when the only change to the file is that it uses
another coding system.

>> diff --git a/lisp/userlock.el b/lisp/userlock.el
>> index a0c55fd..9b45ef4 100644
>> --- a/lisp/userlock.el
>> +++ b/lisp/userlock.el
>> @@ -97,6 +97,20 @@ ask-user-about-lock-help
>> 
>> (define-error 'file-supersession nil 'file-error)
>> 
>> +(defun userlock--check-content-unchanged (fn)
>> +  (save-restriction
>> +    (widen)
>> +    (let ((buf (current-buffer))
>> +          (start (point-min))
>> +          (end (point-max)))
>> +      (when (with-temp-buffer
>> +              (insert-file-contents fn)
>> +              (= 0 (compare-buffer-substrings
>> +                    buf start end
>> +                    (current-buffer) (point-min) (point-max))))
>> +        (set-visited-file-modtime)
>> +        'unchanged))))
>> +
>> ;;;###autoload
>> (defun ask-user-about-supersession-threat (fn)
>> "Ask a user who is about to modify an obsolete buffer what to do.
>> @@ -106,30 +120,30 @@ ask-user-about-supersession-threat
>> 
>> You can rewrite this to use any criterion you like to choose which one to do.
>> The buffer in question is current when this function is called."
>> -  (discard-input)
>> -  (save-window-excursion
>> -    (let ((prompt
>> -       (format "%s changed on disk; \
>> +  (unless (userlock--check-content-unchanged fn)
>> +    (discard-input)
>> +    (save-window-excursion
>> +      (let ((prompt
>> +             (format "%s changed on disk; \
>> really edit the buffer? (y, n, r or C-h) "
>> -               (file-name-nondirectory fn)))
>> -      (choices '(?y ?n ?r ?? ?\C-h))
>> -      answer)
>> -      (while (null answer)
>> -    (setq answer (read-char-choice prompt choices))
>> -    (cond ((memq answer '(?? ?\C-h))
>> -           (ask-user-about-supersession-help)
>> -           (setq answer nil))
>> -          ((eq answer ?r)
>> -           ;; Ask for confirmation if buffer modified
>> -           (revert-buffer nil (not (buffer-modified-p)))
>> -           (signal 'file-supersession
>> -                   (list "File reverted" fn)))
>> -          ((eq answer ?n)
>> -           (signal 'file-supersession
>> -                   (list "File changed on disk" fn)))))
>> -      (message
>> -       "File on disk now will become a backup file if you save these 
>> changes.")
>> -      (setq buffer-backed-up nil))))
>> +                     (file-name-nondirectory fn))))
>> +        (while
>> +            (let ((answer (read-char-choice prompt '(?y ?n ?r ?? ?\C-h))))
>> +              (cond ((memq answer '(?? ?\C-h))
>> +                     (ask-user-about-supersession-help)
>> +                     'repeat)
>> +                    ((eq answer ?r)
>> +                     ;; Ask for confirmation if buffer modified
>> +                     (revert-buffer nil (not (buffer-modified-p)))
>> +                     (signal 'file-supersession
>> +                             (list "File reverted" fn)))
>> +                    ((eq answer ?n)
>> +                     (signal 'file-supersession
>> +                             (list "File changed on disk" fn)))
>> +                    (t (null answer)))))
>> +        (message
>> +         "File on disk now will become a backup file if you save these 
>> changes.")
>> +        (setq buffer-backed-up nil)))))
>> 
>> (defun ask-user-about-supersession-help ()
>> (with-output-to-temp-buffer "*Help*"
>> 
>>