[Top][All Lists]
[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
[PATCH] improve M4 quoting
|
From: |
Jim Meyering |
|
Subject: |
[PATCH] improve M4 quoting |
|
Date: |
Tue, 30 Dec 2008 19:27:38 +0100 |
* configure.ac: Add quotes.
* gl/m4/mgetgroups.m4 (gl_MGETGROUPS): Likewise.
* m4/boottime.m4 (GNULIB_BOOT_TIME): Likewise.
* m4/check-decl.m4 (gl_CHECK_DECLS): Likewise.
* m4/gmp.m4 (cu_GMP): Likewise.
* m4/jm-macros.m4 (coreutils_MACROS, gl_CHECK_ALL_HEADERS): Likewise.
(gl_CHECK_ALL_TYPES): Likewise.
* m4/lib-check.m4 (cu_LIB_CHECK): Likewise.
* m4/stat-prog.m4 (cu_PREREQ_STAT_PROG): Likewise.
FYI, I first ran this command:
git ls-files | grep -E '\.(m4|ac)$' | xargs perl -pi \
-e 's/(AC_[A-Z_]+\()([^[()]+?)([,)])/$1\[$2]$3/g;' \
-e 's/(AC_[A-Z_]+\(\[[^,]+?\], )([^,[()]+?)([,)])/$1\[$2]$3/g;' \
-e 's/(AC_[A-Z_]+\((?:\[[^,]+?\], ){2})([^,[()]+?)([,)])/$1\[$2]$3/g'
Then I updated serial numbers and copyright dates manually.
Also, I manually added two pairs of quotes in boottime.m4.
---
I've pushed this to next.
Thus begins my automatic-m4-quoting crusade ;-)
I'll soon apply the above command to gnulib, since
it seems to do the right thing, modulo one glitch in a comment.
configure.ac | 78 +++++++++++++++++++++++++-------------------------
gl/m4/mgetgroups.m4 | 4 +-
m4/boottime.m4 | 16 +++++-----
m4/check-decl.m4 | 6 ++--
m4/gmp.m4 | 2 +-
m4/jm-macros.m4 | 24 ++++++++--------
m4/lib-check.m4 | 22 +++++++-------
m4/stat-prog.m4 | 8 ++--
8 files changed, 80 insertions(+), 80 deletions(-)
diff --git a/configure.ac b/configure.ac
index 6e5b5b6..99452c8 100644
--- a/configure.ac
+++ b/configure.ac
@@ -18,7 +18,7 @@
dnl Written by Jim Meyering.
-AC_PREREQ(2.61)
+AC_PREREQ([2.61])
# Make inter-release version strings look like, e.g., v6.9-219-g58ddd, which
# indicates that it is built from the 219th delta (in _some_ repository)
@@ -27,9 +27,9 @@ AC_INIT([GNU coreutils],
m4_esyscmd([build-aux/git-version-gen .tarball-version]),
address@hidden)
-AC_CONFIG_SRCDIR(src/ls.c)
+AC_CONFIG_SRCDIR([src/ls.c])
-AC_CONFIG_AUX_DIR(build-aux)
+AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
AM_INIT_AUTOMAKE([1.10a dist-xz])
@@ -72,25 +72,25 @@ if test "$gl_gcc_warnings" = yes; then
gl_WARN_ADD([-Wmissing-prototypes])
gl_WARN_ADD([-Wstrict-prototypes])
AC_SUBST([WARN_CFLAGS])
- AC_DEFINE([lint], 1, [Define to 1 if the compiler is checking for lint.])
- AC_DEFINE([_FORTIFY_SOURCE], 2,
+ AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
+ AC_DEFINE([_FORTIFY_SOURCE], [2],
[enable compile-time and run-time bounds-checking, and some warnings])
fi
AC_FUNC_FORK
optional_bin_progs=
-AC_CHECK_FUNCS(uname,
+AC_CHECK_FUNCS([uname],
gl_ADD_PROG([optional_bin_progs], [uname]))
-AC_CHECK_FUNCS(chroot,
+AC_CHECK_FUNCS([chroot],
gl_ADD_PROG([optional_bin_progs], [chroot]))
-AC_CHECK_FUNCS(gethostid,
+AC_CHECK_FUNCS([gethostid],
gl_ADD_PROG([optional_bin_progs], [hostid]))
gl_WINSIZE_IN_PTEM
-AC_MSG_CHECKING(whether localtime caches TZ)
-AC_CACHE_VAL(utils_cv_localtime_cache,
+AC_MSG_CHECKING([whether localtime caches TZ])
+AC_CACHE_VAL([utils_cv_localtime_cache],
[if test x$ac_cv_func_tzset = xyes; then
AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
#if STDC_HEADERS
@@ -131,22 +131,22 @@ else
# since we can't invalidate the cache if we don't have tzset.
utils_cv_localtime_cache=no
fi])dnl
-AC_MSG_RESULT($utils_cv_localtime_cache)
+AC_MSG_RESULT([$utils_cv_localtime_cache])
if test $utils_cv_localtime_cache = yes; then
- AC_DEFINE([LOCALTIME_CACHE], 1, [FIXME])
+ AC_DEFINE([LOCALTIME_CACHE], [1], [FIXME])
fi
# SCO-ODT-3.0 is reported to need -los to link programs using initgroups
-AC_CHECK_FUNCS(initgroups)
+AC_CHECK_FUNCS([initgroups])
if test $ac_cv_func_initgroups = no; then
- AC_CHECK_LIB(os, initgroups)
+ AC_CHECK_LIB([os], [initgroups])
fi
-AC_CHECK_FUNCS(syslog)
+AC_CHECK_FUNCS([syslog])
if test $ac_cv_func_syslog = no; then
# syslog is not in the default libraries. See if it's in some other.
for lib in bsd socket inet; do
- AC_CHECK_LIB($lib, syslog, [AC_DEFINE([HAVE_SYSLOG], 1, [FIXME])
+ AC_CHECK_LIB([$lib], [syslog], [AC_DEFINE([HAVE_SYSLOG], [1], [FIXME])
LIBS="$LIBS -l$lib"; break])
done
fi
@@ -180,29 +180,29 @@ AC_DEFUN([coreutils_DUMMY_1],
])
coreutils_DUMMY_1
-AC_MSG_CHECKING(ut_host in struct utmp)
-AC_CACHE_VAL(su_cv_func_ut_host_in_utmp,
+AC_MSG_CHECKING([ut_host in struct utmp])
+AC_CACHE_VAL([su_cv_func_ut_host_in_utmp],
[AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
#include <utmp.h>]], [[struct utmp ut; return !sizeof ut.ut_host;]])],
[su_cv_func_ut_host_in_utmp=yes],
[su_cv_func_ut_host_in_utmp=no])])
-AC_MSG_RESULT($su_cv_func_ut_host_in_utmp)
+AC_MSG_RESULT([$su_cv_func_ut_host_in_utmp])
if test $su_cv_func_ut_host_in_utmp = yes; then
have_ut_host=1
- AC_DEFINE([HAVE_UT_HOST], 1, [FIXME])
+ AC_DEFINE([HAVE_UT_HOST], [1], [FIXME])
fi
if test -z "$have_ut_host"; then
- AC_MSG_CHECKING(ut_host in struct utmpx)
- AC_CACHE_VAL(su_cv_func_ut_host_in_utmpx,
+ AC_MSG_CHECKING([ut_host in struct utmpx])
+ AC_CACHE_VAL([su_cv_func_ut_host_in_utmpx],
[AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
#include <utmpx.h>]], [[struct utmpx ut; return !sizeof ut.ut_host;]])],
[su_cv_func_ut_host_in_utmpx=yes],
[su_cv_func_ut_host_in_utmpx=no])])
- AC_MSG_RESULT($su_cv_func_ut_host_in_utmpx)
+ AC_MSG_RESULT([$su_cv_func_ut_host_in_utmpx])
if test $su_cv_func_ut_host_in_utmpx = yes; then
- AC_DEFINE([HAVE_UTMPX_H], 1, [FIXME])
- AC_DEFINE([HAVE_UT_HOST], 1, [FIXME])
+ AC_DEFINE([HAVE_UTMPX_H], [1], [FIXME])
+ AC_DEFINE([HAVE_UT_HOST], [1], [FIXME])
fi
fi
@@ -214,24 +214,24 @@ gl_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
if test $ac_cv_sys_posix_termios = yes; then
gl_ADD_PROG([optional_bin_progs], [stty])
- AC_MSG_CHECKING(whether termios.h needs _XOPEN_SOURCE)
- AC_CACHE_VAL(su_cv_sys_termios_needs_xopen_source,
- [AC_EGREP_CPP(yes, [#include <termios.h>
+ AC_MSG_CHECKING([whether termios.h needs _XOPEN_SOURCE])
+ AC_CACHE_VAL([su_cv_sys_termios_needs_xopen_source],
+ [AC_EGREP_CPP([yes], [#include <termios.h>
#ifdef IUCLC
yes
#endif], su_cv_sys_termios_needs_xopen_source=no,
- AC_EGREP_CPP(yes, [#define _XOPEN_SOURCE
+ AC_EGREP_CPP([yes], [#define _XOPEN_SOURCE
#include <termios.h>
#ifdef IUCLC
yes
#endif], su_cv_sys_termios_needs_xopen_source=yes,
su_cv_sys_termios_needs_xopen_source=no))])
- AC_MSG_RESULT($su_cv_sys_termios_needs_xopen_source)
+ AC_MSG_RESULT([$su_cv_sys_termios_needs_xopen_source])
test $su_cv_sys_termios_needs_xopen_source = yes &&
- AC_DEFINE([TERMIOS_NEEDS_XOPEN_SOURCE], 1, [FIXME])
+ AC_DEFINE([TERMIOS_NEEDS_XOPEN_SOURCE], [1], [FIXME])
- AC_MSG_CHECKING(c_line in struct termios)
- AC_CACHE_VAL(su_cv_sys_c_line_in_termios,
+ AC_MSG_CHECKING([c_line in struct termios])
+ AC_CACHE_VAL([su_cv_sys_c_line_in_termios],
[AC_LINK_IFELSE([AC_LANG_PROGRAM([[#if TERMIOS_NEEDS_XOPEN_SOURCE
#define _XOPEN_SOURCE
#endif
@@ -239,9 +239,9 @@ yes
#include <termios.h>]], [[struct termios t; return !sizeof t.c_line;]])],
[su_cv_sys_c_line_in_termios=yes],
[su_cv_sys_c_line_in_termios=no])])
- AC_MSG_RESULT($su_cv_sys_c_line_in_termios)
+ AC_MSG_RESULT([$su_cv_sys_c_line_in_termios])
test $su_cv_sys_c_line_in_termios = yes \
- && AC_DEFINE([HAVE_C_LINE], 1, [FIXME])
+ && AC_DEFINE([HAVE_C_LINE], [1], [FIXME])
fi
# FIXME: note that this macro appears above, too.
@@ -252,8 +252,8 @@ gl_HEADER_TIOCGWINSZ_IN_TERMIOS_H
if test $gl_cv_sys_tiocgwinsz_needs_termios_h = no && \
test $gl_cv_sys_tiocgwinsz_needs_sys_ioctl_h = no; then
- AC_MSG_CHECKING(TIOCGWINSZ in sys/pty.h)
- AC_CACHE_VAL(su_cv_sys_tiocgwinsz_in_sys_pty_h,
+ AC_MSG_CHECKING([TIOCGWINSZ in sys/pty.h])
+ AC_CACHE_VAL([su_cv_sys_tiocgwinsz_in_sys_pty_h],
[AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
#ifdef WINSIZE_IN_PTEM
# include <sys/stream.h>
@@ -264,10 +264,10 @@ if test $gl_cv_sys_tiocgwinsz_needs_termios_h = no && \
#include <sys/pty.h>]], [[int x = TIOCGWINSZ;]])],
[su_cv_sys_tiocgwinsz_in_sys_pty_h=yes],
[su_cv_sys_tiocgwinsz_in_sys_pty_h=no])])
- AC_MSG_RESULT($su_cv_sys_tiocgwinsz_in_sys_pty_h)
+ AC_MSG_RESULT([$su_cv_sys_tiocgwinsz_in_sys_pty_h])
test $su_cv_sys_tiocgwinsz_in_sys_pty_h = yes \
- && AC_DEFINE([GWINSZ_IN_SYS_PTY], 1,
+ && AC_DEFINE([GWINSZ_IN_SYS_PTY], [1],
[Define if your system defines TIOCGWINSZ in sys/pty.h.])
fi
diff --git a/gl/m4/mgetgroups.m4 b/gl/m4/mgetgroups.m4
index da55731..f70f5b9 100644
--- a/gl/m4/mgetgroups.m4
+++ b/gl/m4/mgetgroups.m4
@@ -1,4 +1,4 @@
-#serial 2
+#serial 3
dnl Copyright (C) 2007-2008 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
@@ -6,6 +6,6 @@ dnl with or without modifications, as long as this notice is
preserved.
AC_DEFUN([gl_MGETGROUPS],
[
- AC_CHECK_FUNCS(getgrouplist)
+ AC_CHECK_FUNCS([getgrouplist])
AC_LIBOBJ([mgetgroups])
])
diff --git a/m4/boottime.m4 b/m4/boottime.m4
index 863eb02..ca4b85e 100644
--- a/m4/boottime.m4
+++ b/m4/boottime.m4
@@ -1,7 +1,7 @@
-# boottime.m4 serial 3
+# boottime.m4 serial 4
# Determine whether this system has infrastructure for obtaining the boot time.
-# Copyright (C) 1996, 2000, 2002, 2003, 2004, 2006 Free Software Foundation,
Inc.
+# Copyright (C) 1996, 2000, 2002-2004, 2006, 2008 Free Software Foundation,
Inc.
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
@@ -20,14 +20,14 @@
* ----------------------------------------------------------
AC_DEFUN([GNULIB_BOOT_TIME],
[
- AC_CHECK_FUNCS(sysctl)
- AC_CHECK_HEADERS_ONCE(sys/param.h)
- AC_CHECK_HEADERS(sys/sysctl.h, [], [],
+ AC_CHECK_FUNCS([sysctl])
+ AC_CHECK_HEADERS_ONCE([sys/param.h])
+ AC_CHECK_HEADERS([sys/sysctl.h], [], [],
[AC_INCLUDES_DEFAULT
[#if HAVE_SYS_PARAM_H
#include <sys/param.h>
#endif]])
- AC_CHECK_HEADERS_ONCE(utmp.h utmpx.h OS.h)
+ AC_CHECK_HEADERS_ONCE([utmp.h utmpx.h OS.h])
AC_CACHE_CHECK(
[whether we can get the system boot time],
[gnulib_cv_have_boot_time],
@@ -57,8 +57,8 @@ AC_DEFUN([GNULIB_BOOT_TIME],
please_tell_us_how_to_determine_boot_time_on_your_system
#endif
]])],
- gnulib_cv_have_boot_time=yes,
- gnulib_cv_have_boot_time=no)
+ [gnulib_cv_have_boot_time=yes],
+ [gnulib_cv_have_boot_time=no])
])
AS_IF([test $gnulib_cv_have_boot_time = yes], [$1], [$2])
])
diff --git a/m4/check-decl.m4 b/m4/check-decl.m4
index d520352..e2d20f3 100644
--- a/m4/check-decl.m4
+++ b/m4/check-decl.m4
@@ -1,7 +1,7 @@
-#serial 23
+#serial 24
# Check declarations for this package.
-dnl Copyright (C) 1997, 1998, 1999, 2000, 2001, 2003, 2004, 2005, 2006
+dnl Copyright (C) 1997-2001, 2003-2006, 2008
dnl Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
@@ -16,7 +16,7 @@ AC_DEFUN([gl_CHECK_DECLS],
[
AC_REQUIRE([AC_HEADER_TIME])
- AC_CHECK_HEADERS_ONCE(grp.h pwd.h)
+ AC_CHECK_HEADERS_ONCE([grp.h pwd.h])
headers='
#include <sys/types.h>
diff --git a/m4/gmp.m4 b/m4/gmp.m4
index 3e6033d..8cb26c4 100644
--- a/m4/gmp.m4
+++ b/m4/gmp.m4
@@ -28,7 +28,7 @@ AC_DEFUN([cu_GMP],
[test "$ac_cv_search___gmpz_init" = "none required" ||
{
LIB_GMP=$ac_cv_search___gmpz_init
- AC_DEFINE([HAVE_GMP], 1,
+ AC_DEFINE([HAVE_GMP], [1],
[Define if you have GNU libgmp (or replacement)])
}])
LIBS=$cu_saved_libs
diff --git a/m4/jm-macros.m4 b/m4/jm-macros.m4
index 38e19fc..335ec24 100644
--- a/m4/jm-macros.m4
+++ b/m4/jm-macros.m4
@@ -1,4 +1,4 @@
-#serial 107 -*- autoconf -*-
+#serial 108 -*- autoconf -*-
dnl Misc type-related macros for coreutils.
@@ -22,7 +22,7 @@ dnl Misc type-related macros for coreutils.
AC_DEFUN([coreutils_MACROS],
[
AM_MISSING_PROG(HELP2MAN, help2man)
- AC_SUBST(MAN)
+ AC_SUBST([MAN])
dnl This macro actually runs replacement code. See isc-posix.m4.
AC_REQUIRE([AC_ISC_POSIX])dnl
@@ -44,7 +44,7 @@ AC_DEFUN([coreutils_MACROS],
# used by ls
AC_REQUIRE([gl_CLOCK_TIME])
# used by shred
- AC_CHECK_FUNCS_ONCE(directio)
+ AC_CHECK_FUNCS_ONCE([directio])
# Used by install.c.
AC_CHECK_FUNCS_ONCE([matchpathcon_init_prefix])
@@ -79,7 +79,7 @@ AC_DEFUN([coreutils_MACROS],
[test "$ac_cv_search_fdatasync" = "none required" ||
LIB_FDATASYNC=$ac_cv_search_fdatasync])
AC_SUBST([LIB_FDATASYNC])
- AC_CHECK_FUNCS(fdatasync)
+ AC_CHECK_FUNCS([fdatasync])
LIBS=$coreutils_saved_libs
# Check whether libcap is usable -- for ls --color support
@@ -89,7 +89,7 @@ AC_DEFUN([coreutils_MACROS],
[AC_CHECK_LIB([cap], [cap_get_file],
[AC_CHECK_HEADER([sys/capability.h],
[LIB_CAP=-lcap
- AC_DEFINE([HAVE_CAP], 1, [libcap usability])],
+ AC_DEFINE([HAVE_CAP], [1], [libcap usability])],
[AC_MSG_WARN([header sys/capability.h was not found, support for libcap
will not be built])]
)],
[AC_MSG_WARN([libcap library was not found or not usable, support for
libcap will not be built])])
@@ -101,16 +101,16 @@ AC_DEFUN([coreutils_MACROS],
# BeOS which has all the math functions in the normal runtime library
# and doesn't have a separate math library.
- AC_SUBST(SEQ_LIBM)
+ AC_SUBST([SEQ_LIBM])
ac_seq_body='
static double x, y;
x = floor (x);
x = rint (x);
x = modf (x, &y);'
- AC_TRY_LINK([#include <math.h>], $ac_seq_body, ,
+ AC_TRY_LINK([#include <math.h>], [$ac_seq_body], ,
[ac_seq_save_LIBS="$LIBS"
LIBS="$LIBS -lm"
- AC_TRY_LINK([#include <math.h>], $ac_seq_body, SEQ_LIBM=-lm)
+ AC_TRY_LINK([#include <math.h>], [$ac_seq_body], [SEQ_LIBM=-lm])
LIBS="$ac_seq_save_LIBS"
])
@@ -133,7 +133,7 @@ AC_DEFUN([gl_CHECK_ALL_HEADERS],
syslog.h \
termios.h \
)
- AC_CHECK_HEADERS(sys/sysctl.h, [], [],
+ AC_CHECK_HEADERS([sys/sysctl.h], [], [],
[AC_INCLUDES_DEFAULT
[#if HAVE_SYS_PARAM_H
#include <sys/param.h>
@@ -174,12 +174,12 @@ AC_DEFUN([gl_CHECK_ALL_TYPES],
AC_REQUIRE([AC_TYPE_PID_T])
AC_REQUIRE([AC_TYPE_SIZE_T])
AC_REQUIRE([AC_TYPE_UID_T])
- AC_CHECK_TYPE(ino_t, unsigned long int)
+ AC_CHECK_TYPE([ino_t], [unsigned long int])
dnl This relies on the fact that Autoconf's implementation of
dnl AC_CHECK_TYPE checks includes unistd.h.
- AC_CHECK_TYPE(major_t, unsigned int)
- AC_CHECK_TYPE(minor_t, unsigned int)
+ AC_CHECK_TYPE([major_t], [unsigned int])
+ AC_CHECK_TYPE([minor_t], [unsigned int])
AC_REQUIRE([AC_HEADER_MAJOR])
])
diff --git a/m4/lib-check.m4 b/m4/lib-check.m4
index fe36076..b2d8d96 100644
--- a/m4/lib-check.m4
+++ b/m4/lib-check.m4
@@ -1,9 +1,9 @@
-#serial 10
+#serial 11
dnl Misc lib-related macros for coreutils.
-# Copyright (C) 1993, 1994, 1995, 1996, 1997, 2000, 2001, 2003, 2004,
-# 2005, 2006 Free Software Foundation, Inc.
+# Copyright (C) 1993-1997, 2000-2001, 2003-2006, 2008
+# Free Software Foundation, Inc.
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
@@ -24,20 +24,20 @@ AC_DEFUN([cu_LIB_CHECK],
[
# Check for libypsec.a on Dolphin M88K machines.
- AC_CHECK_LIB(ypsec, main)
+ AC_CHECK_LIB([ypsec], [main])
# m88k running dgux 5.4 needs this
- AC_CHECK_LIB(ldgc, main)
+ AC_CHECK_LIB([ldgc], [main])
# The -lsun library is required for YP support on Irix-4.0.5 systems.
# m88k/svr3 DolphinOS systems using YP need -lypsec for id.
- AC_SEARCH_LIBS(yp_match, [sun ypsec])
+ AC_SEARCH_LIBS([yp_match], [sun ypsec])
# SysV needs -lsec, older versions of Linux need -lshadow for
# shadow passwords. UnixWare 7 needs -lgen.
- AC_SEARCH_LIBS(getspnam, [shadow sec gen])
+ AC_SEARCH_LIBS([getspnam], [shadow sec gen])
- AC_CHECK_HEADERS(shadow.h)
+ AC_CHECK_HEADERS([shadow.h])
# Requirements for su.c.
shadow_includes="\
@@ -47,14 +47,14 @@ $ac_includes_default
#endif
"
AC_CHECK_MEMBERS([struct spwd.sp_pwdp],,,[$shadow_includes])
- AC_CHECK_FUNCS(getspnam)
+ AC_CHECK_FUNCS([getspnam])
# SCO-ODT-3.0 is reported to need -lufc for crypt.
# NetBSD needs -lcrypt for crypt.
cu_saved_libs="$LIBS"
- AC_SEARCH_LIBS(crypt, [ufc crypt],
+ AC_SEARCH_LIBS([crypt], [ufc crypt],
[test "$ac_cv_search_crypt" = "none required" ||
LIB_CRYPT="$ac_cv_search_crypt"])
LIBS="$cu_saved_libs"
- AC_SUBST(LIB_CRYPT)
+ AC_SUBST([LIB_CRYPT])
])
diff --git a/m4/stat-prog.m4 b/m4/stat-prog.m4
index b4caadd..c2620b9 100644
--- a/m4/stat-prog.m4
+++ b/m4/stat-prog.m4
@@ -1,7 +1,7 @@
-# stat-prog.m4 serial 5
+# stat-prog.m4 serial 6
# Record the prerequisites of src/stat.c from the coreutils package.
-# Copyright (C) 2002, 2003, 2004, 2006 Free Software Foundation, Inc.
+# Copyright (C) 2002-2004, 2006, 2008 Free Software Foundation, Inc.
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
@@ -68,7 +68,7 @@ AC_INCLUDES_DEFAULT
[$statvfs_includes],
[static statvfs s;
return (s.s_fsid ^ 0) == 0;])],
- [AC_DEFINE([STRUCT_STATVFS_F_FSID_IS_INTEGER], 1,
+ [AC_DEFINE([STRUCT_STATVFS_F_FSID_IS_INTEGER], [1],
[Define to 1 if the f_fsid member of struct statvfs is an integer.])])
else
AC_CHECK_MEMBERS([struct statfs.f_namelen, struct statfs.f_type],,,
@@ -79,7 +79,7 @@ AC_INCLUDES_DEFAULT
[$statfs_includes],
[static statfs s;
return (s.s_fsid ^ 0) == 0;])],
- [AC_DEFINE([STRUCT_STATFS_F_FSID_IS_INTEGER], 1,
+ [AC_DEFINE([STRUCT_STATFS_F_FSID_IS_INTEGER], [1],
[Define to 1 if the f_fsid member of struct statfs is an integer.])])
fi
fi
--
1.6.1.302.gccd4d
| [Prev in Thread] |
Current Thread |
[Next in Thread] |
- [PATCH] improve M4 quoting,
Jim Meyering <=