Parsing Expression Grammars
***************************

Emacs Lisp provides several tools for parsing and matching text, from regular expressions (see Regular Expressions) to full LL grammar parsers (see Bovine parser development (bovine)).  Parsing Expression Grammars (PEG) are another approach to text parsing that offer more structure and composibility than regular expressions, but less complexity than context-free grammars.

A PEG parser is defined as a list of named rules, each of which match text patterns, and/or contain references to other rules. Parsing is initiated with the function peg-run or the macro peg-parse, and parses text after point in the current buffer, using a given set of rules.

The definition of each rule is referred to as a parsing expression (PEX), and can consist of a literal string, a regexp-like character range or set, a peg-specific construct resembling an elisp function call, a reference to another rule, or a combination of any of these.  A grammar is expressed as a set of rules in which one rule is typically treated as a ``top-level'' or ``entry-point'' rule.  For instance:

     ((number sign digit (* digit))
      (sign   (or "+" "-" ""))
      (digit  [0-9]))

The above grammar could be used directly in a call to peg-parse, in which the first rule is considered the ``entry-point'' rule:

     (peg-parse
       ((number sign digit (* digit))
        (sign   (or "+" "-" ""))
        (digit  [0-9])))

Or set as the value of a variable, and the variable used in a combination of calls to with-peg-rules and peg-run, where the ``entry-point'' rule is given explicitly:

     (defvar number-grammar
             '((number sign digit (* digit))
               (sign (or "+" "-" ""))
               (digit [0-9])))

     (with-peg-rules number-grammar
       (peg-run (peg number)))

By default, calls to peg-run or peg-parse produce no output: parsing simply moves point.  In order to return or otherwise act upon parsed strings, rules can include actions, see Parsing Actions for more information.

Individual rules can also be defined using a more defun-like syntax, using the macro define-peg-rule:

     (define-peg-rule digit ()
       [0-9])

This allows the rule to be referred to by name within calls to peg-run or peg-parse elsewhere, and also allows the use of function arguments in the rule body.

PEX Definitions
===============

Parsing expressions can be defined using the following syntax:

(and E1 E2 ...)
     A sequence of PEXs that must all be matched.  The and form is optional and implicit.

(or E1 E2 ...)
     Prioritized choices, meaning that, as in Elisp, the choices are tried in order, and the first successful match is used.  Note that this is distinct from context-free grammars, in which selection between multiple matches is indeterminate.

(any)
     Matches any single character, as the regexp ``.''.

"abc"
     A literal string.

(char C)
     A single character, as an Elisp character literal.

(* E)
     Zero or more of an expression, as the regexp ``*''.  Matching is always ``greedy''.

(+ E)
     One or more of an expression, as the regexp ``+''.  Matching is always ``greedy''.

(opt E)
     Zero or one of an expression, as the regexp ``?''.

SYMBOL
     A symbol representing a previously-defined PEG rule.

(range A B)
     The character range between A and B, as the regexp ``[A-B]''.

[a-b "+*" ?x]
     A character set, including ranges, literal characters, or strings of characters.

[ascii cntrl]
     A list of named character classes (see below).

(syntax-class NAME)
     A single syntax class.

(null)
     The empty string.

The following expressions are used as anchors or tests -- they do not move point, but return a boolean value which can be used to constrain matches as a way of controlling the parsing process (see Writing PEG Rules).

(bob)
     Beginning of buffer.

(eob)
     End of buffer.

(bol)
     Beginning of line.

(eol)
     End of line.

(bow)
     Beginning of word.

(eow)
     End of word.

(bos)
     Beginning of symbol.

(eos)
     End of symbol.

(if E)
     Returns non-nil if parsing PEX E from point succeeds (point is not moved).

(not E)
     Returns non-nil if parsing PEX E from point fails (point is not moved).

(guard EXP)
     Treats the value of the Elisp expression EXP as a boolean.

Named character classes include the following:

  * ascii

  * alnum

  * alpha

  * blank

  * cntrl

  * digit

  * graph

  * lower

  * multibyte

  * nonascii

  * print

  * punct

  * space

  * unibyte

  * upper

  * word

  * xdigit

Parsing Actions
===============

By default the process of parsing simply moves point in the current buffer, ultimately returning t if the parsing succeeds, and nil if it doesn't.  It's also possible to define ``actions'' that can run arbitrary Elisp at certain points in the parsed text. These actions can optionally affect something called the parsing stack, which is a list of values returned by the parsing process. These actions only run (and only return values) if the parsing process ultimately succeeds; if it fails the action code is not run at all.

Actions can be added anywhere in the definition of a rule.  They are distinguished from parsing expressions by an initial backquote (`), followed by a parenthetical form that must contain a pair of hyphens (--) somewhere within it.  Symbols to the left of the hyphens are bound to values popped from the stack (they are somewhat analogous to the argument list in a lambda).  Values produced by code to the right are pushed to the stack (analogous to the return value of the lambda).  For instance, the previous grammar can be augmented with actions to return the parsed number as an actual integer:

     (with-peg-rules ((number sign digit (* digit
                                            `(a b -- (+ (* a 10) b)))
                              `(sign val -- (* sign val)))
                      (sign (or (and "+" `(-- 1))
                                (and "-" `(-- -1))
                                (and ""  `(-- 1))))
                      (digit [0-9] `(-- (- (char-before) ?0))))
       (peg-run (peg number)))

There must be values on the stack before they can be popped and returned -- if there aren't enough stack values to bind to an action's left-hand terms, they will be bound to nil.  An action with only right-hand terms will push values to the stack; an action with only left-hand terms will consume (and discard) values from the stack. At the end of parsing, stack values are returned as a flat list.

To return the string matched by a PEX (instead of simply moving point over it), a rule like this can be used:

     (one-word
       `(-- (point))
       (+ [word])
       `(start -- (buffer-substring start (point))))

The first action pushes the initial value of point to the stack.  The intervening PEX moves point over the next word. The second action pops the previous value from the stack (binding it to the variable start), and uses that value to extract a substring from the buffer and push it to the stack.  This pattern is so common that peg.el provides a shorthand function that does exactly the above, along with a few other shorthands for common scenarios:

(substring E)
     Match PEX E and push the matched string to the stack.

(region E)
     Match E and push the start and end positions of the matched region to the stack.

(replace E "repl")
     Match E and replaced the matched region with the string "repl".

(list E)
     Match E, collect all values produced by E (and its sub-expressions) into a list, and push that list to the stack.  Stack values are typically returned as a flat list; this is a way of ``grouping'' values together.

Writing PEG Rules
=================

Something to be aware of when writing PEG rules is that they are greedy.  Rules which consume a variable amount of text will always consume the maximum amount possible, even if that causes a rule that might otherwise have matched to fail later on.  For instance, this rule will never succeed:

     (forest (+ "tree" (* [blank])) "tree" (eol))

The PEX (+ "tree" (* [blank])) will consume all repetitions of the word ``tree'', leaving none to match the final "tree".

In these situations, the desired result can be obtained by using predicates and guards -- namely the not, if and guard expressions -- to constrain behavior.  For instance:

     (forest (+ "tree" (* [blank])) (not (eol)) "tree" (eol))

The if and not operators accept a parsing expression and interpret it as a boolean, without moving point. The contents of a guard operator are evaluated as regular Elisp (not a PEX) and should return a boolean value.  A nil value causes the match to fail.

Another potentially unexpected behavior is that parsing will move point as far as possible, even if the parsing ultimately fails.  This rule:

     (end-game "game" (eob))

when run in a buffer containing the text ``game over'' after point, will move point to just after ``game'' and halt parsing, returning nil.  Successful parsing will always return t, or the contexts of the parsing stack.