[Top][All Lists]
[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
[Eliot-dev] eliot ./configure.in m4/wxwin.m4 [multibyte]
|
From: |
eliot-dev |
|
Subject: |
[Eliot-dev] eliot ./configure.in m4/wxwin.m4 [multibyte] |
|
Date: |
Wed, 28 Dec 2005 20:45:32 +0000 |
CVSROOT: /sources/eliot
Module name: eliot
Branch: multibyte
Changes by: Olivier Teulière <address@hidden> 05/12/28 20:45:32
Modified files:
. : configure.in
m4 : wxwin.m4
Log message:
Require the unicode build of wxWidgets
CVSWeb URLs:
http://cvs.savannah.gnu.org/viewcvs/eliot/eliot/configure.in.diff?only_with_tag=multibyte&tr1=1.14&tr2=1.14.2.1&r1=text&r2=text
http://cvs.savannah.gnu.org/viewcvs/eliot/eliot/m4/wxwin.m4.diff?only_with_tag=multibyte&tr1=1.1&tr2=1.1.4.1&r1=text&r2=text
Patches:
Index: eliot/configure.in
diff -u /dev/null eliot/configure.in:1.14.2.1
--- /dev/null Wed Dec 28 20:45:32 2005
+++ eliot/configure.in Wed Dec 28 20:45:32 2005
@@ -0,0 +1,137 @@
+dnl -*-m4-*-
+dnl Process this file with autoconf to produce a configure script.
+dnl --------------------------------------------------------------
+dnl configure.in for Eliot
+dnl --------------------------------------------------------------
+AC_INIT(eliot, 1.5)
+AC_CONFIG_SRCDIR(wxwin/main.cc)
+AM_INIT_AUTOMAKE
+AM_CONFIG_HEADER(config.h)
+AM_OPTIONS_WXCONFIG
+
+dnl --------------------------------------------------------------
+dnl Checks for programs.
+dnl --------------------------------------------------------------
+AC_PROG_INSTALL
+AC_PROG_CC
+AC_PROG_CXX
+AC_PROG_MAKE_SET
+AC_PROG_RANLIB
+
+dnl --------------------------------------------------------------
+dnl Checks for compilation flags
+dnl --------------------------------------------------------------
+CFLAGS_save="${CFLAGS}"
+AC_CACHE_CHECK([if \$CC accepts -Wall],
+ [ac_cv_c_Wall],
+ [CFLAGS="-Wall ${CFLAGS_save}"
+ AC_TRY_COMPILE([],,ac_cv_c_Wall=yes, ac_cv_c_Wall=no)])
+CFLAGS="${CFLAGS_save}"
+if test "${ac_cv_c_Wall}" != "no"; then
+ CFLAGS="-Wall ${CFLAGS}"
+ CXXFLAGS="-Wall ${CXXFLAGS}"
+fi
+
+dnl Debug mode
+AC_ARG_ENABLE(debug,
+[ --enable-debug debug mode (default enabled)])
+if test "${enable_debug}" != "no"; then
+ CPPFLAGS="${CPPFLAGS} -DDEBUG"
+ dnl CFLAGS="${CFLAGS} -O0"
+ dnl CXXFLAGS="${CXXFLAGS} -O0"
+fi
+
+dnl Regexp build
+AC_ARG_ENABLE(dictools,
+[ --enable-dictools build independant dictionary tools (default
enabled)])
+AM_PROG_LEX
+AC_PROG_YACC
+AM_CONDITIONAL([BUILD_DICTOOLS], [test "${enable_dictools}" != "no"])
+
+dnl --------------------------------------------------------------
+dnl Checks for header files.
+dnl --------------------------------------------------------------
+AC_HEADER_STDC
+AC_CHECK_HEADERS(fcntl.h unistd.h sys/wait.h)
+
+dnl --------------------------------------------------------------
+dnl Checks for typedefs, structures, and compiler characteristics.
+dnl --------------------------------------------------------------
+AC_C_CONST
+AC_TYPE_SIZE_T
+dnl AC_C_BIGENDIAN
+AC_C_INLINE
+AC_CHECK_SIZEOF(char, 1)
+AC_CHECK_SIZEOF(short, 2)
+AC_CHECK_SIZEOF(int *, 4)
+AC_CHECK_SIZEOF(int, 4)
+AC_CHECK_SIZEOF(long, 4)
+AC_CHECK_SIZEOF(long long, 0)
+
+dnl --------------------------------------------------------------
+dnl Checks for library functions.
+dnl --------------------------------------------------------------
+AC_FUNC_MEMCMP
+
+dnl --------------------------------------------------------------
+dnl Checks for libraries.
+dnl --------------------------------------------------------------
+
+dnl Check for wxWidgets
+AC_ARG_ENABLE(wxwidgets,
+[ --enable-wxwidgets wxWidgets interface support (default disabled)])
+if test "${enable_wxwidgets}" = "yes"
+then
+ AM_PATH_WXCONFIG([2.4.0], [wxwin=1], [wxwin=0], [], [--unicode])
+ if test "${wxwin}" != 1; then
+ AC_MSG_ERROR([
+ wxWidgets (unicode build) must be installed on your system
+ but wx-config script couldn't be found.
+
+ Please check that wx-config is in path, the directory
+ where wxWidgets libraries are installed (returned by
+ 'wx-config --libs' command) is in LD_LIBRARY_PATH or
+ equivalent variable and wxWindows version is 2.4.0 or above.
+ ])
+ fi
+ AM_CPPFLAGS="$AM_CPPFLAGS $WX_CPPFLAGS"
+ AM_CXXFLAGS="$AM_CXXFLAGS $WX_CXXFLAGS_ONLY"
+ AM_CFLAGS="$AM_CFLAGS $WX_CFLAGS_ONLY"
+ AM_LDFLAGS="$AM_LDFLAGS $WX_LIBS"
+fi
+AM_CONDITIONAL([BUILD_WXWIDGETS], [test "${wxwin}" = "1"])
+
+dnl Check for ncurses
+AC_ARG_ENABLE(ncurses,
+[ --enable-ncurses ncurses interface support (default disabled)])
+if test "${enable_ncurses}" = "yes"
+then
+ AC_CHECK_HEADERS(ncurses.h, want_ncurses=1,
+ [AC_MSG_ERROR([Could not find the ncurses library on your system])])
+fi
+AM_CONDITIONAL([BUILD_NCURSES], [test "${want_ncurses}" = "1"])
+
+dnl Enable/disable text version
+AC_ARG_ENABLE(text,
+[ --enable-text text interface support (default enabled)])
+if test "${enable_text}" != "no"
+then
+ AC_CHECK_HEADERS(readline/readline.h, want_text=1,
+ [AC_MSG_ERROR([Could not find the readline library on your system])])
+fi
+AM_CONDITIONAL([BUILD_TEXT], [test "${enable_text}" != "no"])
+
+dnl Internationalization macros
+AM_GNU_GETTEXT_VERSION(0.11.5)
+AM_GNU_GETTEXT
+
+dnl --------------------------------------------------------------
+dnl Output
+dnl --------------------------------------------------------------
+AC_CONFIG_FILES(intl/Makefile po/Makefile.in
+dic/Makefile
+game/Makefile
+wxwin/Makefile
+utils/Makefile
+Makefile)
+AC_OUTPUT
Index: eliot/m4/wxwin.m4
diff -u /dev/null eliot/m4/wxwin.m4:1.1.4.1
--- /dev/null Wed Dec 28 20:45:32 2005
+++ eliot/m4/wxwin.m4 Wed Dec 28 20:45:32 2005
@@ -0,0 +1,345 @@
+dnl ---------------------------------------------------------------------------
+dnl Macros for wxWidgets detection. Typically used in configure.in as:
+dnl
+dnl AC_ARG_ENABLE(...)
+dnl AC_ARG_WITH(...)
+dnl ...
+dnl AM_OPTIONS_WXCONFIG
+dnl ...
+dnl ...
+dnl AM_PATH_WXCONFIG(2.6.0, wxWin=1)
+dnl if test "$wxWin" != 1; then
+dnl AC_MSG_ERROR([
+dnl wxWidgets must be installed on your system
+dnl but wx-config script couldn't be found.
+dnl
+dnl Please check that wx-config is in path, the directory
+dnl where wxWidgets libraries are installed (returned by
+dnl 'wx-config --libs' command) is in LD_LIBRARY_PATH or
+dnl equivalent variable and wxWidgets version is 2.3.4 or above.
+dnl ])
+dnl fi
+dnl CPPFLAGS="$CPPFLAGS $WX_CPPFLAGS"
+dnl CXXFLAGS="$CXXFLAGS $WX_CXXFLAGS_ONLY"
+dnl CFLAGS="$CFLAGS $WX_CFLAGS_ONLY"
+dnl
+dnl LIBS="$LIBS $WX_LIBS"
+dnl ---------------------------------------------------------------------------
+
+dnl ---------------------------------------------------------------------------
+dnl AM_OPTIONS_WXCONFIG
+dnl
+dnl adds support for --wx-prefix, --wx-exec-prefix, --with-wxdir and
+dnl --wx-config command line options
+dnl ---------------------------------------------------------------------------
+
+AC_DEFUN([AM_OPTIONS_WXCONFIG],
+[
+ AC_ARG_WITH(wxdir,
+ [ --with-wxdir=PATH Use uninstalled version of
wxWidgets in PATH],
+ [ wx_config_name="$withval/wx-config"
+ wx_config_args="--inplace"])
+ AC_ARG_WITH(wx-config,
+ [ --with-wx-config=CONFIG wx-config script to use (optional)],
+ wx_config_name="$withval" )
+ AC_ARG_WITH(wx-prefix,
+ [ --with-wx-prefix=PREFIX Prefix where wxWidgets is installed
(optional)],
+ wx_config_prefix="$withval", wx_config_prefix="")
+ AC_ARG_WITH(wx-exec-prefix,
+ [ --with-wx-exec-prefix=PREFIX
+ Exec prefix where wxWidgets is installed (optional)],
+ wx_config_exec_prefix="$withval", wx_config_exec_prefix="")
+])
+
+dnl Helper macro for checking if wx version is at least $1.$2.$3, set's
+dnl wx_ver_ok=yes if it is:
+AC_DEFUN([_WX_PRIVATE_CHECK_VERSION],
+[
+ wx_ver_ok=""
+ if test "x$WX_VERSION" != x ; then
+ if test $wx_config_major_version -gt $1; then
+ wx_ver_ok=yes
+ else
+ if test $wx_config_major_version -eq $1; then
+ if test $wx_config_minor_version -gt $2; then
+ wx_ver_ok=yes
+ else
+ if test $wx_config_minor_version -eq $2; then
+ if test $wx_config_micro_version -ge $3; then
+ wx_ver_ok=yes
+ fi
+ fi
+ fi
+ fi
+ fi
+ fi
+])
+
+dnl ---------------------------------------------------------------------------
+dnl AM_PATH_WXCONFIG(VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND
+dnl [, WX-LIBS [, ADDITIONAL-WX-CONFIG-FLAGS]]]])
+dnl
+dnl Test for wxWidgets, and define WX_C*FLAGS, WX_LIBS and WX_LIBS_STATIC
+dnl (the latter is for static linking against wxWidgets). Set WX_CONFIG_NAME
+dnl environment variable to override the default name of the wx-config script
+dnl to use. Set WX_CONFIG_PATH to specify the full path to wx-config - in this
+dnl case the macro won't even waste time on tests for its existence.
+dnl
+dnl Optional WX-LIBS argument contains comma- or space-separated list of
+dnl wxWidgets libraries to link against (it may include contrib libraries). If
+dnl it is not specified then WX_LIBS and WX_LIBS_STATIC will contain flags to
+dnl link with all of the core wxWidgets libraries.
+dnl
+dnl Optional ADDITIONAL-WX-CONFIG-FLAGS argument is appended to wx-config
+dnl invocation command in present. It can be used to fine-tune lookup of
+dnl best wxWidgets build available.
+dnl
+dnl Example use:
+dnl AM_PATH_WXCONFIG([2.6.0], [wxWin=1], [wxWin=0], [html,core,net]
+dnl [--unicode --debug])
+dnl ---------------------------------------------------------------------------
+
+dnl
+dnl Get the cflags and libraries from the wx-config script
+dnl
+AC_DEFUN([AM_PATH_WXCONFIG],
+[
+ dnl do we have wx-config name: it can be wx-config or wxd-config or ...
+ if test x${WX_CONFIG_NAME+set} != xset ; then
+ WX_CONFIG_NAME=wx-config
+ fi
+
+ if test "x$wx_config_name" != x ; then
+ WX_CONFIG_NAME="$wx_config_name"
+ fi
+
+ dnl deal with optional prefixes
+ if test x$wx_config_exec_prefix != x ; then
+ wx_config_args="$wx_config_args --exec-prefix=$wx_config_exec_prefix"
+ WX_LOOKUP_PATH="$wx_config_exec_prefix/bin"
+ fi
+ if test x$wx_config_prefix != x ; then
+ wx_config_args="$wx_config_args --prefix=$wx_config_prefix"
+ WX_LOOKUP_PATH="$WX_LOOKUP_PATH:$wx_config_prefix/bin"
+ fi
+ if test "$cross_compiling" = "yes"; then
+ wx_config_args="$wx_config_args --host=$host_alias"
+ fi
+
+ dnl don't search the PATH if WX_CONFIG_NAME is absolute filename
+ if test -x "$WX_CONFIG_NAME" ; then
+ AC_MSG_CHECKING(for wx-config)
+ WX_CONFIG_PATH="$WX_CONFIG_NAME"
+ AC_MSG_RESULT($WX_CONFIG_PATH)
+ else
+ AC_PATH_PROG(WX_CONFIG_PATH, $WX_CONFIG_NAME, no, "$WX_LOOKUP_PATH:$PATH")
+ fi
+
+ if test "$WX_CONFIG_PATH" != "no" ; then
+ WX_VERSION=""
+
+ min_wx_version=ifelse([$1], ,2.2.1,$1)
+ if test -z "$5" ; then
+ AC_MSG_CHECKING([for wxWidgets version >= $min_wx_version])
+ else
+ AC_MSG_CHECKING([for wxWidgets version >= $min_wx_version ($5)])
+ fi
+
+ WX_CONFIG_WITH_ARGS="$WX_CONFIG_PATH $wx_config_args $5 $4"
+
+ WX_VERSION=`$WX_CONFIG_WITH_ARGS --version 2>/dev/null`
+ wx_config_major_version=`echo $WX_VERSION | \
+ sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
+ wx_config_minor_version=`echo $WX_VERSION | \
+ sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
+ wx_config_micro_version=`echo $WX_VERSION | \
+ sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
+
+ wx_requested_major_version=`echo $min_wx_version | \
+ sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
+ wx_requested_minor_version=`echo $min_wx_version | \
+ sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
+ wx_requested_micro_version=`echo $min_wx_version | \
+ sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
+
+ _WX_PRIVATE_CHECK_VERSION([$wx_requested_major_version],
+ [$wx_requested_minor_version],
+ [$wx_requested_micro_version])
+
+ if test -n "$wx_ver_ok"; then
+
+ AC_MSG_RESULT(yes (version $WX_VERSION))
+ WX_LIBS=`$WX_CONFIG_WITH_ARGS --libs`
+
+ dnl is this even still appropriate? --static is a real option now
+ dnl and WX_CONFIG_WITH_ARGS is likely to contain it if that is
+ dnl what the user actually wants, making this redundant at best.
+ dnl For now keep it in case anyone actually used it in the past.
+ AC_MSG_CHECKING([for wxWidgets static library])
+ WX_LIBS_STATIC=`$WX_CONFIG_WITH_ARGS --static --libs 2>/dev/null`
+ if test "x$WX_LIBS_STATIC" = "x"; then
+ AC_MSG_RESULT(no)
+ else
+ AC_MSG_RESULT(yes)
+ fi
+
+ dnl starting with version 2.2.6 wx-config has --cppflags argument
+ wx_has_cppflags=""
+ if test $wx_config_major_version -gt 2; then
+ wx_has_cppflags=yes
+ else
+ if test $wx_config_major_version -eq 2; then
+ if test $wx_config_minor_version -gt 2; then
+ wx_has_cppflags=yes
+ else
+ if test $wx_config_minor_version -eq 2; then
+ if test $wx_config_micro_version -ge 6; then
+ wx_has_cppflags=yes
+ fi
+ fi
+ fi
+ fi
+ fi
+
+ if test "x$wx_has_cppflags" = x ; then
+ dnl no choice but to define all flags like CFLAGS
+ WX_CFLAGS=`$WX_CONFIG_WITH_ARGS --cflags`
+ WX_CPPFLAGS=$WX_CFLAGS
+ WX_CXXFLAGS=$WX_CFLAGS
+
+ WX_CFLAGS_ONLY=$WX_CFLAGS
+ WX_CXXFLAGS_ONLY=$WX_CFLAGS
+ else
+ dnl we have CPPFLAGS included in CFLAGS included in CXXFLAGS
+ WX_CPPFLAGS=`$WX_CONFIG_WITH_ARGS --cppflags`
+ WX_CXXFLAGS=`$WX_CONFIG_WITH_ARGS --cxxflags`
+ WX_CFLAGS=`$WX_CONFIG_WITH_ARGS --cflags`
+
+ WX_CFLAGS_ONLY=`echo $WX_CFLAGS | sed "address@hidden *@@"`
+ WX_CXXFLAGS_ONLY=`echo $WX_CXXFLAGS | sed "address@hidden *@@"`
+ fi
+
+ ifelse([$2], , :, [$2])
+
+ else
+
+ if test "x$WX_VERSION" = x; then
+ dnl no wx-config at all
+ AC_MSG_RESULT(no)
+ else
+ AC_MSG_RESULT(no (version $WX_VERSION is not new enough))
+ fi
+
+ WX_CFLAGS=""
+ WX_CPPFLAGS=""
+ WX_CXXFLAGS=""
+ WX_LIBS=""
+ WX_LIBS_STATIC=""
+ ifelse([$3], , :, [$3])
+
+ fi
+ else
+
+ WX_CFLAGS=""
+ WX_CPPFLAGS=""
+ WX_CXXFLAGS=""
+ WX_LIBS=""
+ WX_LIBS_STATIC=""
+ ifelse([$3], , :, [$3])
+
+ fi
+
+ AC_SUBST(WX_CPPFLAGS)
+ AC_SUBST(WX_CFLAGS)
+ AC_SUBST(WX_CXXFLAGS)
+ AC_SUBST(WX_CFLAGS_ONLY)
+ AC_SUBST(WX_CXXFLAGS_ONLY)
+ AC_SUBST(WX_LIBS)
+ AC_SUBST(WX_LIBS_STATIC)
+ AC_SUBST(WX_VERSION)
+])
+
+dnl ---------------------------------------------------------------------------
+dnl Get information on the wxrc program for making C++, Python and xrs
+dnl resource files.
+dnl
+dnl AC_ARG_ENABLE(...)
+dnl AC_ARG_WITH(...)
+dnl ...
+dnl AM_OPTIONS_WXCONFIG
+dnl AM_OPTIONS_WXRC
+dnl ...
+dnl AM_PATH_WXCONFIG(2.6.0, wxWin=1)
+dnl if test "$wxWin" != 1; then
+dnl AC_MSG_ERROR([
+dnl wxWidgets must be installed on your system
+dnl but wx-config script couldn't be found.
+dnl
+dnl Please check that wx-config is in path, the directory
+dnl where wxWidgets libraries are installed (returned by
+dnl 'wx-config --libs' command) is in LD_LIBRARY_PATH or
+dnl equivalent variable and wxWidgets version is 2.6.0 or above.
+dnl ])
+dnl fi
+dnl
+dnl AM_PATH_WXRC([HAVE_WXRC=1], [HAVE_WXRC=0])
+dnl if test "x$HAVE_WXRC" != x1; then
+dnl AC_MSG_ERROR([
+dnl The wxrc program was not installed or not found.
+dnl
+dnl Please check the wxWidgets installation.
+dnl ])
+dnl fi
+dnl
+dnl CPPFLAGS="$CPPFLAGS $WX_CPPFLAGS"
+dnl CXXFLAGS="$CXXFLAGS $WX_CXXFLAGS_ONLY"
+dnl CFLAGS="$CFLAGS $WX_CFLAGS_ONLY"
+dnl
+dnl LDFLAGS="$LDFLAGS $WX_LIBS"
+dnl ---------------------------------------------------------------------------
+
+
+
+dnl ---------------------------------------------------------------------------
+dnl AM_PATH_WXRC([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
+dnl
+dnl Test for wxWidgets' wxrc program for creating either C++, Python or XRS
+dnl resources. The variable WXRC will be set and substituted in the configure
+dnl script and Makefiles.
+dnl
+dnl Example use:
+dnl AM_PATH_WXRC([wxrc=1], [wxrc=0])
+dnl ---------------------------------------------------------------------------
+
+dnl
+dnl wxrc program from the wx-config script
+dnl
+AC_DEFUN([AM_PATH_WXRC],
+[
+ AC_ARG_VAR([WXRC], [Path to wxWidget's wxrc resource compiler])
+
+ if test "x$WX_CONFIG_NAME" = x; then
+ AC_MSG_ERROR([The wxrc tests must run after wxWidgets test.])
+ else
+
+ AC_MSG_CHECKING([for wxrc])
+
+ if test "x$WXRC" = x ; then
+ dnl wx-config --utility is a new addition to wxWidgets:
+ _WX_PRIVATE_CHECK_VERSION(2,5,3)
+ if test -n "$wx_ver_ok"; then
+ WXRC=`$WX_CONFIG_WITH_ARGS --utility=wxrc`
+ fi
+ fi
+
+ if test "x$WXRC" = x ; then
+ AC_MSG_RESULT([not found])
+ ifelse([$2], , :, [$2])
+ else
+ AC_MSG_RESULT([$WXRC])
+ ifelse([$1], , :, [$1])
+ fi
+
+ AC_SUBST(WXRC)
+ fi
+])
| [Prev in Thread] |
Current Thread |
[Next in Thread] |
- [Eliot-dev] eliot ./configure.in m4/wxwin.m4 [multibyte],
eliot-dev <=