[bug#27855] [PATCH] gnu: Add rsync service.

[Oleg Pykhalov]

>From 1ca5dab9f0a05205a85cc78d9a099bbe991ce884 Mon Sep 17 00:00:00 2001
From: Oleg Pykhalov <address@hidden>
Date: Thu, 27 Jul 2017 04:01:01 +0300
Subject: [PATCH] gnu: Add rsync service.

* doc/guix.texi (Incremental file transfer): Add documentation.
* gnu/services/rsync.scm (<rsync-configuration>): New record type.
(rsync-accounts, rsync-shepherd-service): New service extensions.
(rsync-service-type): New service type.
---
 doc/guix.texi          |  67 +++++++++++++++++++++++
 gnu/local.mk           |   1 +
 gnu/services/rsync.scm | 140 +++++++++++++++++++++++++++++++++++++++++++++++++
 3 files changed, 208 insertions(+)
 create mode 100644 gnu/services/rsync.scm

diff --git a/doc/guix.texi b/doc/guix.texi
index cda131557..cb5b59615 100644
--- a/doc/guix.texi
+++ b/doc/guix.texi
@@ -16528,6 +16528,73 @@ Extra options will be passed to @code{git daemon}, 
please run
 @end table
 @end deftp
 
address@hidden File transfer
+
+The @code{(gnu services rsync)} module provides the following services:
+
address@hidden Rsync service
+
+You might want an rsync daemon if you have files that you want available
+so anyone (or just yourself) can download existing files or upload new
+files.
+
address@hidden {Scheme Variable} rsync-service-type
+This is the type for the @uref{https://rsync.samba.org} rsync daemon,
address@hidden record as in this example:
+
address@hidden
+(service rsync-service-type
+         (rsync-configuration))
address@hidden example
+
+See below for details about @code{rsync-configuration}.
address@hidden deffn
+
address@hidden {Data Type} rsync-configuration
+Data type representing the configuration for @code{rsync-service}.
+
address@hidden @asis
address@hidden @code{package} (default: @var{rsync})
address@hidden package to use.
+
address@hidden @code{port-number} (default: @code{873})
+TCP port on which @command{rsync} listens for incoming connections.  If
+port is less than @code{1024} @command{rsync} will be started as the
address@hidden user and group.
+
address@hidden @code{pid-file} (default: @code{"/var/run/rsyncd.pid"})
+Name of the file where @command{rsync} writes its PID.
+
address@hidden @code{lock-file} (default: @code{"/var/run/rsyncd.lock"})
+Name of the file where @command{rsync} writes its lock file.
+
address@hidden @code{log-file} (default: @code{"/var/log/rsyncd.log"})
+Name of the file where @command{rsync} writes its log file.
+
address@hidden @code{use-choot?} (default: @var{#f})
+Whether to use chroot for @command{rsync} shared directory.
+
address@hidden @code{share-path} (default: @file{/srv/rsync})
+Location of the @command{rsync} shared directory.
+
address@hidden @code{share-comment} (default: @code{"Rsync share"})
+Comment of the @command{rsync} shared directory.
+
address@hidden @code{read-only?} (default: @var{#f})
+Read-write permissions to shared directory.
+
address@hidden @code{timeout} (default: @code{300})
+I/O timeout in seconds.
+
address@hidden @code{user} (default: @code{"rsyncd"})
+Privilege separation user.
+
address@hidden @code{group} (default: @code{"rsyncd"})
+Privilege separation group.
+
address@hidden table
address@hidden deftp
+
 @node Setuid Programs
 @subsection Setuid Programs
 
diff --git a/gnu/local.mk b/gnu/local.mk
index f48e6638b..bc445b731 100644
--- a/gnu/local.mk
+++ b/gnu/local.mk
@@ -445,6 +445,7 @@ GNU_SYSTEM_MODULES =                                \
   %D%/services/shepherd.scm                    \
   %D%/services/herd.scm                                \
   %D%/services/pm.scm                          \
+  %D%/services/rsync.scm                       \
   %D%/services/sddm.scm                                \
   %D%/services/spice.scm                               \
   %D%/services/ssh.scm                         \
diff --git a/gnu/services/rsync.scm b/gnu/services/rsync.scm
new file mode 100644
index 000000000..b5ba68291
--- /dev/null
+++ b/gnu/services/rsync.scm
@@ -0,0 +1,140 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2017 Oleg Pykhalov <address@hidden>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu services rsync)
+  #:use-module (gnu services)
+  #:use-module (gnu services base)
+  #:use-module (gnu services shepherd)
+  #:use-module (gnu system shadow)
+  #:use-module (gnu packages rsync)
+  #:use-module (gnu packages admin)
+  #:use-module (guix records)
+  #:use-module (guix gexp)
+  #:use-module (srfi srfi-1)
+  #:use-module (srfi srfi-26)
+  #:use-module (ice-9 match)
+  #:export (rsync-configuration
+            rsync-configuration?
+            rsync-service-type))
+
+;;;; Commentary:
+;;;
+;;; This module implements a service that to run instance of Rsync,
+;;; files synchronization tool.
+;;;
+;;;; Code:
+
+(define-record-type* <rsync-configuration>
+  rsync-configuration make-rsync-configuration
+  rsync-configuration?
+  (package       rsync-configuration-package ;package
+                 (default rsync))
+  (port-number   rsync-configuration-port-number ;integer
+                 (default 873))
+  (pid-file      rsync-configuration-pid-file ;string
+                 (default "/var/run/rsyncd.pid"))
+  (lock-file     rsync-configuration-lock-file ;string
+                 (default "/var/run/rsyncd.lock"))
+  (log-file      rsync-configuration-log-file ;string
+                 (default "/var/log/rsyncd.log"))
+  (use-chroot?   rsync-configuration-use-chroot? ;boolean
+                 (default #f))
+  (share-path    rsync-configuration-share-path ;string
+                 (default "/srv/rsync"))
+  (share-comment rsync-configuration-share-comment ;string
+                 (default "Rsync share"))
+  (read-only?    rsync-configuration-read-only? ;boolean
+                 (default #f))
+  (timeout       rsync-configuration-timeout ;integer
+                 (default 300))
+  (user          rsync-configuration-user ;string
+                 (default "rsyncd"))
+  (group         rsync-configuration-group ;string
+                 (default "rsyncd")))
+
+(define (rsync-account config)
+  "Return the user accounts and user groups for CONFIG."
+  (let ((rsync-user (rsync-configuration-user config))
+        (rsync-group (rsync-configuration-group config)))
+    (list (user-group (name "rsyncd") (system? #t))
+          (user-account
+           (name rsync-user)
+           (system? #t)
+           (group rsync-group)
+           (comment "rsyncd privilege separation user")
+           (home-directory "/var/run/rsyncd")
+           (shell #~(string-append #$shadow "/sbin/nologin"))))))
+
+(define (rsync-activation config)
+  "Return the activation GEXP for CONFIG."
+  #~(begin
+      (use-modules (guix build utils))
+      (let ((share-path #$(rsync-configuration-share-path config))
+            (user (getpw #$(rsync-configuration-user config)))
+            (group (getpw #$(rsync-configuration-group config))))
+        (and=> share-path mkdir-p)
+        (chown share-path
+               (passwd:uid user)
+               (group:gid group)))))
+
+(define (rsync-config-file config)
+  "Return the rsync configuration file corresponding to CONFIG."
+  (match config
+    (($ <rsync-configuration> package port-number pid-file
+                              lock-file log-file use-chroot? share-path
+                              share-comment read-only? timeout user group)
+     (mixed-text-file "rsync.conf"
+                      "pid file = " pid-file "\n"
+                      "lock file = " lock-file "\n"
+                      "log file = " log-file "\n"
+                      "port = " (number->string port-number) "\n"
+                      "use chroot = " (if use-chroot? "true" "false") "\n"
+                      "gid = " group "\n"
+                      "[files]\n"
+                      "path = " share-path "\n"
+                      "comment = " share-comment "\n"
+                      "read only = " (if read-only? "true" "false") "\n"
+                      "timeout = " (number->string timeout) "\n"))))
+
+(define (rsync-shepherd-service config)
+  "Return a <shepherd-service> for rsync with CONFIG."
+  (let* ((rsync (rsync-configuration-package config))
+         (pid-file (rsync-configuration-pid-file config))
+         (port (rsync-configuration-port-number config))
+         (user (if (> port  1024) (rsync-configuration-user config) "root"))
+         (group (if (> port  1024) (rsync-configuration-group config) "root")))
+    (list (shepherd-service
+           (provision '(rsync))
+           (documentation "Run rsync daemon.")
+           (start #~(make-forkexec-constructor
+                     (list (string-append #$rsync "/bin/rsync")
+                           "--config" #$(rsync-config-file config)
+                           "--daemon")
+                     #:pid-file #$pid-file
+                     #:user #$user
+                     #:group #$group))
+           (stop #~(make-kill-destructor))))))
+
+(define rsync-service-type
+  (service-type
+   (name 'rsync)
+   (extensions
+    (list (service-extension shepherd-root-service-type rsync-shepherd-service)
+          (service-extension account-service-type rsync-account)
+          (service-extension activation-service-type rsync-activation)))
+   (default-value (rsync-configuration))))
-- 
2.13.3