emacs-devel
[Top][All Lists]
Advanced

[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: What a modern collaboration toolkit looks like


From: Eli Zaretskii
Subject: Re: What a modern collaboration toolkit looks like
Date: Tue, 01 Jan 2008 22:44:47 +0200

> From: Dan Nicolaescu <address@hidden>
> Cc: address@hidden
> Date: Mon, 31 Dec 2007 16:27:07 -0800
> 
>   > All I needed to do is introduce
>   > them to some optional features, such as Speedbar, ebrowse, and gdb-ui,
>   > and craft a simple .emacs to bind the various Fn keys to
>   > compile/run/debug commands they were used to have.  After that, I
>   > never again heard anyone of them laughing at "stagnant backwater" that
>   > is Emacs.
> 
> Care to post an example of such .emacs? 
> Maybe it can be used as a skeleton for a package for such users, or
> maybe we can change some defaults to match such users' expectations.

There's nothing too fancy about it; most of it goes like this:

  (defun ez-clcheckout ()
    "Checkout from ClearCase the file visited by current buffer."
    (interactive)
    (shell-command (format "cleartool co %s" buffer-file-name))
    (revert-buffer nil t))
  (global-set-key (kbd "<f9>") 'ez-clcheckout)
  (defun ez-clcheckin ()
    "Checkin to ClearCase the file visited by current buffer."
    (interactive)
    (shell-command
        (format "cleartool ci %s" buffer-file-name))
    (revert-buffer nil t))
  (global-set-key (kbd "<C-f9>") 'ez-clcheckin)
  (defun ez-maketarg ()
    "Build the project in current buffer's directory."
    (interactive)
    (save-buffer)
    (if (eq system-type 'windows-nt)
        (compile compile-command)
      (compile "gmake -k DEBUG")))

  (global-set-key (kbd "<f7>") 'ez-maketarg)
  (add-hook 'c-mode-common-hook
         (lambda ()
           (unless (or (file-exists-p "makefile")
                       (file-exists-p "Makefile"))
             (let* ((dsp-dir (file-name-directory buffer-file-name))
                    (dsp-file (downcase (file-name-nondirectory
                                         (directory-file-name dsp-dir)))))
               (set (make-local-variable 'compile-command)
                    (concat "devenv.com "
                            (convert-standard-filename dsp-dir)
                            dsp-file
                          ".vcproj debug /rebuild"))))))

  (global-set-key (kbd "<f4>") 'next-error)




reply via email to

[Prev in Thread] Current Thread [Next in Thread]