#!/usr/bin/perl -w
#
#       pdfmake         : Frontend to run groff  to produce PDFs
#       Deri James      : Friday 16 Mar 2012
#


use strict;
use File::Temp qw/tempfile/;
my @cmd;
my $dev='pdf';
my $preconv='';
my $readstdin=1;
my $mom=($0=~m/pdfmom$/)?'-mom':'';
my $RT_SEP=':';

$ENV{PATH}=$ENV{GROFF_BIN_PATH}.$RT_SEP.$ENV{PATH} if exists($ENV{GROFF_BIN_PATH});
$ENV{TMPDIR}=$ENV{GROFF_TMPDIR} if exists($ENV{GROFF_TMPDIR});

while (my $c=shift)
{
    $c=~s/(?<!\\)"/\\"/g;
    
    if (substr($c,0,2) eq '-T')
    {
	if (length($c) > 2)
	{
	    $dev=substr($c,2);
	}
	else
	{
	    $dev=shift;
	}
	next;
    }
    elsif (substr($c,0,2) eq '-K')
    {
	if (length($c) > 2)
	{
	    $preconv=$c;
	}
	else
	{
	    $preconv=$c;
	    $preconv.=shift;
	}
	next;
    }
    elsif (substr($c,0,2) eq '-k')
    {
	$preconv=$c;
	next;
    }
    elsif ($c eq '-z' or $c eq '-Z')
    {
	$dev=$c;
	next;
    }
    elsif ($c eq '-v')
    {
	print "GNU pdfmom (groff) version 1.23.0.rc1.2849-26523d-dirty\n";
	exit;
    }
    elsif (substr($c,0,1) eq '-')
    {
	if (length($c) > 1)
	{
	    push(@cmd,"\"$c\"");
	    push(@cmd,"'".(shift)."'") if length($c)==2 and index('dDfFIKLmMnoPrwW',substr($c,-1)) >= 0;
	}
	else
	{
	    # Just a '-'
	    
	    push(@cmd,$c);
	    $readstdin=2;
	}
    }
    else
    {
	# Got a filename?
	
	push(@cmd,"\"$c\"");
	$readstdin=0 if $readstdin == 1;
	
    }

}

my $cmdstring=' '.join(' ',@cmd).' ';

if ($readstdin)
{
    my ($fh,$tmpfn)=tempfile('pdfmake-XXXXX', UNLINK=>1);

    while (<STDIN>)
    {
	print $fh ($_);
    }
    
    close($fh);
    
    $cmdstring=~s/ - / $tmpfn / if $readstdin == 2;
    $cmdstring.=" $tmpfn " if $readstdin == 1;
}

if ($dev eq 'pdf')
{
    system("groff -Tpdf -dPDF.EXPORT=1 -dLABEL.REFS=1 $mom -z $cmdstring 2>&1 | LC_ALL=C grep '^\\. *ds' | groff -Tpdf $mom $preconv - $cmdstring");
}
elsif ($dev eq 'ps')
{
    if ($mom)
    {
	system("groff -Tpdf -dLABEL.REFS=1 $mom -z $cmdstring 2>&1 | LC_ALL=C grep '^\\. *ds' | pdfroff -mpdfmark $mom --no-toc - $preconv $cmdstring");
    }
    else
    {
	system("pdfroff -mpdfmark $mom --no-toc $preconv $cmdstring");
    }
}
elsif ($dev eq '-z') # pseudo dev - just compile for warnings
{
    system("groff -Tpdf $mom -z $cmdstring");
}
elsif ($dev eq '-Z') # pseudo dev - produce troff output
{
    system("groff -Tpdf $mom -Z $cmdstring");
}
else
{
    print STDERR "Not compatible with device '-T $dev'\n";
    exit 1;
}

