>From aab7908e63589b989cc8d4efebfcc838d5b4c805 Mon Sep 17 00:00:00 2001
From: Adam Porter <adam@alphapapa.net>
Date: Sun, 13 Dec 2020 05:54:28 +0000
Subject: [PATCH] New tab-line options, faces, and face function

* lisp/tab-line.el:
(tab-line-tab-face-function): New option.
(tab-line-alternate-colors): New option.
(tab-line-tab-inactive-alternate): New face.
(tab-line-tab-special): New face.
(tab-line-tab-face-default): New function.
(tab-line-format-template): Use them.

Thanks to Juri Linkov for his feedback.
---
 lisp/tab-line.el | 72 ++++++++++++++++++++++++++++++++++++++++++++----
 1 file changed, 66 insertions(+), 6 deletions(-)

diff --git a/lisp/tab-line.el b/lisp/tab-line.el
index 46bf89f14e..313899503c 100644
--- a/lisp/tab-line.el
+++ b/lisp/tab-line.el
@@ -27,6 +27,7 @@
 
 ;;; Code:
 
+(require 'cl-lib)
 (require 'seq) ; tab-line.el is not pre-loaded so it's safe to use it here
 
 
@@ -35,6 +36,22 @@ tab-line
   :group 'convenience
   :version "27.1")
 
+(defcustom tab-line-alternate-colors t
+  "Alternate background colors of inactive tabs.
+When non-nil, alternating tabs use the face
+`tab-line-tab-inactive-alternate'."
+  :type 'boolean
+  :group 'tab-line
+  :version "28.1")
+
+(defcustom tab-line-tab-face-function #'tab-line-tab-face-default
+  "Function called to get a tab's face.
+The function is called with two arguments: the tab and a list of
+all tabs."
+  :type 'function
+  :group 'tab-line
+  :version "28.1")
+
 (defgroup tab-line-faces '((tab-line custom-face)) ; tab-line is defined in faces.el
   "Faces used in the tab line."
   :group 'tab-line
@@ -63,6 +80,19 @@ tab-line-tab-inactive
   :version "27.1"
   :group 'tab-line-faces)
 
+(defface tab-line-tab-inactive-alternate
+  (let ((mode-line-bg (face-background 'mode-line nil t)))
+    `((t (:inherit tab-line-tab-inactive :background ,mode-line-bg))))
+  "Alternate face for inactive tab-line tabs.
+Used on alternating tabs when `tab-line-alternate-colors' is non-nil."
+  :version "28.1"
+  :group 'tab-line-faces)
+
+(defface tab-line-tab-special '((t (:slant italic)))
+  "Face for special (i.e. non-file-backed) tabs."
+  :version "28.1"
+  :group 'tab-line-faces)
+
 (defface tab-line-tab-current
   '((default
       :inherit tab-line-tab)
@@ -412,7 +442,9 @@ tab-line-format-template
                                   (cdr (assq 'selected tab))))
                     (name (if buffer-p
                               (funcall tab-line-tab-name-function tab tabs)
-                            (cdr (assq 'name tab)))))
+                            (cdr (assq 'name tab))))
+                    (face (funcall tab-line-tab-face-function
+                                   tab tabs)))
                (concat
                 separator
                 (apply 'propertize
@@ -425,11 +457,7 @@ tab-line-format-template
                        `(
                          tab ,tab
                          ,@(if selected-p '(selected t))
-                         face ,(if selected-p
-                                   (if (eq (selected-window) (old-selected-window))
-                                       'tab-line-tab-current
-                                     'tab-line-tab)
-                                 'tab-line-tab-inactive)
+                         face ,face
                          mouse-face tab-line-highlight)))))
            tabs))
          (hscroll-data (tab-line-auto-hscroll strings hscroll)))
@@ -453,6 +481,38 @@ tab-line-format-template
                 tab-line-new-button)
        (list tab-line-new-button)))))
 
+(defun tab-line-tab-face-default (tab tabs)
+  "Return face for TAB in TABS.
+If TAB is selected, return `tab-line-tab-current' if the tab's
+window is also selected, otherwise `tab-line-tab'.
+
+Otherwise, if `tab-line-alternate-colors' is non-nil, return
+`tab-line-tab-inactive-alternate' for even-numbered tabs and
+`tab-line-tab-inactive' for odd-numbered ones.
+
+Otherwise, return `tab-line-tab-inactive'.
+
+If the tab's buffer is not file-backed, the returned face also
+inherits from `tab-line-tab-special'.
+
+For use as `tab-line-tab-face-function'."
+  (let* ((buffer-p (bufferp tab))
+	 (selected-p (if buffer-p
+			 (eq tab (window-buffer))
+		       (cdr (assq 'selected tab))))
+	 (face (cond (selected-p
+		      (if (eq (selected-window) (old-selected-window))
+			  'tab-line-tab-current
+			'tab-line-tab))
+		     ((and tab-line-alternate-colors
+			   (cl-evenp (cl-position tab tabs)))
+		      'tab-line-tab-inactive-alternate)
+		     (t
+		      'tab-line-tab-inactive))))
+    (if (and buffer-p (not (buffer-file-name tab)))
+	`((t (:inherit (tab-line-tab-special ,face))))
+      face)))
+
 (defvar tab-line-auto-hscroll)
 
 (defun tab-line-format ()
-- 
2.20.1