Re: c-ts-mode

[João Távora]

On Thu, Sep 7, 2023 at 7:32 PM Eli Zaretskii <eliz@gnu.org> wrote:
>
> > From: João Távora <joaotavora@gmail.com>
> > Date: Thu, 7 Sep 2023 19:23:33 +0100
> > Cc: casouri@gmail.com, spacibba@aol.com, emacs-devel@gnu.org
> >
> > The real challenge is writing the rules themselves.  I'm missing
> > a kind of "debug rule" that doesn't do anything but prints out
> > contextual information from the node, parent-node, grandparents.
> > I made one but it's not very good.  Is there something like that?
> > Wouldn't even need to be an indentation rule, more like a "describe
> > AST at point"...
>
> Did you try "M-x treesit-explore-mode RET"?

That's a great find, and so is M-x treesit-inspect-mode.

My rules are now done.

(setq c-ts-mode-indent-style
      (lambda ()
        (append '(((n-p-gp nil nil "namespace_definition") grand-parent 0)
                  ((n-p-gp nil nil "linkage_specification") grand-parent 0))
                (alist-get 'gnu (c-ts-mode--indent-styles 'cpp)))))

The lambda, cl-list*, the alist-get and the '--' are ugly but
beyond that, it's better than cc-mode's system, to be honest.

Anyway, to get the ugly out, here's an idea.

IMHO making c-ts-mode--indent-styles a public CL-style
generic function would be a good possibility.

It's a simple patch to allow that.

diff --git a/lisp/progmodes/c-ts-mode.el b/lisp/progmodes/c-ts-mode.el
index 5f685e016d2..337c8c4eed1 100644
--- a/lisp/progmodes/c-ts-mode.el
+++ b/lisp/progmodes/c-ts-mode.el
@@ -165,9 +165,12 @@ c-ts-mode--get-indent-style
   (let ((style
          (if (functionp c-ts-mode-indent-style)
              (funcall c-ts-mode-indent-style)
-           (alist-get c-ts-mode-indent-style
(c-ts-mode--indent-styles mode)))))
+           (c-ts-mode-indent-styles c-ts-mode-indent-style mode))))
     `((,mode ,@style))))

+(cl-defgeneric c-ts-mode-indent-styles (style mode)
+  (alist-get style (c-ts-mode--indent-styles mode)))
+
 (defun c-ts-mode--prompt-for-style ()
   "Prompt for an indent style and return the symbol for it."
   (let ((mode (if (derived-mode-p 'c-ts-mode) 'c 'c++)))


With this patch, my rules become:

(cl-defmethod c-ts-mode-indent-styles ((_style (eql gnu)) (_m (eql cpp)))
  (append '(((n-p-gp nil nil "namespace_definition") grand-parent 0)
            ((n-p-gp nil nil "linkage_specification") grand-parent 0))
          (cl-call-next-method)))

Or maybe just

(cl-defmethod c-ts-mode-indent-styles (_style (_m (eql cpp)))
  (append '(((n-p-gp nil nil "namespace_definition") grand-parent 0)
            ((n-p-gp nil nil "linkage_specification") grand-parent 0))
          (cl-call-next-method)))

if I would like them to apply to other non-gnu styles, too.

A defcustom-style thing for customize lovers can also be added,
later for people that don't like defgeneric.  Seems like a pretty
large DSL to code up in customize, though.

João