Re: new macro: AC_C_RESTRICT

[Jim Meyering]

Paul Eggert <address@hidden> wrote:
> Looks good, thanks.  However, could you please check for "__restrict"
> before "__restrict__"?  GCC supports either spelling, but "__restrict"
> is shorter and older DEC Alpha C compilers support only "__restrict".
> The handwritten "configure" script for MPlayer
> <http://www.mplayerhq.hu> checks for "__restrict" first, so this
> should be reliable.
>
> Also, please check for "_Restrict" as well.  That is the only spelling
> supported by Sun WorkShop 6 update 2 C.

Hi Paul,
Thanks for those suggestions.
Here's a new patch.

        * lib/autoconf/c.m4 (AC_C_RESTRICT): New macro.
        * doc/autoconf.texi (C Compiler): Describe AC_C_RESTRICT.

Index: doc/autoconf.texi
===================================================================
RCS file: /cvsroot/autoconf/autoconf/doc/autoconf.texi,v
retrieving revision 1.726
diff -u -p -u -p -r1.726 autoconf.texi
--- doc/autoconf.texi   28 Mar 2003 14:51:31 -0000      1.726
+++ doc/autoconf.texi   1 Apr 2003 21:34:43 -0000
@@ -5122,6 +5122,23 @@ installers who run into trouble in this 
 like GCC to compile their C code.
 @end defmac
 
address@hidden AC_C_RESTRICT
address@hidden C_RESTRICT
address@hidden volatile
+If the C compiler recognizes the @code{restrict} keyword, don't do anything.
+If it recognizes only a variant spelling (@code{__restrict},
address@hidden, or @code{_Restrict}), then define
address@hidden to that.
+Otherwise, define @code{restrict} to be empty.
+Thus, programs may simply use @code{restrict} as if every C compiler
+supported it; for those that do not, the @file{Makefile}
+or configuration header defines it away.
+
+Although support in C++ for the @code{restrict} keyword is not
+required, several C++ compilers do accept the keyword.
+This macro works for them, too.
address@hidden defmac
+
 @defmac AC_C_VOLATILE
 @acindex C_VOLATILE
 @cvindex volatile
Index: lib/autoconf/c.m4
===================================================================
RCS file: /cvsroot/autoconf/autoconf/lib/autoconf/c.m4,v
retrieving revision 1.175
diff -u -p -u -p -r1.175 c.m4
--- lib/autoconf/c.m4   6 Mar 2003 20:35:23 -0000       1.175
+++ lib/autoconf/c.m4   1 Apr 2003 21:34:44 -0000
@@ -1,6 +1,6 @@
 # This file is part of Autoconf.                       -*- Autoconf -*-
 # Programming languages support.
-# Copyright (C) 2001, 2002 Free Software Foundation, Inc.
+# Copyright (C) 2001, 2002, 2003 Free Software Foundation, Inc.
 #
 # This program is free software; you can redistribute it and/or modify
 # it under the terms of the GNU General Public License as published by
@@ -1075,6 +1075,40 @@ if test $ac_cv_c_const = no; then
             [Define to empty if `const' does not conform to ANSI C.])
 fi
 ])# AC_C_CONST
+
+
+# AC_C_RESTRICT
+# -------------
+# based on acx_restrict.m4, from the GNU Autoconf Macro Archive at:
+# http://www.gnu.org/software/ac-archive/htmldoc/acx_restrict.html
+#
+# Determine whether the C/C++ compiler supports the "restrict" keyword
+# introduced in ANSI C99, or an equivalent.  Do nothing if the compiler
+# accepts it.  Otherwise, if the compiler supports an equivalent,
+# define "restrict" to be that.  Here are some variants:
+# - GCC supports both __restrict and __restrict__
+# - older DEC Alpha C compilers support only __restrict
+# - _Restrict is the only spelling accepted by Sun WorkShop 6 update 2 C
+# Otherwise, define "restrict" to be empty.
+AC_DEFUN([AC_C_RESTRICT],
+[AC_CACHE_CHECK([for C/C++ restrict keyword], ac_cv_c_restrict,
+  [ac_cv_c_restrict=no
+   # Try the official restrict keyword, then gcc's __restrict__, and
+   # the less common variants.
+   for ac_kw in restrict __restrict __restrict__ _Restrict; do
+     AC_COMPILE_IFELSE([AC_LANG_SOURCE(
+      [float * $ac_kw x;])],
+      [ac_cv_c_restrict=$ac_kw; break])
+   done
+  ])
+ case $ac_cv_c_restrict in
+   restrict) ;;
+   no) AC_DEFINE(restrict,,
+        [Define to equivalent of C99 restrict keyword, or to nothing if this
+        is not supported.  Do not define if restrict is supported directly.]) 
;;
+   *)  AC_DEFINE_UNQUOTED(restrict, $ac_cv_c_restrict) ;;
+ esac
+])# AC_C_RESTRICT
 
 
 # AC_C_VOLATILE