RE: Customization problem

[Drew Adams]

> What do you mean by "every file"?  We know which file is supposed
> to have the custom-set-variables call.  It is the one speciifed
> by custom-file.

I haven't followed everything written about this, but there is no guarantee
that only the user's custom-file will use `custom-set-variable'.

In this case, a third-party library uses `custom-set-variable'. This is done
via `kill-emacs-hook' using this function:

(defun icicle-control-reminder-prompt ()
  "If `icicle-reminder-prompt-flag' > 0, then decrement it and save it.
Used in `kill-emacs-hook'."
  (when (and (wholenump icicle-reminder-prompt-flag)
        (> icicle-reminder-prompt-flag 0))
    (condition-case nil
        (customize-save-variable
          'icicle-reminder-prompt-flag
          (1- icicle-reminder-prompt-flag))
      (error nil))))

FYI, option `icicle-reminder-prompt-flag' is defined as follows:

(defcustom icicle-reminder-prompt-flag 20
  "*Whether to use `icicle-prompt-suffix' reminder in minibuffer prompt.
Nil means never use the reminder.
Non-nil means use the reminder, if space permits:
 An integer value means use only for that many Emacs sessions.
 t means always use it."
  :type
  '(choice
    (const
     :tag "Never use a reminder in the prompt" nil)
    (const
     :tag "Always use a reminder in the prompt" t)
    (integer
     :tag "Use a reminder in the prompt for this many sessions"
     :value 20))
  :group 'icicles)

The effect is that the value of this option is decremented each time you
quit Emacs, until it is zero. The purpose is to provide a learning aid for
the first N Emacs sessions (unless the option is customized to nil or t).