Re: address@hidden: emacs customization suggestion: 'customize-existing']

[Per Abrahamsen]

Richard Stallman <address@hidden> writes:

>     > Perhaps we could use something to customize all the options that have
>     > non-default customizations, which is a little different from
>     > customize-customized.
>
>     How is it different?  Or rather, what do you mean by "non-default
>     customizations"? 
>
> customize-customized shows you the variables that have unsaved
> customizations.
>
> This proposed command would also show you the variables that have
> customize settings that are saved.

customize-saved also exists.  Combining them is trivial, but I'm not
sure the extra functionality is worth the extra command.

;;;###autoload
(defun customize-touched ()
  "Customize all user options that have been set through customize."
  (interactive)
  (let ((found nil))
    (mapatoms (lambda (symbol)
                (and (or (get symbol 'customized-face)
                         (get symbol 'customized-face-comment)
                         (get symbol 'saved-face)
                         (get symbol 'saved-face-comment))
                     (custom-facep symbol)
                     (push (list symbol 'custom-face) found))
                (and (or (get symbol 'customized-value)
                         (get symbol 'customized-variable-comment)
                         (get symbol 'saved-value)
                         (get symbol 'saved-variable-comment))
                     (boundp symbol)
                     (push (list symbol 'custom-variable) found))))
    (if (not found)
        (error "No touched user options")
      (custom-buffer-create (custom-sort-items found t nil)
                            "*Customize Touched*"))))