Am Mi., 21. Nov. 2018 um 04:38 Uhr schrieb Mark H Weaver <
address@hidden>:
Hi Marc,
Dear Mark,
thank you very much for all your detailed replies; these are extremely helpful!
No, it does not monotonically grow during the course of expansion. One
way to think about it is that it's the lexical environment of the
_expanded_ code. It therefore only grows when the macro expander
_descends_ into a core lexical binding form. For example, in
(let ((x (let ((y 4))
(+ y y))))
(+ x x))
the expansion environment used to expand (+ x x) does not include a
binding for the gensym corresponding to 'y'.
Ah, ok.
> In general, that's how Psyntax implements lexical binding. When a core
> binding form is encountered, a fresh gensym is bound in the transformer
> environment, and that new environment is used to expand all forms
> within, including the results of expanding macros within, which in
> general include identifiers that originally appeared in macro
> definitions elsewhere that are not in the lexical scope of those
> bindings.
>
> The reason this works is because when a core binding form is encountered
> by the expander, the fresh gensym is substituted for all free references
> of the user-visible identifier in the body, *before* expanding the
> macros found within. The substitution is deferred using the 'wrap'
> mechanism, but the result is the same. Any identifiers not visible in
> the body at that time are not affected by that subtitution.
>
> Ellipsis identifiers are a bit more tricky, because unlike other
> bindings, the user-visible ellipsis identifiers are not actually
> substituted. We can't do that because ellipsis identifiers can be used
> for other purposes, e.g. bound to ordinary variables or macros, and
> these two ways of binding ellipsis identifiers should not shadow each
> other.
>
> Is this universally true? Maybe I misunderstood what you mean about
> shadowing. How about the following?
>
> (use-modules (guile))
> (define-syntax ... (syntax-rules ()))
> (define-syntax bar
> (syntax-rules ()
> ((_ ...) ...)))
>
> At least by the R7RS, this shouldn't yield an error due to a misplaced
> ellipsis.
I'm not aware of any language in the R[567]RS that makes it clear
whether '...' should be recognized as an ellipsis if it is bound to a
variable. The Scheme implementations I tried do not seem to agree.
For example, consider this example:
(let ((... 'hello))
(let-syntax ((foo (syntax-rules ()
((foo x ...)
'((x) ...)))))
(foo 1 2)))
If '...' is recognized as an ellipsis within the 'let', then the result
will be '((1) (2)). Otherwise, the result will be '((1) 2).
I just tested with Chez Scheme 9.5 as well. It returns the same result as Chibi, namely '((1) 2).
I found that Racket 7.0, Chicken 4.13.0, and Scheme48 1.9.2 return
'((1) (2)). Chibi-Scheme returns '((1) 2). I see the same results
with this variant:
(let-syntax ((... (syntax-rules ())))
(let-syntax ((foo (syntax-rules ()
((foo x ...)
'((x) ...)))))
(foo 1 2)))
Again, Chez returns '((1) 2).
If we instead bind '...' as a top-level variable:
(define-syntax ... (syntax-rules ()))
(let-syntax ((foo (syntax-rules ()
((foo x ...)
'((x) ...)))))
(foo 1 2))
Then all four of these Schemes agree that the answer is '((1) (2)),
including Chibi-Scheme.
Chez Scheme still returns '((1) 2) and thus does not recognize `...' as the ellipsis.
Did you compile Chibi with -DSEXP_USE_STRICT_TOPLEVEL_BINDINGS=1? Without, Chibi does not implement the intended R7RS semantics; see the fourth paragraph here:
http://synthcode.com/scheme/chibi/#h3_SchemeStandard. And, indeed, Chibi 0.8 with this feature flag enabled returns '((1) 2) once more.
So what does R7RS say about it: `...' is defined as auxiliary syntax in Section 4.3.2. By Section 1.3.3, auxiliary syntax describes a syntax binding. Appendix A. states that the standard binding for `...' is exported by `(scheme base)'. Auxiliary syntax is matched by their binding in R7RS; an example for this is given at the end of Section 4.3.2: The _expression_ `(let ((=> #f)) (cond #t => 'ok))' is not an error, but evaluates to `ok'. Note that this example is about the auxiliary syntax `=>', but the report does not distinguish different types of auxiliary syntax (in particular, it is nowhere mentioned that `...' should be treated differently than any other auxiliary syntax).
Thus, Chibi (in R7RS mode by the above flag) implements the R7RS correctly.
Now to R6RS. Section 6.4 says that auxiliary syntax describes a syntax binding. Section 12.4 of the R6RS Library Report defines `...' as auxiliary syntax. The example definition of `case' in Section 12.5 ibid. shows explicitely that auxiliary keywords are matched using `free-identifier=?' (in this example, `else'). Also, in all other regards with respect to auxiliary syntax R6RS does not differ from R7RS.
Thus, Chez Scheme implements the R6RS semantics.
Now, what about Racket in R6RS mode? I tested your examples with Racket 6.12 and the results are the same as in Racket 7.0. The following code prints '((1) (2)):
#!r6rs
(import (rnrs))
(write
(let ((... 'hello))
let-syntax ((foo (syntax-rules ()
((foo x ...)
'((x) ...)))))
(foo 1 2))))
(newline)
Does Racket contradict the R6RS semantics here? Not necessarily. The reason is that in Racket identifiers are allowed to have different bindings during different phases, while R6RS does not allow to import the same identifier with different bindings at different phases, for example (the reason is that R6RS also wants to support implicit phasing). So in this example, at phase level 0, `...' is being bound to a location containing the symbol 'hello, while the binding of `...' at phase level 1 is the ellipsis as recognized by `syntax-case'.
This behavior is demonstrated by the following example, which prints '((1) 2) in agreement with Chez and the R[67]RS.
#!r6rs
(import (rnrs))
(write
(let-syntax ((foo (let ((... 'hello))
(syntax-rules ()
((foo x ...)
'((x) ...))))))
(foo 1 2)))
(newline)
The reason is that the transformer code is expanded and evaluated in phase level 1.
Another demonstration of this fact is given by the following, which also prints '((1) 2):
#!r6rs
(import (rnrs) (only (racket) begin-for-syntax))
(begin-for-syntax
(define ... 'hello))
(write
(let-syntax ((foo (syntax-rules ()
((foo x ...)
'((x) ...)))))
(foo 1 2)))
(newline)
> And what about:
>
> (with-ellipsis e
> (define-syntax e (syntax-rules ()))
> (define-syntax bar
> (syntax-rules ()
> ---)))
>
> Is `e' recognized as the ellipsis in `---'?
Yes. For example:
(with-ellipsis e
(define-syntax e (syntax-rules ()))
(let-syntax ((foo (syntax-rules ()
((foo x e)
'((x) e)))))
(foo 1 2)))
=> '((1) (2))
This is unfortunate because it contradicts the R7RS semantics discussed above. It also goes against the Scheme (as a LISP-1) tradition that an identifier (at least in models with implicit phasing) has only one binding (e.g. to a variable location, to a syntax transformer, as a pattern variable), doesn't it?
Regards,
Marc
> > Now, why does the following work (i.e. why does it print `#t')?
> >
> > (eval-when (expand)
> > (define-syntax bar2
> > (syntax-rules ()
> > ((_ e body)
> > (with-ellipsis e body)))))
> >
> > (define-syntax foo2
> > (lambda (stx)
> > (bar2 f (syntax-case stx ()
> > ((_ a ...)
> > #'#t)
> > ((_ a b c)
> > #'#f)))))
> >
> > (display (foo2 1 2 3))
> > (newline)
>
> I think this should print #f, and that's what happens on my machine with
> Guile 2.2.3. In this example, 'bar2' is essentially an alias for
> 'with-ellipsis', and should behave the same way.
>
> I tested several variation of the above example and probably managed
> to confound the results. :-/ Here are hopefully the correct results
> (Guile 2.2.4 as shipped with Ubuntu 18.10):
>
> So this one indeed outputs #f, thus reproducing your result.
>
> (eval-when (expand)
> (define-syntax bar2
> (syntax-rules ()
> ((_ e body)
> (with-ellipsis e body)))))
>
> (define-syntax foo2
> (lambda (stx)
> (bar2 e (syntax-case stx ()
> ((_a ...)
> #'#t)
> ((_ a b c)
> #'#f)))))
>
> (display (foo2 1 2 3))
> (newline)
>
> On the other hand, this one prints #t.
>
> (eval-when (expand)
> (define-syntax bar2
> (syntax-rules ()
> ((_ e body)
> (with-ellipsis f body))))) ; THE DIFFERENCE IS HERE.
>
> (define-syntax foo2
> (lambda (stx)
> (bar2 e (syntax-case stx ()
> ((_a ...)
> #'#t)
> ((_ a b c)
> #'#f)))))
>
> (display (foo2 1 2 3))
> (newline)
This last example is an interesting case which demonstrates an aspect of
the 'with-ellipsis' semantics that I haven't previously discussed in
this thread.
When checking if an identifier is an ellipsis, the only 'with-ellipsis'
bindings that will be considered in scope are those where the first
operand to 'with-ellipsis' have the same marks as the identifier being
checked.
In this case, the '...' identifier in 'foo2' has different marks than
the 'f' in 'bar2', so that ellipsis binding is effectively ignored.
Since there are no other ellipsis bindings in scope, the identifier is
simply compared with '...' using 'free-identifier=?', as the default
ellipsis identifier.
> I think this behavior of your algorithm and the `with-ellipsis' form
> is optimal as it allows to nested macro expansions to have their
> private ellipsis identifiers while it also allows to write wrapper
> macros that behave like `with-ellipsis'.
Thanks. I'm not 100% sure these are the ideal semantics, but they seem
to cover the cases I've considered reasonably well.
> > > In Chez Scheme, I would have used `define-property' to define my
> > > custom property directly on the identifier standing for the pattern
> > > variable. I haven't found an equivalent feature in Guile. I don't know
> > > how to nicely code my-syntax-case/my-syntax in standard R6RS.
> >
> > Sure, that sounds like a nice feature. I'll add it to my TODO list :)
> >
> > That would be great! :-)
>
> I'll probably raise the priority of this TODO item, since I'd prefer to
> enable you to avoid using 'syntax-local-binding' if possible.
>
> How would you implement this?
I'm not yet sure, I would need to study the problem carefully and have
not yet had the time.
Regards,
Mark