Re: Tramp with Dired produces unwanted //DIRED// line

[Michael Albinus]

Michael Albinus <michael.albinus@gmx.de> writes:

Hi Felix,

>>> Good. However, I need to find out what happens with compiled Tramp
>>> files. Hopefully, I can reproduce the problem locally.
>>
>> Let me know if I you need help reproducing the issue.
>
> Thanks for the offer. If needed, I'll contact you.

The upcoming Tramp 2.5.0.4 will come with the following command:

--8<---------------cut here---------------start------------->8---
(defun tramp-recompile-elpa ()
  "Recompile the installed Tramp ELPA package.
This is needed if there are compatibility problems."
  (interactive)
  ;; We expect just one Tramp package is installed.
  (when-let
      ((dir (tramp-compat-funcall
             'package-desc-dir
             (car (alist-get 'tramp (bound-and-true-p package-alist))))))
    (dolist (elc (directory-files dir 'full "\\.elc$"))
      (delete-file elc))
    (with-current-buffer (get-buffer-create byte-compile-log-buffer)
      (let ((inhibit-read-only t))
        (compilation-mode)
        (goto-char (point-max))
        (insert "\f\n")
        (call-process
         (expand-file-name invocation-name invocation-directory) nil t t
         "-Q" "-batch" "-L" dir
         "--eval" (format "(byte-recompile-directory %S 0 t)" dir))
        (message "Package `tramp' recompiled.")))))
--8<---------------cut here---------------end--------------->8---

Would you mind to check, whether it fixes the compatibility issue in
your setup? Prerequisites are that package.el is loaded, and Tramp is
installed as ELPA package. Then you can call 'M-x tramp-recompile-elpa'.
Likely, you must restart Emacs afterwards, in order to profit from the
recompiled files.

Thanks, and best regards, Michael.