[bug#29719] [PATCH] gnu: virtualization: Add lookingglass.

[Ludovic Courtès]

Hello!

Rutger Helling <address@hidden> skribis:

> From ccea9a6c9dd71aea5ef5c07802f7e376a7f86a96 Mon Sep 17 00:00:00 2001
> From: Rutger Helling <address@hidden>
> Date: Fri, 15 Dec 2017 11:58:10 +0100
> Subject: [PATCH] gnu: virtualization: Add lookingglass.
>
> * gnu/packages/virtualization.scm (lookingglass): New variable.

[...]

> +(define-public lookingglass
> +  (package
> +   (name "lookingglass")

Please run:

  ./etc/indent-code.el gnu/packages/virtualization.scm lookingglass

> +   (version "a5")
> +   (source
> +    (origin
> +     (method url-fetch)
> +     (uri (string-append "https://github.com/gnif/LookingGlass/archive/";
> +                         version ".tar.gz"))
> +     (file-name (string-append name "-" version))
> +     (sha256
> +      (base32
> +       "0lrb821914fp27xaq0spwhbblssz55phiygvdlvcrkifa138v8pf"))))
> +   (build-system gnu-build-system)
> +   (inputs `(("fontconfig" ,fontconfig)
> +             ("glu" ,glu)
> +             ("mesa" ,mesa)
> +             ("openssl" ,openssl)
> +             ("sdl2" ,sdl2)
> +             ("sdl2-ttf" ,sdl2-ttf)
> +             ("spice-protocol" ,spice-protocol)))
> +   (native-inputs `(("pkg-config", pkg-config)))
> +   (arguments
> +    `(#:tests? #f ;; No tests are available.
> +      #:phases (modify-phases %standard-phases
> +                 (replace 'configure
> +                    (lambda* (#:key outputs #:allow-other-keys)
> +                      (chdir "client")))

Return #t.

> +                  (replace 'install
> +                    (lambda* (#:key outputs #:allow-other-keys)
> +                      (mkdir-p (string-append %output "/bin"))
> +                      (copy-file "bin/looking-glass-client" (string-append
> +                                 %output "/bin/looking-glass-client")))))))

Same here.

Use the ‘outputs’ argument instead of the ‘%output’ global variable.

Also, you can replace the mkdir-p/copy-file pair with just:

  (install-file "bin/looking-glass-client"
                (string-append (assoc-ref outputs "out") "/bin"))

> +   (home-page "https://looking-glass.hostfission.com";)
> +   (synopsis "Low-latency KVMFR implementation for QEMU guests with VGA PCI
> +passthrough")
> +   (description "LookingGlass is an extremely low latency KVMFR (KVM 
> FrameRelay)
> +implementation for QEMU guests with VGA PCI Passthrough.")

Could you shorten the synopsis and expound the description a little bit?
:-)  I find it hard to understand what this is about looking at this.

> +   (license gpl2)))

AFAICS source file headers explicitly say “or any later version”, so
this should be ‘gpl2+’.

The rest LGTM.  Could you send an updated patch?

Thank you!

Ludo’.