[Top][All Lists]
[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
RFC: 77-gary-diagnose-version-mismatch.patch
From: |
Gary V. Vaughan |
Subject: |
RFC: 77-gary-diagnose-version-mismatch.patch |
Date: |
Fri, 30 Jan 2004 17:54:28 +0000 |
User-agent: |
Mozilla/5.0 (X11; U; Linux i686; en-US; rv:1.5) Gecko/20030925 Thunderbird/0.3 |
-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1
This patch kind of fell out of me wanting libtool to do automake-like version
mismatch checking at runtime, and autoconf-like AC_PREREQ version-minima.
If you guys like this, I'll rewrite the docs, update the test directories and
resubmit.
If you don't like it, I will throw my toys out of the pram :-b Alternatively,
you might want to convince me to split out just the version checks with eg.
AC_PROG_LIBTOOL(1.5).
I've also added an m4_pattern_forbid which means we don't need to keep using
the lame LT_AC_ prefix to pick up unexpanded macros in configure -- we can
migrate to a proper LT_ namespace! :-)
Cheers,
Gary
- --
Gary V. Vaughan ())_. address@hidden,gnu.org}
Research Scientist ( '/ http://www.oranda.demon.co.uk
GNU Hacker / )= http://www.gnu.org/software/libtool
Technical Author `(_~)_ http://sources.redhat.com/autobook
-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.2.2 (GNU/Linux)
Comment: Using GnuPG with Thunderbird - http://enigmail.mozdev.org
iD8DBQFAGppUFRMICSmD1gYRAhweAJ9OD14dxhM9uPSRX3uiv6jbb6nXFQCfSBb/
h6oi2W+PklVORU2X7lpD8uY=
=FJEZ
-----END PGP SIGNATURE-----
Index: ChangeLog
from Gary V. Vaughan <address@hidden>
Sweeping changes to the user interface to libtool from
`configure.ac' to be more like AM_INIT_AUTOMAKE and accept a space
delimited list of options. Instead of calling `AC_LIBTOOL_DLOPEN;
AC_PROG_LIBTOOL', we now recommend `LT_INIT_LIBTOOL(dlopen)'. The
full list of options is `dlopen', `win32-dll', `shared',
`disable-shared', `static', `disable-static', `fast-install',
`disable-fast-install', `pic-only' and `no-pic'. Additionally if
a version number is listed in the options, we check that the
macros come from a release of libtool at least as new as the
version number given. Various runtime checks in the generated
libtool script will diagnose a version mismatch between the macro
files and the ltmain.sh script used:
* m4/ltversion.in: New file to capture what version number macros
are being used.
* Makefile.am (pkgmacro_DATA): Add m4/ltversion.m4.
(m4/ltversion.m4): New rule to create it from m4/ltversion.in.
* bootstrap: Call the Makefile.am to create an initial
m4/ltversion.m4.
* m4/libtool.m4 (AC_PROVIDE_IFELSE): Removed. We require Autoconf
2.58, which ships this macro.
(AC_PROG_LIBTOOL, _AC_PROG_LIBTOOL, AC_LIBTOOL_SETUP): Removed.
Added AUDEFUNs.
(LT_INIT_LIBTOOL): Replace with an automake like interface which
accepts a version number as a minimum required libtool release at
configure time.
* m4/ltsugar.m4 (lt_version_prereq): Use m4_version_compare to
ensure we meet the prerequisite libtool version.
* m4/ltoptions.m4: New file based on automake/m4/amoptions.m4,
which additionally flags an error if the configuring libtool
macros are not new enough according to LT_LIBTOOL_INIT.
(_LT_ENABLE_SHARED, _LT_ENABLE_STATIC, _LT_ENABLE_FAST_INSTALL)
(_LT_WITH_PIC, _LT_WIN32_DLL): New macros to handle
LT_LIBTOOL_INIT options...
* m4/libtool.m4 (AC_ENABLE_SHARED, AC_ENABLE_STATIC)
(AC_ENABLE_FAST_INSTALL, AC_LIBTOOL_DLOPEN, AC_LIBTOOL_WIN32_DLL):
...to replace these user interface macros, now defined as
AU_DEFUNs.
(AC_DISABLE_SHARED, AC_DISABLE_STATIC, AC_DISABLE_FAST_INSTALL):
Removed. No longer required with LT_INIT_LIBTOOL interface.
Added AU_DEFUNs.
(AM_ENABLE_SHARED, AM_DISABLE_SHARED, AM_ENABLE_STATIC)
(AM_DISABLE_STATIC): Changed AU_DEFUNs to match new interface.
(_LT_SETUP): Internal to LT_INIT_LIBTOOL, replaces
AC_LIBTOOL_SETUP.
* m4/lt~obsolete.m4 (AC_LIBTOOL_SETUP, _AC_PROG_LIBTOOL)
(_LT_PROG_LTMAIN): More AC_DEFUNs that have been retracted.
* ltmain.in: Diagnose version mismatches of various flavours.
Index: Makefile.am
===================================================================
RCS file: /cvsroot/libtool/libtool/Makefile.am,v
retrieving revision 1.96
diff -u -p -u -r1.96 Makefile.am
--- Makefile.am 27 Jan 2004 12:38:47 -0000 1.96
+++ Makefile.am 30 Jan 2004 17:44:34 -0000
@@ -32,10 +32,27 @@ CLEANFILES = libtool libtoolize ltmain.s
pkgdata_SCRIPTS = config/config.guess config/config.sub
pkgdata_DATA = config/ltmain.sh
-# Me maintain our own macros to provent problems with ancient definitions.
+# We maintain our own macros to prevent problems with ancient definitions.
# lt~obsolete.m4 doesn't belong here, it's for bootstrapping us only
pkgmacrodir = $(pkgdatadir)/m4
-pkgmacro_DATA = m4/libtool.m4 m4/ltdl.m4 m4/ltsugar.m4
+dist_pkgmacro_DATA = m4/libtool.m4 m4/ltdl.m4 m4/ltsugar.m4 m4/ltversion.m4
+EXTRA_DIST += m4/ltversion.in
+
+# We build ltversion.m4 here, instead of from config.status,
+# because config.status is rerun each time one og configure's
+# dependencies change and ltversion.m4 happens to be a configure
+# dependency. configure and ltversion.m4 vould be rebuilt in
+# a loop otherwise.
+# Use `$(top_srcdir)/m4' for the benefit of non-GNU makes: this is
+# how ltversion.m4 appears in our dependencies.
+$(top_srcdir)/m4/ltversion.m4: $(top_srcdir)/m4/ltversion.in stamp-vcl
+ set `$(MKSTAMP) < $(top_srcdir)/ChangeLog`; \
+ sed -e "s,address@hidden@],$(VERSION),g" \
+ -e "s,address@hidden@],$$1,g" \
+ -e "s,address@hidden@],Generated from ltversion.in; do not edit by
hand.,g" \
+ $(top_srcdir)/m4/ltversion.in > address@hidden
+ chmod a-w address@hidden
+ mv -f address@hidden $@
# The standalone libtool script, and the libtool distributor.
bin_SCRIPTS = libtool libtoolize
@@ -229,7 +246,6 @@ delta-diff: prev-tarball new-tarball
## Unpack the tarballs somewhere to diff them
rm -rf delta-diff
mkdir delta-diff
-
ofile="../$(PACKAGE)-$(LASTRELEASE)-$(VERSION).diff.gz"; \
cd delta-diff \
&& tar xzf "../$(PACKAGE)-$(LASTRELEASE).tar.gz" \
@@ -243,7 +259,7 @@ delta-diff: prev-tarball new-tarball
&& rm -f $$ofile.directive
rm -rf delta-diff
-
+
XDELTA = xdelta
XDELTA_OPTIONS = --pristine -9
@@ -261,4 +277,3 @@ delta-xdelta: prev-tarball new-tarball g
&& echo "directory: libtool" > $$ofile.directive \
&& $(GPG) --clearsign $$ofile.directive \
&& rm -f $$ofile.directive
-
Index: bootstrap
===================================================================
RCS file: /cvsroot/libtool/libtool/bootstrap,v
retrieving revision 1.37
diff -u -p -u -r1.37 bootstrap
--- bootstrap 4 Jan 2004 20:45:24 -0000 1.37
+++ bootstrap 30 Jan 2004 17:44:34 -0000
@@ -41,6 +41,8 @@ if test -z "$reconfdirs"; then
reconfdirs=". `ls -1d tests/*demo tests/*demo[0-9]`"
fi
+make top_srcdir=. -f Makefile.am ./m4/ltversion.m4
+
for file in $fakes; do
cat > $file <<'EOF'
#! /bin/sh
Index: configure.ac
===================================================================
RCS file: /cvsroot/libtool/libtool/configure.ac,v
retrieving revision 1.33
diff -u -p -u -r1.33 configure.ac
--- configure.ac 27 Jan 2004 12:38:47 -0000 1.33
+++ configure.ac 30 Jan 2004 17:44:34 -0000
@@ -48,26 +48,26 @@ dnl AC_CONFIG_FILES([tests/atlocal])
# http://www.gnu.org/software/libtool/contribute.html
# First we break the version number up into its constituent parts.
-LT_MAJOR=`echo "AC_PACKAGE_VERSION" | sed ['s,\..*$,,g']`
-LT_MINOR=`echo "AC_PACKAGE_VERSION" | sed ['s,^[0-9]*\.\([0-9]*\).*$,\1,']`
-LT_MICRO=`echo "AC_PACKAGE_VERSION" | sed
['s,^[0-9]*\.[0-9]*\(\.[0-9]*\).*$,\1,']`
-LT_ALPHA=`echo "AC_PACKAGE_VERSION" | sed ['s,^[0-9.]*,,']`
+lt_major=`echo "AC_PACKAGE_VERSION" | sed ['s,\..*$,,g']`
+lt_minor=`echo "AC_PACKAGE_VERSION" | sed ['s,^[0-9]*\.\([0-9]*\).*$,\1,']`
+lt_micro=`echo "AC_PACKAGE_VERSION" | sed
['s,^[0-9]*\.[0-9]*\(\.[0-9]*\).*$,\1,']`
+lt_alpha=`echo "AC_PACKAGE_VERSION" | sed ['s,^[0-9.]*,,']`
-test "$LT_MINOR" = "AC_PACKAGE_VERSION" && LT_MINOR=0
-test "$LT_MICRO" = "AC_PACKAGE_VERSION" && LT_MICRO=""
+test "$lt_minor" = "AC_PACKAGE_VERSION" && lt_minor=0
+test "$lt_micro" = "AC_PACKAGE_VERSION" && lt_micro=""
# Then we try to work out what the release before this one would have been
# numbered. The only time we come unstuck is when this is the first release
# from a stable branch (LT_MICRO=LT_ALPHA=""), so LASTRELEASE is the last
# release from the old stable branch, and we don't know what version that
# was, so leave it unset so that the Makefile can complain.
-case $LT_ALPHA in
+case $lt_alpha in
[[ab]])
- case $LT_MICRO in
+ case $lt_micro in
[.[01]])
- LASTRELEASE="$LT_MAJOR.$LT_MINOR" ;;
+ LASTRELEASE="$lt_major.$lt_minor" ;;
*)
- LASTRELEASE="$LT_MAJOR.$LT_MINOR$LT_MICRO" ;;
+ LASTRELEASE="$lt_major.$lt_minor$lt_micro" ;;
esac
;;
[[cegikmoqsuwy]])
@@ -75,14 +75,14 @@ case $LT_ALPHA in
[[dfhjlnprtvxz]])
LASTRELEASE=`echo "AC_PACKAGE_VERSION" | tr 'd-z' 'b-x'` ;;
*) # No LT_ALPHA component
- case $LT_MICRO in
+ case $lt_micro in
.0)
LASTRELEASE="" ;;
.1)
- LASTRELEASE="$LT_MAJOR.$LT_MINOR" ;;
+ LASTRELEASE="$lt_major.$lt_minor" ;;
.*)
- lt_micro_value=`echo $LT_MICRO | sed 's,^\.,,'`
- LASTRELEASE="$LT_MAJOR.$LT_MINOR.`expr $lt_micro_value - 1`" ;;
+ lt_micro_value=`echo $lt_micro | sed 's,^\.,,'`
+ LASTRELEASE="$lt_major.$lt_minor.`expr $lt_micro_value - 1`" ;;
*)
LASTRELEASE="" ;;
esac
@@ -94,7 +94,7 @@ AC_SUBST([LASTRELEASE])
# It is assumed that we only want to see the date extension for cvs libtool
# versions (i.e. "odd" letters) and not actual alpha releases.
TIMESTAMP=
-case $LT_ALPHA in
+case $lt_alpha in
[[acegikmoqsuwy]])
TIMESTAMP=`${CONFIG_SHELL} ${ac_aux_dir}/mkstamp < ${srcdir}/ChangeLog`
AS_BOX([Configuring AC_PACKAGE_TARNAME (Build:$TIMESTAMP)
AC_PACKAGE_VERSION])
@@ -178,9 +178,7 @@ AM_CONDITIONAL(HAVE_RC, [test "x$RC" !=
## Libtool initialisation. ##
## ----------------------- ##
AC_CONFIG_FILES([config/ltmain.sh:./ltmain.in])
-AC_LIBTOOL_DLOPEN
-AC_LIBTOOL_WIN32_DLL
-AC_PROG_LIBTOOL
+LT_INIT_LIBTOOL(dlopen win32-dll)
AC_LIB_LTDL
Index: ltmain.in
===================================================================
RCS file: /cvsroot/libtool/libtool/ltmain.in,v
retrieving revision 1.369
diff -u -p -u -r1.369 ltmain.in
--- ltmain.in 22 Jan 2004 15:27:25 -0000 1.369
+++ ltmain.in 30 Jan 2004 17:44:35 -0000
@@ -65,6 +65,40 @@ mkdir="mkdir"
mv="mv -f"
rm="rm -f"
+# Ensure that we are using m4 macros, and libtool script from the same
+# release of libtool.
+package_revision=`( set $TIMESTAMP; echo $1; )`
+if test "$package_revision" != "$macro_revision"; then
+ if test "$VERSION" != "$macro_version"; then
+ if test -z "$macro_version"; then
+ cat >&2 <<_LT_EOF
+$progname: Version mismatch error. This is $PACKAGE $VERSION, but the
+$progname: definition of this LT_INIT_LIBTOOL comes from an older release.
+$progname: You should recreate aclocal.m4 with macro's from $PACKAGE $VERSION
+$progname: and run autoconf again.
+_LT_EOF
+ else
+ cat >&2 <<_LT_EOF
+$progname: Version mismatch error. This is $PACKAGE $VERSION, but the
+$progname: definition of this LT_INIT_LIBTOOL comes from $PACKAGE
$macro_version.
+$progname: You should recreate aclocal.m4 with macro's from $PACKAGE $VERSION
+$progname: and run autoconf again.
+_LT_EOF
+ fi
+ else
+ cat >&2 <<_LT_EOF
+$progname: Version mismatch error. This is $PACKAGE $VERSION, revision
$package_revision,
+$progname: but the definition used by this LT_INIT_LIBTOOL comes from revision
+$progname: $macro_revision.
+$progname: You should recreate aclocal.m4 with macro's from revision
$package_revision
+$progname: of $PACKAGE $VERSION and run autoconf again.
+_LT_EOF
+ fi
+
+ # $? = 63 is used to indicate version mismatch to missing.
+ exit 63
+fi
+
# Sed substitution that helps us do robust quoting. It backslashifies
# metacharacters that are still active within double-quoted strings.
Xsed="${SED}"' -e 1s/^X//'
Index: m4/libtool.m4
===================================================================
RCS file: /cvsroot/libtool/libtool/m4/libtool.m4,v
retrieving revision 1.35
diff -u -p -u -r1.35 libtool.m4
--- m4/libtool.m4 22 Jan 2004 19:01:19 -0000 1.35
+++ m4/libtool.m4 30 Jan 2004 17:44:37 -0000
@@ -27,33 +27,26 @@ m4_define([_LT_COPYING], [dnl
# the same distribution terms that you use for the rest of that program.
])
-# serial 49 AC_PROG_LIBTOOL
+# serial 50 AC_PROG_LIBTOOL
-# AC_PROVIDE_IFELSE(MACRO-NAME, IF-PROVIDED, IF-NOT-PROVIDED)
-# -----------------------------------------------------------
-# If this macro is not defined by Autoconf, define it here.
-m4_ifdef([AC_PROVIDE_IFELSE],
- [],
- [m4_define([AC_PROVIDE_IFELSE],
- [m4_ifdef([AC_PROVIDE_$1],
- [$2], [$3])])])
-
-# AC_PROG_LIBTOOL
-# ---------------
-AC_DEFUN([AC_PROG_LIBTOOL],
-[AC_REQUIRE([_AC_PROG_LIBTOOL])dnl
-]) # AC_PROG_LIBTOOL
-
-
-# _AC_PROG_LIBTOOL
-# ----------------
-AC_DEFUN([_AC_PROG_LIBTOOL],
-[AC_REQUIRE([AC_LIBTOOL_SETUP])dnl
+# LT_INIT_LIBTOOL([OPTIONS])
+# --------------------------
+AC_DEFUN_ONCE([LT_INIT_LIBTOOL],
+[AC_PREREQ([2.58])dnl We use AC_INCLUDES_DEFAULT
+dnl Autoconf doesn't catch unexpanded LT_ macros by default:
+m4_pattern_forbid([^_?LT_[A-Z_]+$])dnl
+m4_pattern_allow([^(_LT_EOF|LT_DLGLOBAL|LT_DLLAZY_OR_NOW)$])dnl
+dnl aclocal doesn't pull ltoptions.m4, ltsugar.m4, or ltversion.m4
+dnl unless we require an AC_DEFUNed macro:
+AC_REQUIRE([LTOPTIONS_VERSION])dnl
+AC_REQUIRE([LTSUGAR_VERSION])dnl
+AC_REQUIRE([LTVERSION_VERSION])dnl
AC_REQUIRE([_LT_PROG_LTMAIN])dnl
-AC_BEFORE([$0],[AC_LIBTOOL_CXX])dnl
-AC_BEFORE([$0],[AC_LIBTOOL_F77])dnl
-AC_BEFORE([$0],[AC_LIBTOOL_GCJ])dnl
+AC_BEFORE([$0], [AC_LIBTOOL_CXX])dnl
+AC_BEFORE([$0], [AC_LIBTOOL_F77])dnl
+AC_BEFORE([$0], [AC_LIBTOOL_GCJ])dnl
+_LT_SET_OPTIONS([$1])dnl
# This can be used to rebuild libtool when needed
LIBTOOL_DEPS="$ltmain"
@@ -62,56 +55,47 @@ LIBTOOL_DEPS="$ltmain"
LIBTOOL='$(SHELL) $(top_builddir)/libtool'
AC_SUBST(LIBTOOL)dnl
-# Prevent multiple expansion
-define([AC_PROG_LIBTOOL], [])
-])# _AC_PROG_LIBTOOL
-
-
-# _LT_PROG_LTMAIN
-# ---------------
-# In libtool itself `ltmain.sh' is in the build tree, but everything else
-# ships it in the source tree, for completeness, if we find a copy in the
-# build tree use that before falling back to auxdir.
-#
-# Note that this code is called both from `configure', and `config.status'
-# now that we use AC_CONFIG_COMMANDS to generate libtool. Notably,
-# `config.status' has no value for ac_aux_dir unless we are using Automake,
-# so we pass a copy along to make sure it has a sensible value anyway.
-AC_DEFUN([_LT_PROG_LTMAIN],
-[_LT_CONFIG_LIBTOOL_INIT([ac_aux_dir='$ac_aux_dir'])
-case $ac_aux_dir in
- $srcdir) ltmain=./ltmain.sh ;;
- $srcdir/*) ltmain=`expr "$ac_aux_dir" : "$srcdir/\(.*\)"`/ltmain.sh ;;
-esac
-test -f "$ltmain" || ltmain="$ac_aux_dir/ltmain.sh"
-])# _LT_PROG_LTMAIN
-
-
-# AC_LIBTOOL_SETUP
-# ----------------
-AC_DEFUN([AC_LIBTOOL_SETUP],
-[AC_PREREQ(2.56)dnl We use the new compiler based header checking in 2.56
-AC_REQUIRE([LTSUGAR_VERSION])dnl
-AC_REQUIRE([AC_CANONICAL_HOST])dnl
+# Set options
+_LT_IF_OPTION([dlopen], enable_dlopen=yes, enable_dlopen=no)
+_LT_IF_OPTION([win32-dll], enable_win32_dll=yes, enable_win32_dll=no)
+_LT_IF_OPTION([shared], [_LT_ENABLE_SHARED],
+ [_LT_IF_OPTION([disable-shared], [_LT_ENABLE_SHARED(no)],
+ [_LT_ENABLE_SHARED])])
+_LT_IF_OPTION([static], [_LT_ENABLE_STATIC],
+ [_LT_IF_OPTION([disable-static], [_LT_ENABLE_STATIC(no)],
+ [_LT_ENABLE_STATIC])])
+_LT_IF_OPTION([fast-install], [_LT_ENABLE_FAST_INSTALL],
+ [_LT_IF_OPTION([disable-fast-install], [_LT_ENABLE_FAST_INSTALL(no)],
+ [_LT_ENABLE_FAST_INSTALL])])
+_LT_IF_OPTION([pic-only], [_LT_WITH_PIC(yes)],
+ [_LT_IF_OPTION([no-pic], [_LT_WITH_PIC(no)],
+ [_LT_WITH_PIC])])
+
+_LT_SETUP
+])# LT_INIT_LIBTOOL
+
+
+# _LT_SETUP
+#----------
+m4_define([_LT_SETUP],
+[AC_REQUIRE([AC_CANONICAL_HOST])dnl
AC_REQUIRE([AC_CANONICAL_BUILD])dnl
_LT_DECL([], [host_alias], [0], [The host system])dnl
_LT_DECL([], [host], [0])dnl
-
+dnl
AC_REQUIRE([AC_PROG_CC])dnl
AC_REQUIRE([AC_PROG_LD])dnl
AC_REQUIRE([AC_PROG_LD_RELOAD_FLAG])dnl
AC_REQUIRE([AC_PROG_NM])dnl
-
+dnl
AC_REQUIRE([AC_PROG_LN_S])dnl
test -z "$LN_S" && LN_S="ln -s"
_LT_DECL([], [LN_S], [1], [Whether we need soft or hard links])dnl
-
+dnl
AC_REQUIRE([AC_DEPLIBS_CHECK_METHOD])dnl
AC_REQUIRE([AC_LIBTOOL_SYS_OLD_ARCHIVE])dnl
AC_REQUIRE([AC_LIBTOOL_SYS_MAX_CMD_LEN])dnl
AC_REQUIRE([AC_LIBTOOL_SYS_GLOBAL_SYMBOL_PIPE])dnl
-
-# Autoconf 2.13's AC_OBJEXT and AC_EXEEXT macros only works for C compilers!
AC_REQUIRE([AC_OBJEXT])dnl
_LT_DECL([objext], [ac_objext], [0], [Object file suffix (normally "o")])dnl
AC_REQUIRE([AC_EXEEXT])dnl
@@ -129,10 +113,8 @@ if test -n "${ZSH_VERSION+set}" ; then
setopt NO_GLOB_SUBST
fi
-AC_ENABLE_SHARED
-AC_ENABLE_STATIC
-AC_ENABLE_FAST_INSTALL
AC_LIBTOOL_OBJDIR
+_LT_IF_OPTION([win32-dll], [_LT_WIN32_DLL])
AC_REQUIRE([_LT_AC_SYS_COMPILER])dnl
_LT_AC_PROG_ECHO_BACKSLASH
@@ -200,30 +182,37 @@ file_magic*)
;;
esac
-AC_PROVIDE_IFELSE([AC_LIBTOOL_DLOPEN], enable_dlopen=yes, enable_dlopen=no)
-AC_PROVIDE_IFELSE([AC_LIBTOOL_WIN32_DLL],
-enable_win32_dll=yes, enable_win32_dll=no)
-
AC_ARG_ENABLE([libtool-lock],
[AC_HELP_STRING([--disable-libtool-lock],
[avoid locking (might break parallel builds)])])
test "x$enable_libtool_lock" != xno && enable_libtool_lock=yes
-AC_ARG_WITH([pic],
- [AC_HELP_STRING([--with-pic],
- [try to use only PIC/non-PIC objects @<:@default=use both@:>@])],
- [pic_mode="$withval"],
- [pic_mode=default])
-test -z "$pic_mode" && pic_mode=default
-_LT_DECL([], [pic_mode], [0], [What type of objects to build])
-
# Use C for the default configuration in the libtool script
AC_LIBTOOL_LANG_C_CONFIG
_LT_AC_TAG_CONFIG
_LT_CONFIG_COMMANDS
-])# AC_LIBTOOL_SETUP
+])# _LT_SETUP
+# _LT_PROG_LTMAIN
+# ---------------
+# In libtool itself `ltmain.sh' is in the build tree, but everything else
+# ships it in the source tree, for completeness, if we find a copy in the
+# build tree use that before falling back to auxdir.
+#
+# Note that this code is called both from `configure', and `config.status'
+# now that we use AC_CONFIG_COMMANDS to generate libtool. Notably,
+# `config.status' has no value for ac_aux_dir unless we are using Automake,
+# so we pass a copy along to make sure it has a sensible value anyway.
+AC_DEFUN([_LT_PROG_LTMAIN],
+[_LT_CONFIG_LIBTOOL_INIT([ac_aux_dir='$ac_aux_dir'])dnl
+case $ac_aux_dir in
+ $srcdir) ltmain=./ltmain.sh ;;
+ $srcdir/*) ltmain=`expr "$ac_aux_dir" : "$srcdir/\(.*\)"`/ltmain.sh ;;
+esac
+test -f "$ltmain" || ltmain="$ac_aux_dir/ltmain.sh"
+])# _LT_PROG_LTMAIN
+
## ------------------------------------- ##
@@ -2068,6 +2057,7 @@ m4_define([_LT_AC_TAG_CHECK],
[m4_define([_LT_TAG_]$1, [])])
]) # _LT_AC_TAG_CHECK
+
# _LT_AC_TAG_CONFIG
# -----------------
m4_define([_LT_AC_TAG_CONFIG],
@@ -2131,173 +2121,6 @@ m4_define([_LT_AC_TAG_CONFIG],
])# _LT_AC_TAG_CONFIG
-# AC_LIBTOOL_DLOPEN
-# -----------------
-# enable checks for dlopen support
-AC_DEFUN([AC_LIBTOOL_DLOPEN],
- [AC_BEFORE([$0],[AC_LIBTOOL_SETUP])
-])# AC_LIBTOOL_DLOPEN
-
-
-# AC_LIBTOOL_WIN32_DLL
-# --------------------
-# declare package support for building win32 dll's
-AC_DEFUN([AC_LIBTOOL_WIN32_DLL],
-[AC_BEFORE([$0], [AC_LIBTOOL_SETUP])
-test -z "$AS" && AS=as
-test -z "$DLLTOOL" && DLLTOOL=dlltool
-test -z "$OBJDUMP" && OBJDUMP=objdump
-
-case $host in
-*-*-cygwin* | *-*-mingw* | *-*-pw32*)
- AC_CHECK_TOOL(AS, as, false)
- AC_CHECK_TOOL(DLLTOOL, dlltool, false)
- AC_CHECK_TOOL(OBJDUMP, objdump, false)
- ;;
-esac
-
-_LT_DECL([], [AS], [0], [Assembler program])dnl
-_LT_DECL([], [DLLTOOL], [0], [DLL creation program])dnl
-_LT_DECL([], [OBJDUMP], [0], [Object dumper program])dnl
-])# AC_LIBTOOL_WIN32_DLL
-
-
-# AC_ENABLE_SHARED([DEFAULT])
-# ---------------------------
-# implement the --enable-shared flag
-# DEFAULT is either `yes' or `no'. If omitted, it defaults to `yes'.
-AC_DEFUN([AC_ENABLE_SHARED],
-[m4_define([AC_ENABLE_SHARED_DEFAULT], [m4_if($1, no, no, yes)])dnl
-AC_ARG_ENABLE([shared],
- [AC_HELP_STRING([--enable-shared@<:@=PKGS@:>@],
- [build shared libraries @<:@default=]AC_ENABLE_SHARED_DEFAULT[@:>@])],
- [p=${PACKAGE-default}
- case $enableval in
- yes) enable_shared=yes ;;
- no) enable_shared=no ;;
- *)
- enable_shared=no
- # Look at the argument we got. We use all the common list separators.
- lt_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR,"
- for pkg in $enableval; do
- IFS="$lt_save_ifs"
- if test "X$pkg" = "X$p"; then
- enable_shared=yes
- fi
- done
- IFS="$lt_save_ifs"
- ;;
- esac],
- [enable_shared=]AC_ENABLE_SHARED_DEFAULT)
-
- _LT_DECL([build_libtool_libs], [enable_shared], [0],
- [Whether or not to build shared libraries])
-])# AC_ENABLE_SHARED
-
-
-# AC_DISABLE_SHARED
-# -----------------
-#- set the default shared flag to --disable-shared
-AC_DEFUN([AC_DISABLE_SHARED],
-[AC_BEFORE([$0],[AC_LIBTOOL_SETUP])dnl
-AC_ENABLE_SHARED(no)
-])# AC_DISABLE_SHARED
-
-
-# AC_ENABLE_STATIC([DEFAULT])
-# ---------------------------
-# implement the --enable-static flag
-# DEFAULT is either `yes' or `no'. If omitted, it defaults to `yes'.
-AC_DEFUN([AC_ENABLE_STATIC],
-[m4_define([AC_ENABLE_STATIC_DEFAULT], [m4_if($1, no, no, yes)])dnl
-AC_ARG_ENABLE([static],
- [AC_HELP_STRING([--enable-static@<:@=PKGS@:>@],
- [build static libraries @<:@default=]AC_ENABLE_STATIC_DEFAULT[@:>@])],
- [p=${PACKAGE-default}
- case $enableval in
- yes) enable_static=yes ;;
- no) enable_static=no ;;
- *)
- enable_static=no
- # Look at the argument we got. We use all the common list separators.
- lt_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR,"
- for pkg in $enableval; do
- IFS="$lt_save_ifs"
- if test "X$pkg" = "X$p"; then
- enable_static=yes
- fi
- done
- IFS="$lt_save_ifs"
- ;;
- esac],
- [enable_static=]AC_ENABLE_STATIC_DEFAULT)
-
- _LT_DECL([build_old_libs], [enable_static], [0],
- [Whether or not to build static libraries])
-])# AC_ENABLE_STATIC
-
-
-# AC_DISABLE_STATIC
-# -----------------
-# set the default static flag to --disable-static
-AC_DEFUN([AC_DISABLE_STATIC],
-[AC_BEFORE([$0],[AC_LIBTOOL_SETUP])dnl
-AC_ENABLE_STATIC(no)
-])# AC_DISABLE_STATIC
-
-
-# AC_ENABLE_FAST_INSTALL([DEFAULT])
-# ---------------------------------
-# implement the --enable-fast-install flag
-# DEFAULT is either `yes' or `no'. If omitted, it defaults to `yes'.
-AC_DEFUN([AC_ENABLE_FAST_INSTALL],
-[m4_define([AC_ENABLE_FAST_INSTALL_DEFAULT], [m4_if($1, no, no, yes)])dnl
-AC_ARG_ENABLE([fast-install],
- [AC_HELP_STRING([--enable-fast-install@<:@=PKGS@:>@],
- [optimize for fast installation
@<:@default=]AC_ENABLE_FAST_INSTALL_DEFAULT[@:>@])],
- [p=${PACKAGE-default}
- case $enableval in
- yes) enable_fast_install=yes ;;
- no) enable_fast_install=no ;;
- *)
- enable_fast_install=no
- # Look at the argument we got. We use all the common list separators.
- lt_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR,"
- for pkg in $enableval; do
- IFS="$lt_save_ifs"
- if test "X$pkg" = "X$p"; then
- enable_fast_install=yes
- fi
- done
- IFS="$lt_save_ifs"
- ;;
- esac],
- [enable_fast_install=]AC_ENABLE_FAST_INSTALL_DEFAULT)
-
- _LT_DECL([fast_install], [enable_fast_install], [0],
- [Whether or not to optimize for fast installation])
-])# AC_ENABLE_FAST_INSTALL
-
-
-# AC_DISABLE_FAST_INSTALL
-# -----------------------
-# set the default to --disable-fast-install
-AC_DEFUN([AC_DISABLE_FAST_INSTALL],
-[AC_BEFORE([$0],[AC_LIBTOOL_SETUP])dnl
-AC_ENABLE_FAST_INSTALL(no)
-])# AC_DISABLE_FAST_INSTALL
-
-
-# AC_LIBTOOL_PICMODE([MODE])
-# --------------------------
-# implement the --with-pic flag
-# MODE is either `yes' or `no'. If omitted, it defaults to `both'.
-AC_DEFUN([AC_LIBTOOL_PICMODE],
-[AC_BEFORE([$0],[AC_LIBTOOL_SETUP])dnl
-pic_mode=m4_if($#, 1, $1, default)
-])# AC_LIBTOOL_PICMODE
-
-
# AC_PATH_TOOL_PREFIX
# -------------------
# find a file program which can recognise shared library
@@ -5842,14 +5665,27 @@ AC_DEFUN([LT_AC_PROG_RC],
[AC_CHECK_TOOL(RC, windres, no)
])
-# old names
-AU_DEFUN([AM_PROG_LIBTOOL], [AC_PROG_LIBTOOL])
-AU_DEFUN([AM_ENABLE_SHARED], [AC_ENABLE_SHARED($@)])
-AU_DEFUN([AM_ENABLE_STATIC], [AC_ENABLE_STATIC($@)])
-AU_DEFUN([AM_DISABLE_SHARED], [AC_DISABLE_SHARED($@)])
-AU_DEFUN([AM_DISABLE_STATIC], [AC_DISABLE_STATIC($@)])
-AU_DEFUN([AM_PROG_LD], [AC_PROG_LD])
-AU_DEFUN([AM_PROG_NM], [AC_PROG_NM])
+# ---------- #
+# old names. #
+# ---------- #
+
+AU_DEFUN([AC_DISABLE_FAST_INSTALL], [_LT_SET_OPTION([disable-fast-install])
+AU_DEFUN([AC_DISABLE_SHARED], [_LT_SET_OPTION([disable-shared])])
+AU_DEFUN([AC_DISABLE_STATIC], [_LT_SET_OPTION([disable-static])])
+AU_DEFUN([AC_ENABLE_FAST_INSTALL], [_LT_SET_OPTION([fast-install])
+AU_DEFUN([AC_ENABLE_SHARED], [_LT_SET_OPTION([shared])])
+AU_DEFUN([AC_ENABLE_STATIC], [_LT_SET_OPTION([static])])
+AU_DEFUN([AC_LIBTOOL_DLOPEN], [_LT_SET_OPTION([dlopen])])
+AU_DEFUN([AC_LIBTOOL_PIC_MODE], [_LT_SET_OPTION([pic-only])])
+AU_DEFUN([AC_LIBTOOL_WIN32_DLL], [_LT_SET_OPTION([win32-dll])])
+AU_DEFUN([AC_PROG_LIBTOOL], [LT_INIT_LIBTOOL])
+AU_DEFUN([AM_DISABLE_SHARED], [_LT_SET_OPTION([disable-shared])])
+AU_DEFUN([AM_DISABLE_STATIC], [_LT_SET_OPTION([disable-static])])
+AU_DEFUN([AM_ENABLE_SHARED], [_LT_SET_OPTION([enable-shared])])
+AU_DEFUN([AM_ENABLE_STATIC], [_LT_SET_OPTION([enable-static])])
+AU_DEFUN([AM_PROG_LD], [AC_PROG_LD])
+AU_DEFUN([AM_PROG_LIBTOOL], [LT_INIT_LIBTOOL])
+AU_DEFUN([AM_PROG_NM], [AC_PROG_NM])
# This is just to silence aclocal about the macro not being used
m4_if([AC_DISABLE_FAST_INSTALL])
Index: m4/ltoptions.m4
===================================================================
RCS file: m4/ltoptions.m4
diff -N m4/ltoptions.m4
--- /dev/null 1 Jan 1970 00:00:00 -0000
+++ m4/ltoptions.m4 30 Jan 2004 17:44:37 -0000
@@ -0,0 +1,200 @@
+# Helper functions for option handling. -*- Autoconf -*-
+
+# Copyright (C) 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
+# Adapted from m4/options.m4 (#serial 2) in GNU Automake
+
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2, or (at your option)
+# any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software
+# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
+# 02111-1307, USA.
+
+# serial 1
+
+# This is to help aclocal find these macros, as it can't see m4_define.
+AC_DEFUN([LTOPTIONS_VERSION], [m4_if([1])])
+
+
+# _LT_MANGLE_OPTION(NAME)
+# -----------------------
+m4_define([_LT_MANGLE_OPTION],
+[[_LT_OPTION_]m4_bpatsubst($1, [[^a-zA-Z0-9_]], [_])])
+
+
+# _LT_SET_OPTION(NAME)
+# ------------------------------
+# Set option NAME. If NAME is a version number, then check that the
+# m4 macros we are using come from at least as new a version as the
+# parameter. Other NAMEs are saved as a flag.
+m4_define([_LT_SET_OPTION],
+[m4_bmatch([$1], [[1-9][0-9]*\.[0-9]+\(\.[0-9]+\)?[a-z]?],
+ [lt_version_prereq([$1])],
+ [m4_define(_LT_MANGLE_OPTION([$1]), 1)])
+])
+
+
+# _LT_SET_OPTIONS(OPTIONS)
+# ----------------------------------
+# OPTIONS is a space-separated list of Automake options.
+m4_define([_LT_SET_OPTIONS],
+[AC_FOREACH([_LT_Option], [$1], [_LT_SET_OPTION(_LT_Option)])])
+
+
+# _LT_IF_OPTION(OPTION, IF-SET, [IF-NOT-SET])
+# -------------------------------------------
+# Execute IF-SET if OPTION is set, IF-NOT-SET otherwise.
+m4_define([_LT_IF_OPTION],
+[m4_ifset(_LT_MANGLE_OPTION([$1]), [$2], [$3])])
+
+
+# _LT_WIN32_DLL
+# -------------
+# Declare package support for building win32 dll's. Used to implement
+# the `win32-dll' LT_INIT_LIBTOOL option.
+m4_define([_LT_WIN32_DLL],
+[AC_BEFORE([$0], [AC_LIBTOOL_SETUP])
+test -z "$AS" && AS=as
+test -z "$DLLTOOL" && DLLTOOL=dlltool
+test -z "$OBJDUMP" && OBJDUMP=objdump
+
+case $host in
+*-*-cygwin* | *-*-mingw* | *-*-pw32*)
+ AC_CHECK_TOOL(AS, as, false)
+ AC_CHECK_TOOL(DLLTOOL, dlltool, false)
+ AC_CHECK_TOOL(OBJDUMP, objdump, false)
+ ;;
+esac
+
+_LT_DECL([], [AS], [0], [Assembler program])dnl
+_LT_DECL([], [DLLTOOL], [0], [DLL creation program])dnl
+_LT_DECL([], [OBJDUMP], [0], [Object dumper program])dnl
+])# _LT_WIN32_DLL
+
+
+# _LT_ENABLE_SHARED([DEFAULT])
+# ----------------------------
+# implement the --enable-shared flag, and supports the `shared' and
+# `disable-shared' LT_INIT_LIBTOOL options.
+# DEFAULT is either `yes' or `no'. If omitted, it defaults to `yes'.
+m4_define([_LT_ENABLE_SHARED],
+[m4_define([_LT_ENABLE_SHARED_DEFAULT], [m4_if($1, no, no, yes)])dnl
+AC_ARG_ENABLE([shared],
+ [AC_HELP_STRING([--enable-shared@<:@=PKGS@:>@],
+ [build shared libraries @<:@default=]_LT_ENABLE_SHARED_DEFAULT[@:>@])],
+ [p=${PACKAGE-default}
+ case $enableval in
+ yes) enable_shared=yes ;;
+ no) enable_shared=no ;;
+ *)
+ enable_shared=no
+ # Look at the argument we got. We use all the common list separators.
+ lt_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR,"
+ for pkg in $enableval; do
+ IFS="$lt_save_ifs"
+ if test "X$pkg" = "X$p"; then
+ enable_shared=yes
+ fi
+ done
+ IFS="$lt_save_ifs"
+ ;;
+ esac],
+ [enable_shared=]_LT_ENABLE_SHARED_DEFAULT)
+
+ _LT_DECL([build_libtool_libs], [enable_shared], [0],
+ [Whether or not to build shared libraries])
+])# _LT_ENABLE_SHARED
+
+
+# _LT_ENABLE_STATIC([DEFAULT])
+# ----------------------------
+# implement the --enable-static flag, and support the `static' and
+# `disable-static' LT_INIT_LIBTOOL options.
+# DEFAULT is either `yes' or `no'. If omitted, it defaults to `yes'.
+m4_define([_LT_ENABLE_STATIC],
+[m4_define([_LT_ENABLE_STATIC_DEFAULT], [m4_if($1, no, no, yes)])dnl
+AC_ARG_ENABLE([static],
+ [AC_HELP_STRING([--enable-static@<:@=PKGS@:>@],
+ [build static libraries @<:@default=]_LT_ENABLE_STATIC_DEFAULT[@:>@])],
+ [p=${PACKAGE-default}
+ case $enableval in
+ yes) enable_static=yes ;;
+ no) enable_static=no ;;
+ *)
+ enable_static=no
+ # Look at the argument we got. We use all the common list separators.
+ lt_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR,"
+ for pkg in $enableval; do
+ IFS="$lt_save_ifs"
+ if test "X$pkg" = "X$p"; then
+ enable_static=yes
+ fi
+ done
+ IFS="$lt_save_ifs"
+ ;;
+ esac],
+ [enable_static=]_LT_ENABLE_STATIC_DEFAULT)
+
+ _LT_DECL([build_old_libs], [enable_static], [0],
+ [Whether or not to build static libraries])
+])# _LT_ENABLE_STATIC
+
+
+# _LT_ENABLE_FAST_INSTALL([DEFAULT])
+# ----------------------------------
+# implement the --enable-fast-install flag, and support the `fast-install'
+# and `disable-fast-install' LT_INIT_LIBTOOL options.
+# DEFAULT is either `yes' or `no'. If omitted, it defaults to `yes'.
+m4_define([_LT_ENABLE_FAST_INSTALL],
+[m4_define([_LT_ENABLE_FAST_INSTALL_DEFAULT], [m4_if($1, no, no, yes)])dnl
+AC_ARG_ENABLE([fast-install],
+ [AC_HELP_STRING([--enable-fast-install@<:@=PKGS@:>@],
+ [optimize for fast installation
@<:@default=]_LT_ENABLE_FAST_INSTALL_DEFAULT[@:>@])],
+ [p=${PACKAGE-default}
+ case $enableval in
+ yes) enable_fast_install=yes ;;
+ no) enable_fast_install=no ;;
+ *)
+ enable_fast_install=no
+ # Look at the argument we got. We use all the common list separators.
+ lt_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR,"
+ for pkg in $enableval; do
+ IFS="$lt_save_ifs"
+ if test "X$pkg" = "X$p"; then
+ enable_fast_install=yes
+ fi
+ done
+ IFS="$lt_save_ifs"
+ ;;
+ esac],
+ [enable_fast_install=]_LT_ENABLE_FAST_INSTALL_DEFAULT)
+
+_LT_DECL([fast_install], [enable_fast_install], [0],
+ [Whether or not to optimize for fast installation])dnl
+])# _LT_ENABLE_FAST_INSTALL
+
+
+# _LT_WITH_PIC([MODE])
+# --------------------
+# implement the --with-pic flag, and support the `pic-only' and `no-pic'
+# LT_INIT_LIBTOOL options.
+# MODE is either `yes' or `no'. If omitted, it defaults to `both'.
+m4_define([_LT_WITH_PIC],
+[AC_ARG_WITH([pic],
+ [AC_HELP_STRING([--with-pic],
+ [try to use only PIC/non-PIC objects @<:@default=use both@:>@])],
+ [pic_mode="$withval"],
+ [pic_mode=default])
+
+test -z "$pic_mode" && pic_mode=m4_if($#, 1, $1, default)
+
+_LT_DECL([], [pic_mode], [0], [What type of objects to build])dnl
+])# _LT_WITH_PIC
Index: m4/ltsugar.m4
===================================================================
RCS file: /cvsroot/libtool/libtool/m4/ltsugar.m4,v
retrieving revision 1.2
diff -u -p -u -r1.2 ltsugar.m4
--- m4/ltsugar.m4 8 Jan 2004 10:34:52 -0000 1.2
+++ m4/ltsugar.m4 30 Jan 2004 17:44:37 -0000
@@ -113,3 +113,15 @@ m4_define([lt_dict_filter],
m4_quote(lt_if_dict_fetch([$1], [$5], [$2], [$3], [$5])),
m4_quote($0([$1], [$2], [$3], [$4], m4_shiftn(5, $@))))])dnl
])
+
+
+# lt_version_prereq(VERSION, [IF-OK], [IF-NOT = FAIL])
+# ----------------------------------------------------
+# Check this Libtool version against VERSION.
+m4_define([lt_version_prereq],
+[m4_if(m4_version_compare(m4_defn([LT_PACKAGE_VERSION]), [$1]), -1,
+ [m4_default([$3],
+ [m4_fatal([Libtool version $1 or higher is required],
+ 63)])],
+ [$2])[]dnl
+])
Index: m4/ltversion.in
===================================================================
RCS file: m4/ltversion.in
diff -N m4/ltversion.in
--- /dev/null 1 Jan 1970 00:00:00 -0000
+++ m4/ltversion.in 30 Jan 2004 17:44:37 -0000
@@ -0,0 +1,14 @@
+# ltversion.m4 -- version numbers -*- Autoconf -*-
+# @configure_input@
+
+# This file is part of GNU Libtool
+
+m4_define([LT_PACKAGE_VERSION], address@hidden@])
+m4_define([LT_PACKAGE_REVISION], address@hidden@])
+
+AC_DEFUN([LTVERSION_VERSION],
+[macro_version='@MACRO_VERSION@'
+macro_revision='@MACRO_REVISION@'
+_LT_DECL(, macro_version, 0, [Which release of libtool.m4 was used?])
+_LT_DECL(, macro_revision, 0)
+])
Index: m4/lt~obsolete.m4
===================================================================
RCS file: /cvsroot/libtool/libtool/m4/lt~obsolete.m4,v
retrieving revision 1.1
diff -u -p -u -r1.1 lt~obsolete.m4
--- m4/lt~obsolete.m4 15 Jan 2004 19:16:51 -0000 1.1
+++ m4/lt~obsolete.m4 30 Jan 2004 17:44:37 -0000
@@ -1,5 +1,5 @@
# lt~obsolete.m4 -- aclocal satisfying obsolete definitions. -*-Autoconf-*-
-#
+#
# Copyright (C) 2004 Free Software Foundation, Inc.
# Written by Scott James Remnant.
#
@@ -35,22 +35,24 @@
# using a macro with the same name in our local m4/libtool.m4 it'll
# pull the old libtool.m4 in (it doesn't see our shiny new m4_define
# and doesn't know about Autoconf macros at all.)
-#
+#
# So we provide this file, which has a silly filename so it's always
# included after everything else. This provides aclocal with the
# AU_DEFUNs it wants, but when m4 processes it, it doesn't do anything
# because those macros already exist.
-#
+#
# Anytime we withdraw an AC_DEFUN or AU_DEFUN, but still refer to it,
# remember to add it here.
-m4_ifdef([AC_LIBTOOL_CONFIG], [], [AU_DEFUN([AC_LIBTOOL_CONFIG])])dnl
-m4_ifdef([AC_LIBTOOL_LINKER_OPTION], [],
[AU_DEFUN([AC_LIBTOOL_LINKER_OPTION])])dnl
-m4_ifdef([AC_PROG_EGREP], [], [AU_DEFUN([AC_PROG_EGREP])])dnl
-m4_ifdef([_LT_AC_LANG_C_CONFIG], [], [AU_DEFUN([_LT_AC_LANG_C_CONFIG])])dnl
-m4_ifdef([_LT_AC_LANG_GCJ_CONFIG], [], [AU_DEFUN([_LT_AC_LANG_GCJ_CONFIG])])dnl
-m4_ifdef([_LT_AC_LANG_RC_CONFIG], [], [AU_DEFUN([_LT_AC_LANG_RC_CONFIG])])dnl
-m4_ifdef([_LT_AC_PROG_ECHO_BACKSLASH], [],
[AU_DEFUN([_LT_AC_PROG_ECHO_BACKSLASH])])dnl
-m4_ifdef([_LT_AC_SHELL_INIT], [], [AU_DEFUN([_LT_AC_SHELL_INIT])])dnl
-m4_ifdef([_LT_AC_SYS_LIBPATH_AIX], [], [AU_DEFUN([_LT_AC_SYS_LIBPATH_AIX])])dnl
-m4_ifdef([_LT_AC_TAGVAR], [], [AU_DEFUN([_LT_AC_TAGVAR])])dnl
+m4_ifdef([AC_LIBTOOL_CONFIG],, [AU_DEFUN([AC_LIBTOOL_CONFIG])])
+m4_ifdef([AC_LIBTOOL_LINKER_OPTION],, [AU_DEFUN([AC_LIBTOOL_LINKER_OPTION])])
+m4_ifdef([AC_LIBTOOL_SETUP],, [AU_DEFUN([AC_LIBTOOL_SETUP])])
+m4_ifdef([AC_PROG_EGREP],, [AU_DEFUN([AC_PROG_EGREP])])
+m4_ifdef([_AC_PROG_LIBTOOL],, [AU_DEFUN([_AC_PROG_LIBTOOL])])
+m4_ifdef([_LT_AC_LANG_C_CONFIG],, [AU_DEFUN([_LT_AC_LANG_C_CONFIG])])
+m4_ifdef([_LT_AC_LANG_GCJ_CONFIG],, [AU_DEFUN([_LT_AC_LANG_GCJ_CONFIG])])
+m4_ifdef([_LT_AC_LANG_RC_CONFIG],, [AU_DEFUN([_LT_AC_LANG_RC_CONFIG])])
+m4_ifdef([_LT_AC_PROG_ECHO_BACKSLASH],,
[AU_DEFUN([_LT_AC_PROG_ECHO_BACKSLASH])])
+m4_ifdef([_LT_AC_SHELL_INIT],, [AU_DEFUN([_LT_AC_SHELL_INIT])])
+m4_ifdef([_LT_AC_SYS_LIBPATH_AIX],, [AU_DEFUN([_LT_AC_SYS_LIBPATH_AIX])])
+m4_ifdef([_LT_PROG_LTMAIN],, [AU_DEFUN([_LT_PROG_LTMAIN])])
- RFC: 77-gary-diagnose-version-mismatch.patch,
Gary V. Vaughan <=