Re: New keybinding suggestion: C-x _ for `shrink-window'

[Juanma Barranquero]

On 10/31/07, Stefan Monnier <address@hidden> wrote:

> I usually don't know how by how many lines I want to expand/shrink a window,
> so I typically end up doing
>
>    C-x ^ C-x ^ C-x ^
>
> which is *really* inconvenient.

I've been using this for years:

;; Function by Hirose Yuuji and Bob Wiener
(defun resize-window (&optional arg)
  "Resize window interactively."
  (interactive "p")
  (when (one-window-p) (error "Cannot resize sole window"))
  (unless arg (setq arg 1))
  (catch 'done
    (while t
      (message "h=heighten, s=shrink, w=widen, n=narrow (by %d);
1-9=unit, q=quit"
               arg)
      (ignore-errors
        (let ((c (read-char))
              (window-size-fixed nil))
          (cond ((= c ?h) (enlarge-window arg))
                ((= c ?s) (shrink-window arg))
                ((= c ?w) (enlarge-window-horizontally arg))
                ((= c ?n) (shrink-window-horizontally arg))
                ((= c ?\^G) (keyboard-quit))
                ((= c ?q) (throw 'done t))
                ((and (> c ?0) (<= c ?9)) (setq arg (- c ?0))))))))
  (message "Done."))

             Juanma