%{
#define YYSTYPE double

#include <math.h>
#include <stdio.h>
#include <ctype.h>
%}

%glr_parser
%debug

/* BISON Declarations */
%token NUM
%left '-' '+'
%left '*' '/'
%left NEG     /* negation--unary minus */
%right '^'    /* exponentiation        */

/* Grammar follows */
%%
input:    /* empty string */
| input line
;

line:     '\n'
| exp '\n'  { printf ("\t%.10g\n", $1); }
;

exp:      NUM                { $$ = $1;         }
| exp '+' exp        { $$ = $1 + $3;    }
| exp '-' exp        { $$ = $1 - $3;    }
| exp '*' exp        { $$ = $1 * $3;    }
| exp '/' exp        { $$ = $1 / $3;    }
| '-' exp  %prec NEG { $$ = -$2;        }
| exp '^' exp        { $$ = pow ($1, $3); }
| '(' exp ')'        { $$ = $2;         }
;
%%


int
yyerror (const char *s)  /* Called by yyparse on error */
{
  printf ("%s\n", s);
  return 0;
}


int
yylex (void)
{
  int c;

  /* skip white space  */
  while ((c = getchar ()) == ' ' || c == '\t')
    ;
  /* process numbers   */
  if (c == '.' || isdigit (c))
    {
      ungetc (c, stdin);
      scanf ("%lf", &yylval);
      return NUM;
    }
  /* return end-of-file  */
  if (c == EOF)
    return 0;
  /* return single chars */
  return c;
}

int main(void)
{
  yydebug = 1;
  return yyparse ();
}