Re: verify ISSN (issn-verify.el)

[Emanuel Berg]

See
https://dataswamp.org/~incal/emacs-init/issn-verify.el
for further (very small) changes...

;;; issn-verify.el --- verify ISSN -*- lexical-binding: t
;;
;;; Commentary:
;;
;; This Elisp package provides functions to verify
;; ISSN by computing their check digits.
;;
;; Author: Emanuel Berg (incal) <moasenwood@zoho.eu>
;; Created: 2020-09-06
;; Keywords: bib, tex
;; License: GPL3+
;; Package-Requires: ((cl-lib "1.0"))
;; URL: https://dataswamp.org/~incal/emacs-init/issn-verify.el
;; Version: 1.1.0
;;
;; Also see:
;;
;;   https://dataswamp.org/~incal/emacs-init/isbn-verify.el
;;
;; To install this package, with this file in
;; a buffer, do:
;;
;;   M-x load-file RET RET
;;
;; International Standard Serial Number:
;;
;;   ISO 3297, 1975
;;
;; format:
;;
;;   The Ring Magazine: ISSN 0035-5410
;;   d_1d_2d_3d_4-d_5d_6d_7c
;;   d_i for i \in [1, 7] is an integer
;;   c, the check digit, is 0..9 or X for 10
;;
;; compute check digit c:
;;
;;     c' = 8d_1*7d_2*6d_3*5d_4*4d_5*3d_6*2d_7 mod 11
;;
;;         { 0        c' = 0
;;     c = {
;;         { 11 - c'    else
;;
;;; Code:

(require 'cl-lib)

(defun issn--get-digits (issn)
  (if (and (= 9 (length issn))
           (zerop (string-match 
"[[:digit:]]\\{4\\}-[[:digit:]]\\{3\\}[X[:digit:]]" issn)) )
    (let*((issn-lst      (string-to-list issn))
          (dash-pos 4))
      (mapcar (lambda (c) (if (eq ?X c) "X" (- c ?0)))
              (append (cl-subseq issn-lst 0   dash-pos)
                      (cl-subseq issn-lst (1+ dash-pos)) )))
    (error "Malformed ISSN") ))

(defun issn-verify-issn (issn)
  (let*((issn-lst (issn--get-digits issn))
        (c-prop   (car (last issn-lst)))
        (c-w      (cl-loop with cwl = 0
                           for d in issn-lst
                           for w downfrom 8 to 2
                           do (cl-incf cwl (* w d))
                           finally return cwl) )
        (c-prime (mod c-w 11))
        (c       (if (zerop c-prime) 0 (- 11 c-prime) ))
        (c-x     (if (= 10 c) "X" c)) )
    (if (equal c-prop c-x)
        (message "%s (OK)" c-x)
      (message "NOT OK! is %s, should be %s" c-prop c-x) )))

;; Bicycle Quarterly   (issn-verify-issn "1941-8809")  ; 9 (OK)
;; Bicycling           (issn-verify-issn "1651-9744")  ; 4 (OK)
;; Black Belt          (issn-verify-issn "0277-3066")  ; 6 (OK)
;; Filter              (issn-verify-issn "1654-9813")  ; 3 (OK)
;; Linux Pro           (issn-verify-issn "1471-5679")  ; NOT OK! is 9, should 
be 8
;; National Geographic (issn-verify-issn "2535-41241") ; Malformed ISSN
;; Outside             (issn-verify-issn "0278-433")   ; Malformed ISSN
;; The Economist       (issn-verify-issn "0013-06a4")  ; Malformed ISSN
;; The Ring            (issn-verify-issn "0035x5410")  ; Malformed ISSN

(provide 'issn-verify)
;;; issn-verify.el ends here

-- 
underground experts united
http://user.it.uu.se/~embe8573
https://dataswamp.org/~incal