Re: Need help with eldoc:

[João Távora]

"T.V Raman" <raman@google.com> writes:

> If I could be ensured of the eldoc always being in a buffer I could
> eliminate most of the above, but I am also afraid that  that will
> recreate the earlier async problem which is why I didn't go there.

Raman,

You are completely on the right track, and I'm very glad it was
reasonably straightforward.  And yes, "ensuring eldoc always being in a
buffer" is useful and possible -- if very slightly hacky, but read on.

Anyway, if you read the eldoc code and search for
eldoc--format-doc-buffer, you'll notice that the two members of
eldoc-display-functions by default already share "the eldoc doc buffer".
This avoids them repeating common needed work between themselves.  In
Emacsspeak, you have the same problem.

So you have two options:

1. Make use of the internal function eldoc--format-doc-buffer.  This has
   "ensure" semantics and returns the desired buffer.  Then your
   function will become:
  
   (defun emacspeak-speak-eldoc (docs interactive)
     "Speak eldoc."
     (emacspeak-auditory-icon 'help)
     (when interactive
       (with-current-buffer (eldoc--format-doc-buffer docs)
         (dtk-speak (buffer-string)))))

2. Make sure that the function eldoc-display-in-buffer is always present
   in eldoc-display-functions.  It will undertake to call
   eldoc--format-doc-buffer and place that work in the buffer that you
   can access with eldoc--doc-buffer.  Your function becomes:

   (defun emacspeak-speak-eldoc (docs interactive)
     "Speak eldoc."
     (emacspeak-auditory-icon 'help)
     (when interactive
       (with-current-buffer eldoc--doc-buffer
         (dtk-speak (buffer-string)))))

The reason I said before these solutions are slightly hacky is because
of the usage of "internal --" symbols.  But I guess it's reasonable to
make one of these symbols "external".  Or better yet, reuse the existing
external function eldoc-doc-buffer and re-purpose it for non-interactive
use.  This is done in a patch to eldoc.el added in PS, which I think is
reasonable.

Then your function would become more idiomatic:

(defun emacspeak-speak-eldoc (docs interactive)
  "Speak eldoc."
  (emacspeak-auditory-icon 'help)
  (when interactive
    (with-current-buffer (eldoc-doc-buffer)
      (dtk-speak (buffer-string)))))

Let me know what you think,
João


diff --git a/lisp/emacs-lisp/eldoc.el b/lisp/emacs-lisp/eldoc.el
index 74ffeb166d..2d0656fb41 100644
--- a/lisp/emacs-lisp/eldoc.el
+++ b/lisp/emacs-lisp/eldoc.el
@@ -464,19 +464,21 @@ eldoc--doc-buffer
 
 (defvar eldoc--doc-buffer-docs nil "Documentation items in 
`eldoc--doc-buffer'.")
 
-(defun eldoc-doc-buffer ()
+(defun eldoc-doc-buffer (&optional interactive)
   "Display ElDoc documentation buffer.
 
 This holds the results of the last documentation request."
-  (interactive)
+  (interactive (list t))
   (unless (buffer-live-p eldoc--doc-buffer)
     (user-error (format
                  "ElDoc buffer doesn't exist, maybe `%s' to produce one."
                  (substitute-command-keys "\\[eldoc]"))))
   (with-current-buffer eldoc--doc-buffer
-    (rename-buffer (replace-regexp-in-string "^ *" ""
-                                             (buffer-name)))
-    (display-buffer (current-buffer))))
+    (cond (interactive
+           (rename-buffer (replace-regexp-in-string "^ *" ""
+                                                    (buffer-name)))
+           (display-buffer (current-buffer)))
+          (t (current-buffer)))))
 
 (defun eldoc--format-doc-buffer (docs)
   "Ensure DOCS are displayed in an *eldoc* buffer."