[GNUnet-SVN] r11861 - gnunet/m4

[gnunet]

Author: grothoff
Date: 2010-06-22 10:01:57 +0200 (Tue, 22 Jun 2010)
New Revision: 11861

Added:
   gnunet/m4/mkdirp.m4
Modified:
   gnunet/m4/Makefile.am
Log:
mkdir

Modified: gnunet/m4/Makefile.am
===================================================================
--- gnunet/m4/Makefile.am       2010-06-22 07:55:07 UTC (rev 11860)
+++ gnunet/m4/Makefile.am       2010-06-22 08:01:57 UTC (rev 11861)
@@ -21,6 +21,7 @@
 libxml2.m4\
 longdouble.m4\
 longlong.m4\
+mkdir.m4\
 nls.m4\
 pkg.m4\
 po.m4\

Added: gnunet/m4/mkdirp.m4
===================================================================
--- gnunet/m4/mkdirp.m4                         (rev 0)
+++ gnunet/m4/mkdirp.m4 2010-06-22 08:01:57 UTC (rev 11861)
@@ -0,0 +1,63 @@
+##                                                          -*- Autoconf -*-
+# Copyright (C) 2003, 2004, 2005  Free Software Foundation, Inc.
+#
+# This file is free software; the Free Software Foundation
+# gives unlimited permission to copy and/or distribute it,
+# with or without modifications, as long as this notice is preserved.
+
+# AM_PROG_MKDIR_P
+# ---------------
+# Check whether `mkdir -p' is supported, fallback to mkinstalldirs otherwise.
+#
+# Automake 1.8 used `mkdir -m 0755 -p --' to ensure that directories
+# created by `make install' are always world readable, even if the
+# installer happens to have an overly restrictive umask (e.g. 077).
+# This was a mistake.  There are at least two reasons why we must not
+# use `-m 0755':
+#   - it causes special bits like SGID to be ignored,
+#   - it may be too restrictive (some setups expect 775 directories).
+#
+# Do not use -m 0755 and let people choose whatever they expect by
+# setting umask.
+#
+# We cannot accept any implementation of `mkdir' that recognizes `-p'.
+# Some implementations (such as Solaris 8's) are not thread-safe: if a
+# parallel make tries to run `mkdir -p a/b' and `mkdir -p a/c'
+# concurrently, both version can detect that a/ is missing, but only
+# one can create it and the other will error out.  Consequently we
+# restrict ourselves to GNU make (using the --version option ensures
+# this.)
+AC_DEFUN([AM_PROG_MKDIR_P],
+[if mkdir -p --version . >/dev/null 2>&1 && test ! -d ./--version; then
+  # We used to keeping the `.' as first argument, in order to
+  # allow $(mkdir_p) to be used without argument.  As in
+  #   $(mkdir_p) $(somedir)
+  # where $(somedir) is conditionally defined.  However this is wrong
+  # for two reasons:
+  #  1. if the package is installed by a user who cannot write `.'
+  #     make install will fail,
+  #  2. the above comment should most certainly read
+  #     $(mkdir_p) $(DESTDIR)$(somedir)
+  #     so it does not work when $(somedir) is undefined and
+  #     $(DESTDIR) is not.
+  #  To support the latter case, we have to write
+  #     test -z "$(somedir)" || $(mkdir_p) $(DESTDIR)$(somedir),
+  #  so the `.' trick is pointless.
+  MKDIR_P='mkdir -p --'
+else
+  # On NextStep and OpenStep, the `mkdir' command does not
+  # recognize any option.  It will interpret all options as
+  # directories to create, and then abort because `.' already
+  # exists.
+  for d in ./-p ./--version;
+  do
+    test -d $d && rmdir $d
+  done
+  # $(mkinstalldirs) is defined by Automake if mkinstalldirs exists.
+  if test -f "$ac_aux_dir/mkinstalldirs"; then
+    MKDIR_P='$(mkinstalldirs)'
+  else
+    MKDIR_P='$(install_sh) -d'
+  fi
+fi
+AC_SUBST([MKDIR_P])])