Re: RFC: major change to argument processing.

[Marius Vollmer]

Rob Browning <address@hidden> writes:

> Marius Vollmer <address@hidden> writes:
> 
> > I think so, yes.  The effort is not really that large (I think Rob has
> > already written it).
> 
> Yes.

Here is some code for the parser I have in mind, to make things
clearer.

    (define (read-quoted-argument)
      ;; gobble whittespace
      (let loop ((ch (read-char)))
        (cond ((eof-object? ch)
               ch)
              ((char-whitespace? ch)
               (loop (read-char)))
              (else
               ;; gather argument chars
               (let loop ((arg '())
                          (ch ch)
                          (state 'free))
                 (cond ((or (eof-object? ch)
                            (and (eq? state 'free) (char-whitespace? ch)))
                        (list->string (reverse! arg)))
                       ((and (not (eq? state 'single)) (eq? ch #\\))
                        (let ((ch (read-char)))
                          (if (eof-object? ch)
                              (error "escape at end of file"))
                          (loop (cons ch arg) (read-char) state)))
                       ((and (not (eq? state 'double)) (eq? ch #\'))
                        (loop arg (read-char)
                              (if (eq? state 'single) 'free 'single)))
                       ((and (not (eq? state 'single)) (eq? ch #\"))
                        (loop arg (read-char)
                              (if (eq? state 'double) 'free 'double)))
                       (else
                        (loop (cons ch arg) (read-char) state))))))))