[Top][All Lists]
[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
Re: [GNU Autoconf 2.60] testsuite: 3 120 failed
From: |
Ralf Wildenhues |
Subject: |
Re: [GNU Autoconf 2.60] testsuite: 3 120 failed |
Date: |
Sun, 11 Feb 2007 14:36:28 +0100 |
User-agent: |
Mutt/1.5.13 (2006-08-11) |
Hi Peter,
Thanks for the quick review!
* Peter O'Gorman wrote on Sun, Feb 11, 2007 at 01:18:56PM CET:
> On Feb 11, 2007, at 6:33 PM, Ralf Wildenhues wrote:
>
> >OK to apply?
> >+m4_ifndef([_AS_TEST_PREPARE],
> >+[m4_defun([_AS_TEST_PREPARE],
> >+[as_executable_p="test -f"
> Could we test if test -x works and use that? I know that this is
> barely used, but it bugs me that test -f does not test for the
> executable bit :)
>
> I think autoconf has this:
CVS Autoconf has something quite a bit more elaborate. But I guess we
can at least do this much. I'm installing the patch below.
Note that it doesn't define $as_test_x.
Cheers,
Ralf
2007-02-11 Ralf Wildenhues <address@hidden>
* libtool.m4 (_AS_TEST_PREPARE, AS_EXECUTABLE_P): m4_defun
these macros, if undefined, with modified copies from Autoconf
2.59.
(LT_AC_PROG_SED): Use AS_EXECUTABLE_P, not $as_executable_p,
this is an internal Autoconf detail.
Index: libtool.m4
===================================================================
RCS file: /cvsroot/libtool/libtool/Attic/libtool.m4,v
retrieving revision 1.314.2.170
diff -u -r1.314.2.170 libtool.m4
--- libtool.m4 5 Feb 2007 19:40:53 -0000 1.314.2.170
+++ libtool.m4 11 Feb 2007 13:34:14 -0000
@@ -6483,6 +6483,30 @@
[AC_CHECK_TOOL(RC, windres, no)
])
+
+# Cheap backport of AS_EXECUTABLE_P and required macros
+# from Autoconf 2.59; we should not use $as_executable_p directly.
+
+# _AS_TEST_PREPARE
+# ----------------
+m4_ifndef([_AS_TEST_PREPARE],
+[m4_defun([_AS_TEST_PREPARE],
+[if test -x / >/dev/null 2>&1; then
+ as_executable_p='test -x'
+else
+ as_executable_p='test -f'
+fi
+])])# _AS_TEST_PREPARE
+
+# AS_EXECUTABLE_P
+# ---------------
+# Check whether a file is executable.
+m4_ifndef([AS_EXECUTABLE_P],
+[m4_defun([AS_EXECUTABLE_P],
+[AS_REQUIRE([_AS_TEST_PREPARE])dnl
+$as_executable_p $1[]dnl
+])])# AS_EXECUTABLE_P
+
############################################################
# NOTE: This macro has been submitted for inclusion into #
# GNU Autoconf as AC_PROG_SED. When it is available in #
@@ -6505,7 +6529,7 @@
test -z "$as_dir" && as_dir=.
for lt_ac_prog in sed gsed; do
for ac_exec_ext in '' $ac_executable_extensions; do
- if $as_executable_p "$as_dir/$lt_ac_prog$ac_exec_ext"; then
+ if AS_EXECUTABLE_P(["$as_dir/$lt_ac_prog$ac_exec_ext"]); then
lt_ac_sed_list="$lt_ac_sed_list $as_dir/$lt_ac_prog$ac_exec_ext"
fi
done