Re: AC_PATH_XTRA and -rpath

[Paul Eggert]

Thanks for reporting that.  Does the following patch to Autoconf 2.60
fix the bug for you?  I've installed it into Autoconf CVS (for 2.61)
but I'd like you to verify that it actually works on NetBSD.

2006-07-17  Paul Eggert  <address@hidden>

        * lib/autoconf/libs.m4 (AC_PATH_XTRA): Do the check for space after
        -R regardless of host.  Patrick Welche reports that a space after -R
        is also required for NetBSD 3.99.

--- lib/autoconf/libs.m4        28 Jun 2006 08:36:54 -0000      1.18
+++ lib/autoconf/libs.m4        17 Jul 2006 17:32:06 -0000
@@ -395,29 +395,19 @@ else
   # It would also be nice to do this for all -L options, not just this one.
   if test -n "$x_libraries"; then
     X_LIBS="$X_LIBS -L$x_libraries"
-dnl FIXME: banish uname from this macro!
     # For Solaris; some versions of Sun CC require a space after -R and
     # others require no space.  Words are not sufficient . . . .
-    case `(uname -sr) 2>/dev/null` in
-    "SunOS 5"*)
-      AC_MSG_CHECKING([whether -R must be followed by a space])
-      ac_xsave_LIBS=$LIBS; LIBS="$LIBS -R$x_libraries"
-      AC_LINK_IFELSE([AC_LANG_PROGRAM()], ac_R_nospace=yes, ac_R_nospace=no)
-      if test $ac_R_nospace = yes; then
-       AC_MSG_RESULT([no])
-       X_LIBS="$X_LIBS -R$x_libraries"
-      else
-       LIBS="$ac_xsave_LIBS -R $x_libraries"
-       AC_LINK_IFELSE([AC_LANG_PROGRAM()], ac_R_space=yes, ac_R_space=no)
-       if test $ac_R_space = yes; then
-         AC_MSG_RESULT([yes])
-         X_LIBS="$X_LIBS -R $x_libraries"
-       else
-         AC_MSG_RESULT([neither works])
-       fi
-      fi
-      LIBS=$ac_xsave_LIBS
-    esac
+    AC_MSG_CHECKING([whether -R must be followed by a space])
+    ac_xsave_LIBS=$LIBS; LIBS="$LIBS -R$x_libraries"
+    AC_LINK_IFELSE([AC_LANG_PROGRAM()],
+      [AC_MSG_RESULT([no])
+       X_LIBS="$X_LIBS -R$x_libraries"],
+      [LIBS="$ac_xsave_LIBS -R $x_libraries"
+       AC_LINK_IFELSE([AC_LANG_PROGRAM()],
+        [AC_MSG_RESULT([yes])
+         X_LIBS="$X_LIBS -R $x_libraries"],
+        [AC_MSG_RESULT([neither works])])])
+    LIBS=$ac_xsave_LIBS
   fi
 
   # Check for system-dependent libraries X programs must link with.