[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
bug#25529: diagnosis and one approach to a fix
From: |
Tom Tromey |
Subject: |
bug#25529: diagnosis and one approach to a fix |
Date: |
Sun, 05 Feb 2017 11:43:04 -0700 |
User-agent: |
Gnus/5.13 (Gnus v5.13) Emacs/25.1.91 (gnu/linux) |
Tom> Another way is to use a regexp, see appended.
Tom> I'll try to write a test for this soon.
Now with a test.
Dmitry, I'd appreciate your comments on this.
Tom
commit 0841c586b5a933773e770579b4a9cd6f86b2dcf7
Author: Tom Tromey <tom@tromey.com>
Date: Sun Feb 5 11:40:18 2017 -0700
Recognize JS regexp literals more correctly
* lisp/progmodes/js.el (js--syntax-propertize-regexp-regexp): New
constant.
(js-syntax-propertize-regexp): Use it.
* test/lisp/progmodes/js-tests.el (js-mode-regexp-syntax-bug-25529):
New test.
diff --git a/lisp/progmodes/js.el b/lisp/progmodes/js.el
index e42e014..145aa6f 100644
--- a/lisp/progmodes/js.el
+++ b/lisp/progmodes/js.el
@@ -1694,22 +1694,33 @@ js--syntax-propertize-regexp-syntax-table
(modify-syntax-entry ?\\ "\\" st)
st))
+(defconst js--syntax-propertize-regexp-regexp
+ (rx
+ ;; Start of regexp.
+ "/"
+ (0+ (or
+ ;; Match characters outside of a character class.
+ (not (any ?\[ ?/ ?\\))
+ ;; Match backslash quoted characters.
+ (and "\\" not-newline)
+ ;; Match character class.
+ (and
+ "["
+ (0+ (or
+ (not (any ?\] ?\\))
+ (and "\\" not-newline)))
+ "]")))
+ (group "/"))
+ "Regular expression matching the body of a JavaScript regexp literal.")
+
(defun js-syntax-propertize-regexp (end)
(let ((ppss (syntax-ppss)))
(when (eq (nth 3 ppss) ?/)
;; A /.../ regexp.
- (while
- (when (re-search-forward "\\(?:\\=\\|[^\\]\\)\\(?:\\\\\\\\\\)*/"
- end 'move)
- (if (nth 1 (with-syntax-table
- js--syntax-propertize-regexp-syntax-table
- (let ((parse-sexp-lookup-properties nil))
- (parse-partial-sexp (nth 8 ppss) (point)))))
- ;; A / within a character class is not the end of a regexp.
- t
- (put-text-property (1- (point)) (point)
- 'syntax-table (string-to-syntax "\"/"))
- nil))))))
+ (goto-char (nth 8 ppss))
+ (when (looking-at js--syntax-propertize-regexp-regexp)
+ (put-text-property (match-beginning 1) (match-end 1)
+ 'syntax-table (string-to-syntax "\"/"))))))
(defun js-syntax-propertize (start end)
;; JavaScript allows immediate regular expression objects, written /.../.
diff --git a/test/lisp/progmodes/js-tests.el b/test/lisp/progmodes/js-tests.el
index 7cb737c..d1a8db0 100644
--- a/test/lisp/progmodes/js-tests.el
+++ b/test/lisp/progmodes/js-tests.el
@@ -99,6 +99,15 @@
(forward-line)
(should (looking-at " \\* test"))))
+(ert-deftest js-mode-regexp-syntax-bug-25529 ()
+ (with-temp-buffer
+ (js-mode)
+ (insert "let x = /[^[]/;\n")
+ (save-excursion (insert "something();\n"))
+ ;; The failure mode was that the regexp literal was not
+ ;; recognized, causing the next line to be given string syntax.
+ (should-not (nth 3 (syntax-ppss)))))
+
(provide 'js-tests)
;;; js-tests.el ends here
- bug#25529: diagnosis and one approach to a fix, Tom Tromey, 2017/02/05
- bug#25529: diagnosis and one approach to a fix, Tom Tromey, 2017/02/05
- bug#25529: diagnosis and one approach to a fix, Tom Tromey, 2017/02/05
- bug#25529: diagnosis and one approach to a fix,
Tom Tromey <=
- bug#25529: diagnosis and one approach to a fix, Dmitry Gutov, 2017/02/05
- bug#25529: diagnosis and one approach to a fix, Tom Tromey, 2017/02/06
- bug#25529: diagnosis and one approach to a fix, Dmitry Gutov, 2017/02/06
- bug#25529: diagnosis and one approach to a fix, Tom Tromey, 2017/02/07
- bug#25529: diagnosis and one approach to a fix, Dmitry Gutov, 2017/02/07
- bug#25529: diagnosis and one approach to a fix, Stefan Monnier, 2017/02/07
- bug#25529: diagnosis and one approach to a fix, Tom Tromey, 2017/02/10
- bug#25529: diagnosis and one approach to a fix, Stefan Monnier, 2017/02/10
- bug#25529: diagnosis and one approach to a fix, Tom Tromey, 2017/02/10
- bug#25529: diagnosis and one approach to a fix, Stefan Monnier, 2017/02/10